VZERO DAs + Object target dependencies
[u/mrichter/AliRoot.git] / EMCAL / EMCALraw / CMakeLists.txt
1 # **************************************************************************
2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
3 # *                                                                        *
4 # * Author: The ALICE Off-line Project.                                    *
5 # * Contributors are mentioned in the code where appropriate.              *
6 # *                                                                        *
7 # * Permission to use, copy, modify and distribute this software and its   *
8 # * documentation strictly for non-commercial purposes is hereby granted   *
9 # * without fee, provided that the above copyright notice appears in all   *
10 # * copies and that both the copyright notice and this permission notice   *
11 # * appear in the supporting documentation. The authors make no claims     *
12 # * about the suitability of this software for any purpose. It is          *
13 # * provided "as is" without express or implied warranty.                  *
14 # **************************************************************************
15
16 # Module
17 set(MODULE EMCALraw)
18
19 # Module include folder
20 include_directories(${AliRoot_SOURCE_DIR}/EMCAL/${MODULE})
21
22 # Additional include folders in alphabetical order except ROOT
23 include_directories(${ROOT_INCLUDE_DIRS}
24                     ${AliRoot_SOURCE_DIR}/EMCAL/EMCALUtils
25                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
26                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatarec
27                     ${AliRoot_SOURCE_DIR}/STEER/CDB
28                     ${AliRoot_SOURCE_DIR}/STEER/ESD
29                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
30                    )
31
32 # Sources in alphabetical order
33 set(SRCS
34     AliCaloBunchInfo.cxx
35     AliCaloFastAltroFitv0.cxx
36     AliCaloFitResults.cxx
37     AliCaloFitSubarray.cxx
38     AliCaloNeuralFit.cxx
39     AliCaloPeakFinderVectors.cxx
40     AliCaloRawAnalyzerCrude.cxx
41     AliCaloRawAnalyzer.cxx
42     AliCaloRawAnalyzerFactory.cxx
43     AliCaloRawAnalyzerFakeALTRO.cxx
44     AliCaloRawAnalyzerFastFit.cxx
45     AliCaloRawAnalyzerFitter.cxx
46     AliCaloRawAnalyzerKStandard.cxx
47     AliCaloRawAnalyzerNN.cxx
48     AliCaloRawAnalyzerPeakFinder.cxx
49     AliEMCALCCUSBRawStream.cxx
50     AliEMCALRawResponse.cxx
51    )
52
53 # Headers from sources
54 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
55
56 # Generate the dictionary
57 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
58 get_directory_property(incdirs INCLUDE_DIRECTORIES)
59 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
60
61 set(ROOT_DEPENDENCIES )
62 set(ALIROOT_DEPENDENCIES STEERBase CDB ESD RAWDatabase RAWDatarec EMCALUtils)
63
64 # Generate the ROOT map
65 # Dependecies
66 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
67 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
68
69 # Create an object to be reused in case of static libraries 
70 # Otherwise the sources will be compiled twice
71 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
72 # Build dependencies as headers, defines
73 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
74 # Add a library to the project using the object
75 add_library(${MODULE} SHARED $<TARGET_OBJECTS:EMCALraw-object>)
76
77 # Linking to the dependencies
78 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
79
80 # Additional compilation flags
81 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS "")
82 add_definitions(-D__EMCALUTIL__)
83
84 # System dependent: Modify the way the library is build
85 if(${CMAKE_SYSTEM} MATCHES Darwin)
86     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
87 endif(${CMAKE_SYSTEM} MATCHES Darwin)
88
89 # Installation
90 install(TARGETS ${MODULE}
91         ARCHIVE DESTINATION lib
92         LIBRARY DESTINATION lib)
93
94 install(FILES ${HDRS} DESTINATION include)
95
96 # Static version if DA enabled
97 if(ALIROOT_STATIC)
98     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:EMCALraw-object>)
99     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
100     target_link_libraries(${MODULE}-static STEERBase-static ESD-static CDB-static RAWDatabase-static RAWDatarec-static EMCALUtils-static Root)
101     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
102
103     # Installation
104     install(TARGETS ${MODULE}-static
105             ARCHIVE DESTINATION lib
106             LIBRARY DESTINATION lib)
107 endif(ALIROOT_STATIC)