FMD/FMDsim/CMakeLists.txt

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # Module
  17 set(MODULE FMDsim)
  18
  19 # Module include folder
  20 include_directories(${AliRoot_SOURCE_DIR}/FMD/${MODULE})
  21
  22 # Additional include folders in alphabetical order except ROOT
  23 include_directories(${ROOT_INCLUDE_DIRS}
  24                     ${AliRoot_SOURCE_DIR}/FMD/FMDbase
  25                     ${AliRoot_SOURCE_DIR}/FMD/FMDrec
  26                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
  27                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatasim
  28                     ${AliRoot_SOURCE_DIR}/STEER/ESD
  29                     ${AliRoot_SOURCE_DIR}/STEER/STEER
  30                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
  31                    )
  32
  33 # Sources in alphabetical order
  34 set(SRCS
  35     AliFMDBaseDigitizer.cxx
  36     AliFMD.cxx
  37     AliFMDDigitizer.cxx
  38     AliFMDEdepMap.cxx
  39     AliFMDHit.cxx
  40     AliFMDHitDigitizer.cxx
  41     AliFMDQADataMakerSim.cxx
  42     AliFMDRawWriter.cxx
  43     AliFMDv0.cxx
  44     AliFMDv1.cxx
  45    )
  46
  47 # Headers from sources
  48 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
  49 set(HDRS ${HDRS} AliFMDEdepHitPair.h)
  50
  51 # Generate the dictionary
  52 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
  53 get_directory_property(incdirs INCLUDE_DIRECTORIES)
  54 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
  55
  56 # Dependencies
  57 set(ROOT_DEPENDENCIES)
  58 set(ALIROOT_DEPENDENCIES STEERBase STEER ESD RAWDatabase RAWDatasim FMDbase FMDrec)
  59
  60 # Generate the ROOT map
  61 # Dependecies
  62 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  63 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
  64
  65 # Create an object to be reused in case of static libraries
  66 # Otherwise the sources will be compiled twice
  67 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
  68 # Follow headers dependencies
  69 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
  70 # Add a library to the project using the object
  71 add_library(${MODULE} SHARED $<TARGET_OBJECTS:${MODULE}-object>)
  72
  73 # linking
  74 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  75
  76 # Setting the correct headers for the object as gathered from the dependencies
  77 target_include_directories(${MODULE}-object PUBLIC $<TARGET_PROPERTY:${MODULE},INCLUDE_DIRECTORIES>)
  78 set_target_properties(${MODULE}-object PROPERTIES COMPILE_DEFINITIONS $<TARGET_PROPERTY:${MODULE},COMPILE_DEFINITIONS>)
  79
  80 # Additional compilation flags
  81 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS " ")
  82
  83 # System dependent: Modify the way the library is build
  84 if(${CMAKE_SYSTEM} MATCHES Darwin)
  85     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
  86 endif(${CMAKE_SYSTEM} MATCHES Darwin)
  87
  88 # Installation
  89 install(TARGETS ${MODULE}
  90         ARCHIVE DESTINATION lib
  91         LIBRARY DESTINATION lib)
  92
  93 install(FILES ${HDRS} DESTINATION include)
  94
  95 # Static version if DA enabled
  96 if(ALIROOT_STATIC)
  97     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:${MODULE}-object>)
  98     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
  99
 100     # list of shared dependencies / the name of the variable containing the list of static ones
 101     generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")
 102     target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root)
 103
 104     # Public include folders that will be propagated to the dependecies
 105     target_include_directories(${MODULE}-static PUBLIC ${incdirs})
 106
 107     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
 108
 109     # Installation
 110     install(TARGETS ${MODULE}-static
 111             ARCHIVE DESTINATION lib
 112             LIBRARY DESTINATION lib)
 113 endif(ALIROOT_STATIC)
 114