CDECK  ID>, HWDXLM.

*CMZ :-        -27/07/99  13.33.03  by  Mike Seymour

*-- Author :    Ian Knowles

C-----------------------------------------------------------------------

      SUBROUTINE HWDXLM(DKVRTX,STAB)

C-----------------------------------------------------------------------

C     Sets STAB=.TRUE. if DKVRTX lies outside the specified region.

C-----------------------------------------------------------------------

      INCLUDE 'HERWIG61.INC'

      DOUBLE PRECISION DKVRTX(4),RCYL,RSPH,ZMAX,R,S

      LOGICAL STAB

      PARAMETER (RCYL=20,RSPH=100,ZMAX=500)

      STAB=.FALSE.

      IF (IOPDKL.EQ.1) THEN

C Cylinderical geometry

         S=SQRT(DKVRTX(1)**2+DKVRTX(2)**2)

         IF (S.GE.RCYL.OR.ABS(DKVRTX(3)).GE.ZMAX) STAB=.TRUE.

      ELSEIF (IOPDKL.EQ.2) THEN

C Spherical geometry

         R=SQRT(DKVRTX(1)**2+DKVRTX(2)**2+DKVRTX(3)**2)

         IF (R.GE.RSPH) STAB=.TRUE.

      ELSE

C User supplied geometry

      ENDIF

      RETURN

  999 END

CDECK  ID>, HWEFIN.

*CMZ :-        -26/04/91  11.11.55  by  Bryan Webber

*-- Author :    Bryan Webber

C-----------------------------------------------------------------------

      SUBROUTINE HWEFIN

C-----------------------------------------------------------------------

C     TERMINAL CALCULATIONS ON ELEMENTARY PROCESS

C-----------------------------------------------------------------------

      INCLUDE 'HERWIG61.INC'

      DOUBLE PRECISION RNWGT,SPWGT,ERWGT

      WRITE (6,1)

    1 FORMAT(/10X,'OUTPUT ON ELEMENTARY PROCESS'/)

      IF (NWGTS.EQ.0) THEN

        WRITE (6,10)

   10   FORMAT(10X,'NO WEIGHTS GENERATED')

      ELSE

        RNWGT=1./FLOAT(NWGTS)

        AVWGT=WGTSUM*RNWGT

        SPWGT=SQRT(MAX(WSQSUM*RNWGT-AVWGT**2,ZERO))

        ERWGT=SPWGT*SQRT(RNWGT)

        IF (.NOT.NOWGT) WGTMAX=AVWGT

        IF (WGTMAX.EQ.ZERO) WGTMAX=ONE

        WRITE (6,11) NEVHEP,NWGTS,AVWGT,SPWGT,WBIGST,WGTMAX,IPROC,

     &               1000.*AVWGT,1000.*ERWGT,100.*AVWGT/WGTMAX

   11   FORMAT(1P,

     &         10X,'NUMBER OF EVENTS   = ',I11/

     &         10X,'NUMBER OF WEIGHTS  = ',I11/

     &         10X,'MEAN VALUE OF WGT  =',E12.4/

     &         10X,'RMS SPREAD IN WGT  =',E12.4/

     &         10X,'ACTUAL MAX WEIGHT  =',E12.4/

     &         10X,'ASSUMED MAX WEIGHT =',E12.4//

     &         10X,'PROCESS CODE IPROC = ',I11/

     &         10X,'CROSS SECTION (PB) =',G12.4/

     &         10X,'ERROR IN C-S  (PB) =',G12.4/

     &         10X,'EFFICIENCY PERCENT =',G12.4)

      ENDIF

      END