CDECK  ID>, HWHEW5.

*CMZ :          20/08/91  22.09.33  by  Federico Carminati

*-- Author :    Zoltan Kunszt, modified by Mike Seymour

C-----------------------------------------------------------------------

      SUBROUTINE HWHEW5(N1,N2,N3,N4,N5,N6,HELSUM,HELCTY,ID1,ID2)

C-----------------------------------------------------------------------

C RECALL THAT N1,N3,N5 MUST BE OUTGOING FERMIONS, AND N2,N4,N6 MUST BE

C OUTGOING ANTI-FERMIONS; 3,4 FOR Z0, 5,6 FOR Z0

C

C EQ1 AND T31 ARE FOR OUTOING INITIAL QUARK

C CHOOSE APPROPRIATE CASE ACCORDING TO NUPDN

C NUPDN=1 FOR UUBAR COLLISIONS, NUPDN=2 FOR DDBAR COLLISIONS

C NFINAL CHOOSES THE FINAL DECAYS, 1 FOR DOUBLE LEPTON, 2 FOR 1 FLAVOR

C LEPTON+2FAMILIES OF QUARKS, 3 THE SAME, 4 FOR DOUBLE 2FAM3COLOR QUARKS

C

C NOTE: EXTERNAL FACTOR OF COLOR AVERAGE AND SPIN AVERAGE AND

C COUPLING (E**8/4/9) MUST BE INCLUDED AS WELL AS COMPENSATION

C FOR ON POLE APPROXIMATION AS DESIRED.

C

C---SLIGHTLY MODIFIED BY MHS, SO THAT HELCTY REFERS TO THE FINAL STATE

C   INDICATED BY ID1,ID2

C-----------------------------------------------------------------------

      IMPLICIT NONE

      COMPLEX HWHEW4,ZH,ZCH,ZD,ZAMM(8),ZS134,ZS156,ZS234,ZS256,ZTWO

      DOUBLE PRECISION CPFAC,CPALL,HELSUM,HELCTY,AMM

      INTEGER N1,N2,N3,N4,N5,N6,ID1,ID2,I

      EXTERNAL HWHEW4

      COMMON/HWHEWQ/ZH(7,7),ZCH(7,7),ZD(7,7)

      COMMON/HWHEWR/CPFAC(12,12,8),CPALL(8)

      DATA ZTWO/(2.0,0.0)/

C THE MATRIX ELEMENT DEPENDS ON

      ZS134=(ZD(N1,N3)+ZD(N1,N4)+ZD(N3,N4))*ZTWO

      ZS156=(ZD(N1,N5)+ZD(N1,N6)+ZD(N5,N6))*ZTWO

      ZS234=(ZD(N2,N3)+ZD(N2,N4)+ZD(N3,N4))*ZTWO

      ZS256=(ZD(N2,N5)+ZD(N2,N6)+ZD(N5,N6))*ZTWO

      ZAMM(1)=HWHEW4(N1,N2,N3,N4,N5,N6)/ZS134+

     >        HWHEW4(N1,N2,N5,N6,N3,N4)/ZS156

      ZAMM(2)=HWHEW4(N1,N2,N4,N3,N5,N6)/ZS134+

     >        HWHEW4(N1,N2,N5,N6,N4,N3)/ZS156

      ZAMM(3)=HWHEW4(N1,N2,N3,N4,N6,N5)/ZS134+

     >        HWHEW4(N1,N2,N6,N5,N3,N4)/ZS156

      ZAMM(4)=HWHEW4(N1,N2,N4,N3,N6,N5)/ZS134+

     >        HWHEW4(N1,N2,N6,N5,N4,N3)/ZS156

      ZAMM(5)=HWHEW4(N2,N1,N3,N4,N5,N6)/ZS234+

     >        HWHEW4(N2,N1,N5,N6,N3,N4)/ZS256

      ZAMM(6)=HWHEW4(N2,N1,N4,N3,N5,N6)/ZS234+

     >        HWHEW4(N2,N1,N5,N6,N4,N3)/ZS256

      ZAMM(7)=HWHEW4(N2,N1,N3,N4,N6,N5)/ZS234+

     >        HWHEW4(N2,N1,N6,N5,N3,N4)/ZS256

      ZAMM(8)=HWHEW4(N2,N1,N4,N3,N6,N5)/ZS234+

     >        HWHEW4(N2,N1,N6,N5,N4,N3)/ZS256

      HELSUM=0.0

      HELCTY=0.0

      DO 1 I=1,8

        AMM=REAL(ZAMM(I)*CONJG(ZAMM(I)))

        HELSUM=HELSUM+CPALL(I)*AMM

        HELCTY=HELCTY+CPFAC(ID1,ID2,I)*AMM

 1    CONTINUE

      RETURN

      END