CDECK  ID>, HWHEW3.

*CMZ :-        -27/03/92  19.48.55  by  Mike Seymour

*-- Author :    Zoltan Kunszt, modified by Bryan Webber

C-----------------------------------------------------------------------

      SUBROUTINE HWHEW3(N1,N2,N3,N4,N5,N6,AMPWW)

C-----------------------------------------------------------------------

C RECALL THAT N1,N3,N5 MUST BE OUTGOING FERMIONS, AND N2,N4,N6 MUST BE

C OUTGOING ANTI-FERMIONS; 3,4 FOR W-, 5,6 FOR W+

C

C EQ1 AND T31 ARE FOR OUTOING INITIAL QUARK

C CHOOSE APPROPRIATE CASE ACCORDING TO NUPDN

C NUPDN=1 FOR UUBAR COLLISIONS, NUPDN=2 FOR DDBAR COLLISIONS

C NFINAL CHOOSES THE FINAL DECAYS, 1 FOR DOUBLE LEPTON, 2 FOR 1 FLAVOR

C LEPTON+2FAMILIES OF QUARKS, 3 THE SAME, 4 FOR DOUBLE 2FAM3COLOR QUARKS

C

C NOTE: EXTERNAL FACTOR OF COLOR AVERAGE AND SPIN AVERAGE AND

C COUPLING (E**8/4/9) MUST BE INCLUDED AS WELL AS COMPENSATION

C FOR ON POLE APPROXIMATION AS DESIRED.

C-----------------------------------------------------------------------

      INCLUDE 'HERWIG61.INC'

      COMPLEX HWHEW4,ZH,ZCH,ZD,ZAMP1,ZAMP2,ZAMP3,DWW,CWW,BWW,AWW,AWWM,

     & AWWP,AMPTEM,ZTWO,ZHALF

      DOUBLE PRECISION XW,ZMASS,T3,EQ1,RR,RL,ZM2,AMP2,RKW,COLFAC(4),

     & AMPWW(4)

      INTEGER I,N1,N2,N3,N4,N5,N6

      EXTERNAL HWHEW4

      COMMON/HWHEWQ/ZH(7,7),ZCH(7,7),ZD(7,7)

      EQUIVALENCE (XW,SWEIN),(ZMASS,RMASS(200))

      DATA COLFAC/1.D0,3.D0,3.D0,9.D0/

      DATA ZTWO,ZHALF/(2.0,0.0),(0.5,0.0)/

      T3=-1.D0

      EQ1=-1.D0

      RR=-2.D0*EQ1*XW

      RL=T3+RR

      ZM2=ZMASS*ZMASS

      ZAMP1=CMPLX(ZM2)/(ZTWO*ZD(N1,N2))

     &                /(ZTWO*ZD(N1,N2)+CMPLX(-ZM2,GAMZ*ZMASS))

      ZAMP2=ZHALF/(ZD(N1,N3)+ZD(N1,N4)+ZD(N3,N4))

      ZAMP3=ZHALF/(ZD(N1,N5)+ZD(N1,N6)+ZD(N5,N6))

      DWW=CMPLX(RL)*ZAMP1+T3/(ZTWO*ZD(N1,N2))

      CWW=CMPLX(RR)*ZAMP1

      AWW=DWW

      BWW=DWW-ZAMP3

      AWWM=AWW*HWHEW4(N1,N2,N3,N4,N5,N6)-BWW*HWHEW4(N1,N2,N5,N6,N3,N4)

      AWWP=CWW*(HWHEW4(N2,N1,N5,N6,N3,N4)-HWHEW4(N2,N1,N3,N4,N5,N6))

      AMPTEM=AWWM*CONJG(AWWM)+AWWP*CONJG(AWWP)

      AMP2=REAL(AMPTEM)

C AMP2 DOES NOT INCLUDE COLOR OR FLAVOR SUMS OR AVERAGES YET

C NOR DOES IT INCLUDE TO THIS POINT KWW**2

C 1 LEPTON FLAVOR IF APPROPRIATE FOR NFINAL CHOICE

      RKW=0.25D0/XW**2

      DO 6 I=1,4

6     AMPWW(I)=AMP2*COLFAC(I)*RKW*RKW

      RETURN

      END