bin/rt-mailgate

   1 #!/usr/bin/perl -w
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2012 Best Practical Solutions, LLC
   7 #                                          <sales@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 =head1 NAME
  50
  51 rt-mailgate - Mail interface to RT.
  52
  53 =cut
  54
  55 use strict;
  56 use warnings;
  57
  58 use Getopt::Long;
  59
  60 my $opts = { };
  61 GetOptions( $opts,   "queue=s", "action=s", "url=s",
  62             "jar=s", "help",    "debug",    "extension=s",
  63             "timeout=i", "verify-ssl!", "ca-file=s",
  64           );
  65
  66 my $gateway = RT::Client::MailGateway->new();
  67
  68 $gateway->run($opts);
  69
  70 package RT::Client::MailGateway;
  71
  72 use LWP::UserAgent;
  73 use HTTP::Request::Common qw($DYNAMIC_FILE_UPLOAD);
  74 use File::Temp qw(tempfile tempdir);
  75 $DYNAMIC_FILE_UPLOAD = 1;
  76
  77 use constant EX_TEMPFAIL => 75;
  78 use constant BUFFER_SIZE => 8192;
  79
  80 sub new {
  81     my $class = shift;
  82     my $self = bless {}, $class;
  83     return $self;
  84 }
  85
  86 sub run {
  87     my $self = shift;
  88     my $opts = shift;
  89
  90     if ( $opts->{running_in_test_harness} ) {
  91         $self->{running_in_test_harness} = 1;
  92     }
  93
  94     $self->validate_cli_flags($opts);
  95
  96     my $ua          = $self->get_useragent($opts);
  97     my $post_params = $self->setup_session($opts);
  98     $self->upload_message( $ua => $post_params );
  99     $self->exit_with_success();
 100 }
 101
 102 sub exit_with_success {
 103     my $self = shift;
 104     if ( $self->{running_in_test_harness} ) {
 105         return 1;
 106     } else {
 107         exit 0;
 108     }
 109 }
 110
 111 sub tempfail {
 112     my $self = shift;
 113     if ( $self->{running_in_test_harness} ) {
 114         die "tempfail";
 115     } else {
 116
 117         exit EX_TEMPFAIL;
 118     }
 119 }
 120
 121 sub permfail {
 122     my $self = shift;
 123     if ( $self->{running_in_test_harness} ) {
 124         die "permfail";
 125     } else {
 126
 127         exit 1;
 128     }
 129 }
 130
 131 sub validate_cli_flags {
 132     my $self = shift;
 133     my $opts = shift;
 134     if ( $opts->{'help'} ) {
 135         require Pod::Usage;
 136         Pod::Usage::pod2usage( { verbose => 2 } );
 137         return $self->permfail()
 138             ;    # Don't want to succeed if this is really an email!
 139     }
 140
 141     unless ( $opts->{'url'} ) {
 142         print STDERR
 143             "$0 invoked improperly\n\nNo 'url' provided to mail gateway!\n";
 144         return $self->permfail();
 145     }
 146
 147     if (($opts->{'ca-file'} or $opts->{"verify-ssl"})
 148             and not LWP::UserAgent->can("ssl_opts")) {
 149         print STDERR "Verifying SSL certificates requires LWP::UserAgent 6.0 or higher.\n";
 150         return $self->tempfail();
 151     }
 152
 153     $opts->{"verify-ssl"} = 1 unless defined $opts->{"verify-ssl"};
 154 }
 155
 156 sub get_useragent {
 157     my $self = shift;
 158     my $opts = shift;
 159     my $ua   = LWP::UserAgent->new();
 160     $ua->cookie_jar( { file => $opts->{'jar'} } ) if $opts->{'jar'};
 161
 162     if ( $ua->can("ssl_opts") ) {
 163         $ua->ssl_opts( verify_hostname => $opts->{'verify-ssl'} );
 164         $ua->ssl_opts( SSL_ca_file => $opts->{'ca-file'} )
 165             if $opts->{'ca-file'};
 166     }
 167
 168     return $ua;
 169 }
 170
 171 sub setup_session {
 172     my $self = shift;
 173     my $opts = shift;
 174     my %post_params;
 175     foreach (qw(queue action)) {
 176         $post_params{$_} = $opts->{$_} if defined $opts->{$_};
 177     }
 178
 179     if ( ( $opts->{'extension'} || '' ) =~ /^(?:action|queue|ticket)$/i ) {
 180         $post_params{ lc $opts->{'extension'} } = $ENV{'EXTENSION'}
 181             || $opts->{ $opts->{'extension'} };
 182     } elsif ( $opts->{'extension'} && $ENV{'EXTENSION'} ) {
 183         print STDERR
 184             "Value of the --extension argument is not action, queue or ticket"
 185             . ", but environment variable EXTENSION is also defined. The former is ignored.\n";
 186     }
 187
 188     # add ENV{'EXTENSION'} as X-RT-MailExtension to the message header
 189     if ( my $value = ( $ENV{'EXTENSION'} || $opts->{'extension'} ) ) {
 190
 191         # prepare value to avoid MIME format breakage
 192         # strip trailing newline symbols
 193         $value =~ s/(\r*\n)+$//;
 194
 195         # make a correct multiline header field,
 196         # with tabs in the beginning of each line
 197         $value =~ s/(\r*\n)/$1\t/g;
 198         $opts->{'headers'} .= "X-RT-Mail-Extension: $value\n";
 199     }
 200
 201     # Read the message in from STDIN
 202     # _raw_message is used for testing
 203     my $message = $opts->{'_raw_message'} || $self->slurp_message();
 204     unless ( $message->{'filename'} ) {
 205         $post_params{'message'} = [
 206                                  undef, '',
 207                                  'Content-Type' => 'application/octet-stream',
 208                                  Content        => ${ $message->{'content'} },
 209         ];
 210     } else {
 211         $post_params{'message'} = [
 212                                  $message->{'filename'}, '',
 213                                  'Content-Type' => 'application/octet-stream',
 214         ];
 215     }
 216
 217     return \%post_params;
 218 }
 219
 220 sub upload_message {
 221     my $self        = shift;
 222     my $ua          = shift;
 223     my $post_params = shift;
 224     my $full_url    = $opts->{'url'} . "/REST/1.0/NoAuth/mail-gateway";
 225     print STDERR "$0: connecting to $full_url\n" if $opts->{'debug'};
 226
 227     $ua->timeout( exists( $opts->{'timeout'} ) ? $opts->{'timeout'} : 180 );
 228     my $r = $ua->post( $full_url, $post_params, Content_Type => 'form-data' );
 229     $self->check_failure($r);
 230
 231     my $content = $r->content;
 232     print STDERR $content . "\n" if $opts->{'debug'};
 233
 234     return if ( $content =~ /^(ok|not ok)/ );
 235
 236  # It's not the server's fault if the mail is bogus. We just want to know that
 237  # *something* came out of the server.
 238     print STDERR <<EOF;
 239 RT server error.
 240
 241 The RT server which handled your email did not behave as expected. It
 242 said:
 243
 244 $content
 245 EOF
 246
 247     return $self->tempfail();
 248 }
 249
 250 sub check_failure {
 251     my $self = shift;
 252     my $r    = shift;
 253     return if $r->is_success;
 254
 255     # This ordinarily oughtn't to be able to happen, suggests a bug in RT.
 256     # So only load these heavy modules when they're needed.
 257     require HTML::TreeBuilder;
 258     require HTML::FormatText;
 259
 260     my $error = $r->error_as_HTML;
 261     my $tree  = HTML::TreeBuilder->new->parse($error);
 262     $tree->eof;
 263
 264     # It'll be a cold day in hell before RT sends out bounces in HTML
 265     my $formatter =
 266         HTML::FormatText->new( leftmargin  => 0,
 267                                rightmargin => 50, );
 268     print STDERR $formatter->format($tree);
 269     print STDERR "\n$0: undefined server error\n" if $opts->{'debug'};
 270     return $self->tempfail();
 271 }
 272
 273 sub slurp_message {
 274     my $self = shift;
 275
 276     local $@;
 277
 278     my %message;
 279     my ( $fh, $filename )
 280         = eval { tempfile( DIR => tempdir( CLEANUP => 1 ) ) };
 281     if ( !$fh || $@ ) {
 282         print STDERR "$0: Couldn't create temp file, using memory\n";
 283         print STDERR "error: $@\n" if $@;
 284
 285         my $message = \do { local ( @ARGV, $/ ); <STDIN> };
 286         unless ( $$message =~ /\S/ ) {
 287             print STDERR "$0: no message passed on STDIN\n";
 288             $self->exit_with_success;
 289         }
 290         $$message = $opts->{'headers'} . $$message if $opts->{'headers'};
 291         return ( { content => $message } );
 292     }
 293
 294     binmode $fh;
 295     binmode \*STDIN;
 296
 297     print $fh $opts->{'headers'} if $opts->{'headers'};
 298
 299     my $buf;
 300     my $empty = 1;
 301     while (1) {
 302         my $status = read \*STDIN, $buf, BUFFER_SIZE;
 303         unless ( defined $status ) {
 304             print STDERR "$0: couldn't read message: $!\n";
 305             return $self->tempfail();
 306         } elsif ( !$status ) {
 307             last;
 308         }
 309         $empty = 0 if $buf =~ /\S/;
 310         print $fh $buf;
 311     }
 312     close $fh;
 313
 314     if ($empty) {
 315         print STDERR "$0: no message passed on STDIN\n";
 316         $self->exit_with_success;
 317     }
 318     print STDERR "$0: temp file is '$filename'\n" if $opts->{'debug'};
 319     return ( { filename => $filename } );
 320 }
 321
 322 =head1 SYNOPSIS
 323
 324     rt-mailgate --help : this text
 325
 326 Usual invocation (from MTA):
 327
 328     rt-mailgate --action (correspond|comment|...) --queue queuename
 329                 --url http://your.rt.server/
 330                 [ --debug ]
 331                 [ --extension (queue|action|ticket) ]
 332                 [ --timeout seconds ]
 333
 334
 335
 336 =head1 OPTIONS
 337
 338 =over 3
 339
 340 =item C<--action>
 341
 342 Specifies what happens to email sent to this alias.  The avaliable
 343 basic actions are: C<correspond>, C<comment>.
 344
 345
 346 If you've set the RT configuration variable B<< C<UnsafeEmailCommands> >>,
 347 C<take> and C<resolve> are also available.  You can execute two or more
 348 actions on a single message using a C<-> separated list.  RT will execute
 349 the actions in the listed order.  For example you can use C<take-comment>,
 350 C<correspond-resolve> or C<take-comment-resolve> as actions.
 351
 352 Note that C<take> and C<resolve> actions ignore message text if used
 353 alone.  Include a  C<comment> or C<correspond> action if you want RT
 354 to record the incoming message.
 355
 356 The default action is C<correspond>.
 357
 358 =item C<--queue>
 359
 360 This flag determines which queue this alias should create a ticket in if no ticket identifier
 361 is found.
 362
 363 =item C<--url>
 364
 365 This flag tells the mail gateway where it can find your RT server. You should
 366 probably use the same URL that users use to log into RT.
 367
 368 If your RT server uses SSL, you will need to install additional Perl
 369 libraries. RT will detect and install these dependencies if you pass the
 370 C<--enable-ssl-mailgate> flag to configure as documented in RT's README.
 371
 372 If you have a self-signed SSL certificate, you may also need to pass
 373 C<--ca-file> or C<--no-verify-ssl>, below.
 374
 375 =item C<--ca-file> I<path>
 376
 377 Specifies the path to the public SSL certificate for the certificate
 378 authority that should be used to verify the website's SSL certificate.
 379 If your webserver uses a self-signed certificate, you should
 380 preferentially use this option over C<--no-verify-ssl>, as it will
 381 ensure that the self-signed certificate that the mailgate is seeing the
 382 I<right> self-signed certificate.
 383
 384 =item C<--no-verify-ssl>
 385
 386 This flag tells the mail gateway to trust all SSL certificates,
 387 regardless of if their hostname matches the certificate, and regardless
 388 of CA.  This is required if you have a self-signed certificate, or some
 389 other certificate which is not traceable back to an certificate your
 390 system ultimitely trusts.
 391
 392 Verifying SSL certificates requires L<LWP::UserAgent> version 6.0 or
 393 higher; explicitly passing C<--verify-ssl> on prior versions will error.
 394
 395 =item C<--extension> OPTIONAL
 396
 397 Some MTAs will route mail sent to user-foo@host or user+foo@host to user@host
 398 and present "foo" in the environment variable $EXTENSION. By specifying
 399 the value "queue" for this parameter, the queue this message should be
 400 submitted to will be set to the value of $EXTENSION. By specifying
 401 "ticket", $EXTENSION will be interpreted as the id of the ticket this message
 402 is related to.  "action" will allow the user to specify either "comment" or
 403 "correspond" in the address extension.
 404
 405 =item C<--debug> OPTIONAL
 406
 407 Print debugging output to standard error
 408
 409
 410 =item C<--timeout> OPTIONAL
 411
 412 Configure the timeout for posting the message to the web server.  The
 413 default timeout is 3 minutes (180 seconds).
 414
 415 =back
 416
 417
 418 =head1 DESCRIPTION
 419
 420 The RT mail gateway is the primary mechanism for communicating with RT
 421 via email. This program simply directs the email to the RT web server,
 422 which handles filing correspondence and sending out any required mail.
 423 It is designed to be run as part of the mail delivery process, either
 424 called directly by the MTA or C<procmail>, or in a F<.forward> or
 425 equivalent.
 426
 427 =head1 SETUP
 428
 429 Much of the set up of the mail gateway depends on your MTA and mail
 430 routing configuration. However, you will need first of all to create an
 431 RT user for the mail gateway and assign it a password; this helps to
 432 ensure that mail coming into the web server did originate from the
 433 gateway.
 434
 435 Next, you need to route mail to C<rt-mailgate> for the queues you're
 436 monitoring. For instance, if you're using F</etc/aliases> and you have a
 437 "bugs" queue, you will want something like this:
 438
 439     bugs:         "|/opt/rt4/bin/rt-mailgate --queue bugs --action correspond
 440               --url http://rt.mycorp.com/"
 441
 442     bugs-comment: "|/opt/rt4/bin/rt-mailgate --queue bugs --action comment
 443               --url http://rt.mycorp.com/"
 444
 445 Note that you don't have to run your RT server on your mail server, as
 446 the mail gateway will happily relay to a different machine.
 447
 448 =head1 CUSTOMIZATION
 449
 450 By default, the mail gateway will accept mail from anyone. However,
 451 there are situations in which you will want to authenticate users
 452 before allowing them to communicate with the system. You can do this
 453 via a plug-in mechanism in the RT configuration.
 454
 455 You can set the array C<@MailPlugins> to be a list of plugins. The
 456 default plugin, if this is not given, is C<Auth::MailFrom> - that is,
 457 authentication of the person is done based on the C<From> header of the
 458 email. If you have additional filters or authentication mechanisms, you
 459 can list them here and they will be called in order:
 460
 461     Set( @MailPlugins =>
 462         "Filter::SpamAssassin",
 463         "Auth::LDAP",
 464         # ...
 465     );
 466
 467 See the documentation for any additional plugins you have.
 468
 469 You may also put Perl subroutines into the C<@MailPlugins> array, if
 470 they behave as described below.
 471
 472 =head1 WRITING PLUGINS
 473
 474 What's actually going on in the above is that C<@MailPlugins> is a
 475 list of Perl modules; RT prepends C<RT::Interface::Email::> to the name,
 476 to form a package name, and then C<use>'s this module. The module is
 477 expected to provide a C<GetCurrentUser> subroutine, which takes a hash of
 478 several parameters:
 479
 480 =over 4
 481
 482 =item Message
 483
 484 A C<MIME::Entity> object representing the email
 485
 486 =item CurrentUser
 487
 488 An C<RT::CurrentUser> object
 489
 490 =item AuthStat
 491
 492 The authentication level returned from the previous plugin.
 493
 494 =item Ticket [OPTIONAL]
 495
 496 The ticket under discussion
 497
 498 =item Queue [OPTIONAL]
 499
 500 If we don't already have a ticket id, we need to know which queue we're talking about
 501
 502 =item Action
 503
 504 The action being performed. At the moment, it's one of "comment" or "correspond"
 505
 506 =back
 507
 508 It returns two values, the new C<RT::CurrentUser> object, and the new
 509 authentication level. The authentication level can be zero, not allowed
 510 to communicate with RT at all, (a "permission denied" error is mailed to
 511 the correspondent) or one, which is the normal mode of operation.
 512 Additionally, if C<-1> is returned, then the processing of the plug-ins
 513 stops immediately and the message is ignored.
 514
 515 =head1 ENVIRONMENT
 516
 517 =over 4
 518
 519 =item EXTENSION
 520
 521 Some MTAs will route mail sent to user-foo@host or user+foo@host to user@host
 522 and present "foo" in the environment variable C<EXTENSION>. Mailgate adds value
 523 of this variable to message in the C<X-RT-Mail-Extension> field of the message
 524 header.
 525
 526 See also C<--extension> option. Note that value of the environment variable is
 527 always added to the message header when it's not empty even if C<--extension>
 528 option is not provided.
 529
 530 =back
 531
 532 =cut
 533