ISAJET/code/sigh3.F

   1 #include "isajet/pilot.h"
   2       SUBROUTINE SIGH3
   3 C
   4 C          Calculate angular distributions for W decays from Higgs,
   5 C          d(sigma)/d(qmw**2)d(yw)d(omega)d(omega1)d(omega2)
   6 C
   7 C          Ver 7.14: Only modification needed for MSSM is to check
   8 C          GOMSSM flag instead of INITYP
   9 C
  10 #include "isajet/itapes.inc"
  11 #include "isajet/qcdpar.inc"
  12 #include "isajet/jetpar.inc"
  13 #include "isajet/pjets.inc"
  14 #include "isajet/primar.inc"
  15 #include "isajet/q1q2.inc"
  16 #include "isajet/jetsig.inc"
  17 #include "isajet/wsig.inc"
  18 #include "isajet/wwsig.inc"
  19 #include "isajet/qsave.inc"
  20 #include "isajet/wcon.inc"
  21 #include "isajet/const.inc"
  22 #include "isajet/wwpar.inc"
  23 #include "isajet/hcon.inc"
  24 #include "isajet/xmssm.inc"
  25 C
  26       EQUIVALENCE (S,SHAT),(T,THAT),(U,UHAT)
  27       DIMENSION IDADDR(4),IW(2),LAM(3),LISTJ(29)
  28      $,T12(3,3),T34(3,3),FTERM(4),FR(3,3),FI(3,3)
  29      $,CPHI12(3),SPHI12(3),CPHI34(3),SPHI34(3)
  30       DIMENSION PFCM(5,4),PWCM(5,2)
  31 #if defined(CERNLIB_DOUBLE)
  32       DOUBLE PRECISION TERM,FTERM,ZCM
  33 #endif
  34       DATA LAM/0,1,-1/
  35       DATA LISTJ/
  36      $9,1,-1,2,-2,3,-3,4,-4,5,-5,6,-6,
  37      $11,-11,12,-12,13,-13,14,-14,15,-15,16,-16,
  38      $10,80,-80,90/
  39 C
  40 C          FUNCTIONS
  41       DOTP(I,J)=PPAIR(4,I)*PPAIR(4,J)-PPAIR(1,I)*PPAIR(1,J)
  42      $-PPAIR(2,I)*PPAIR(2,J)-PPAIR(3,I)*PPAIR(3,J)
  43 C
  44 C          ENTRY
  45       IF(NPAIR.NE.4) RETURN
  46 C
  47 C          RECONSTRUCT W-->FF DECAY ANGLES
  48 C
  49 C          INITIALIZE PFCM AND PWCM
  50       DO 10 I=1,4
  51       DO 10 K=1,5
  52 10    PFCM(K,I)=PPAIR(K,I)
  53       DO 11 I=1,2
  54       DO 11 K=1,5
  55 11    PWCM(K,I)=PJETS(K,I)
  56 C
  57 C          Z BOOST TO WW CENTER OF MASS
  58       CHWW=QWJET(4)/QWJET(5)
  59       SHWW=QWJET(3)/QWJET(5)
  60       DO 20 I=1,4
  61       TMP=CHWW*PFCM(4,I)-SHWW*PFCM(3,I)
  62       PFCM(3,I)=-SHWW*PFCM(4,I)+CHWW*PFCM(3,I)
  63 20    PFCM(4,I)=TMP
  64       DO 21 I=1,2
  65       TMP=CHWW*PWCM(4,I)-SHWW*PWCM(3,I)
  66       PWCM(3,I)=-SHWW*PWCM(4,I)+CHWW*PWCM(3,I)
  67 21    PWCM(4,I)=TMP
  68 C
  69 C          ROTATE W1 TO +Z AXIS
  70       PTW1=SQRT(PWCM(1,1)**2+PWCM(2,1)**2)
  71       CPHIW1=PWCM(1,1)/PTW1
  72       SPHIW1=PWCM(2,1)/PTW1
  73       PW1=SQRT(PTW1**2+PWCM(3,1)**2)
  74       CTHW1=PWCM(3,1)/PW1
  75       STHW1=PTW1/PW1
  76 C          Z ROTATION
  77       DO 30 I=1,4
  78       TMP=CPHIW1*PFCM(1,I)+SPHIW1*PFCM(2,I)
  79       PFCM(2,I)=-SPHIW1*PFCM(1,I)+CPHIW1*PFCM(2,I)
  80 30    PFCM(1,I)=TMP
  81 C          Y ROTATION
  82       DO 31 I=1,4
  83       TMP=CTHW1*PFCM(1,I)-STHW1*PFCM(3,I)
  84       PFCM(3,I)=STHW1*PFCM(1,I)+CTHW1*PFCM(3,I)
  85 31    PFCM(1,I)=TMP
  86 C
  87 C          BOOST TO W REST FRAMES
  88       CHW1=PWCM(4,1)/PWCM(5,1)
  89       SHW1=PW1/PWCM(5,1)
  90       DO 40 I=1,4
  91       IF(I.LE.2) THEN
  92         SHWI=SHW1
  93       ELSE
  94         SHWI=-SHW1
  95       ENDIF
  96       TMP=CHW1*PFCM(4,I)-SHWI*PFCM(3,I)
  97       PFCM(3,I)=-SHWI*PFCM(4,I)+CHW1*PFCM(3,I)
  98 40    PFCM(4,I)=TMP
  99 C
 100 C          COMPUTE ANGLES
 101       TH12=ACOS(PFCM(3,1)/SQRT(PFCM(1,1)**2+PFCM(2,1)**2+PFCM(3,1)**2))
 102       PHI12=ATAN2(PFCM(2,1),PFCM(1,1))
 103       TH34=ACOS(PFCM(3,3)/SQRT(PFCM(1,3)**2+PFCM(2,3)**2+PFCM(3,3)**2))
 104       PHI34=ATAN2(PFCM(2,3),PFCM(1,3))
 105 C
 106 C          COMPUTE DECAY ANGULAR DISTRIBUTIONS.
 107 C
 108       DO 100 I=1,4
 109       IDADDR(I)=IABS(IDPAIR(I))
 110 100   IF(IDADDR(I).GE.11) IDADDR(I)=IDADDR(I)-4
 111       IF(GOMSSM) THEN
 112         IW(1)=JETTYP(1)-76
 113         IW(2)=JETTYP(2)-76
 114       ELSE
 115         IW(1)=JETTYP(1)-25
 116         IW(2)=JETTYP(2)-25
 117       ENDIF
 118 C
 119       AMV=PJETS(5,1)
 120       GAMV=WGAM(IW(1))
 121       QMH=QMW
 122 C          COUPLINGS
 123       A12=AQ(IDADDR(1),IW(1))
 124       B12=BQ(IDADDR(1),IW(1))
 125       A34=AQ(IDADDR(3),IW(2))
 126       B34=BQ(IDADDR(3),IW(2))
 127 C          DECAY DISTRIBUTIONS
 128       TVV12=8.*PI*ALFA*(A12**2+B12**2)
 129       TVA12=16.*PI*ALFA*A12*B12
 130       COS12=COS(TH12)
 131       SIN12=SIN(TH12)
 132       T12(1,1)=TVV12*SIN12**2
 133       T12(1,2)=TVV12*SIN12*COS12/SQRT2+TVA12*SIN12/SQRT2
 134       T12(1,3)=-TVV12*SIN12*COS12/SQRT2+TVA12*SIN12/SQRT2
 135       T12(2,1)=T12(1,2)
 136       T12(2,2)=TVV12*(.5+.5*COS12**2)+TVA12*COS12
 137       T12(2,3)=TVV12*.5*SIN12**2
 138       T12(3,1)=T12(1,3)
 139       T12(3,2)=T12(2,3)
 140       T12(3,3)=TVV12*(.5+.5*COS12**2)-TVA12*COS12
 141 C
 142       TVV34=8.*PI*ALFA*(A34**2+B34**2)
 143       TVA34=16.*PI*ALFA*A34*B34
 144       COS34=COS(TH34)
 145       SIN34=SIN(TH34)
 146       T34(1,1)=TVV34*SIN34**2
 147       T34(1,2)=TVV34*SIN34*COS34/SQRT2+TVA34*SIN34/SQRT2
 148       T34(1,3)=-TVV34*SIN34*COS34/SQRT2+TVA34*SIN34/SQRT2
 149       T34(2,1)=T34(1,2)
 150       T34(2,2)=TVV34*(.5+.5*COS34**2)+TVA34*COS34
 151       T34(2,3)=TVV34*.5*SIN34**2
 152       T34(3,1)=T34(1,3)
 153       T34(3,2)=T34(2,3)
 154       T34(3,3)=TVV34*(.5+.5*COS34**2)-TVA34*COS34
 155 C
 156       CPHI12(1)=1.
 157       CPHI12(2)=COS(PHI12)
 158       CPHI12(3)=COS(2.*PHI12)
 159       SPHI12(1)=0.
 160       SPHI12(2)=SIN(PHI12)
 161       SPHI12(3)=SIN(2.*PHI12)
 162       CPHI34(1)=1.
 163       CPHI34(2)=COS(PHI34)
 164       CPHI34(3)=COS(2.*PHI34)
 165       SPHI34(1)=0.
 166       SPHI34(2)=SIN(PHI34)
 167       SPHI34(3)=SIN(2.*PHI34)
 168 C
 169       TCPHI=CPHI12(2)*CPHI34(2)-SPHI12(2)*SPHI34(2)
 170       TSPHI=SPHI12(2)*CPHI34(2)+CPHI12(2)*SPHI34(2)
 171       TC2PHI=CPHI12(3)*CPHI34(3)-SPHI12(3)*SPHI34(3)
 172       TS2PHI=SPHI12(3)*CPHI34(3)+CPHI12(3)*SPHI34(3)
 173 C
 174 C          PURE HIGGS --> W W. CALCULATE ANGULAR DISTRIBUTION FOR
 175 C          HIGGS DECAY AND MULTIPLY BY CROSS SECTION.
 176 C
 177       IF(INITYP(1).LE.25.OR.GOMSSM) THEN
 178         F0=.5*QMH**2/AMV**2-1.
 179         F1=1.
 180         TOTAL=(8.*PI/3.)**2*TVV12*TVV34*(F0**2+2.*F1**2)
 181         DIFF=F0**2*T12(1,1)*T34(1,1)
 182      $  +F0*F1*(2.*T12(1,2)*T34(1,2)+2.*T12(1,3)*T34(1,3))*TCPHI
 183      $  +F1**2*(T12(2,2)*T34(1,2)+T12(3,3)*T34(3,3)
 184      $    +2.*T12(2,3)*T34(2,3)*TC2PHI)
 185         WWSIG=SIGLLQ*DIFF/TOTAL
 186         RETURN
 187       ENDIF
 188 C
 189 C          W W FUSION. CALCULATE ANGULAR DISTRIUBTION FOR DECAY
 190 C          INCLUDING ALL GRAPHS.
 191 C
 192 C          KINEMATICS
 193       IFL1=LISTJ(JETTYP(1))
 194       IFL2=LISTJ(JETTYP(2))
 195       IFIN1=LISTJ(INITYP(1))
 196       IFIN2=LISTJ(INITYP(2))
 197       WMF=AMASS(IFL1)
 198       WMI=AMASS(IFIN1)
 199       PINPF=SQRT((S-4.*WMI**2)*(S-4.*WMF**2))
 200       ZCM=(.5*S+T-WMI**2-WMF**2)/(.5*PINPF)
 201 C          PRODUCTION AMPLITUDES. REMEMBER MISSING SIN(THETA)/SQRT(2)
 202       DO 110 L=1,4
 203       FTERM(L)=0.
 204       DO 120 J=1,4
 205       TERM=0.
 206       DO 130 I=1,4
 207 130   TERM=TERM+ANWWWW(I,J,L)*ZCM**(I-1)
 208       TERM=TERM/(ADWWWW(1,J)+ADWWWW(2,J)*ZCM)
 209 120   FTERM(L)=FTERM(L)+TERM
 210 110   CONTINUE
 211       FTERM(4)=FTERM(4)*SQRT(ABS(1.-ZCM**2))/SQRT2
 212 C          HELICITY AMPLITUDES. NOTATION IS 0,+,-
 213       FR(1,1)=FTERM(1)
 214       FI(1,1)=AIWWWW(1)
 215       FR(1,2)=FTERM(4)
 216       FI(1,2)=AIWWWW(4)
 217       FR(2,2)=FTERM(3)
 218       FI(2,2)=AIWWWW(3)
 219       FR(2,3)=FTERM(2)
 220       FI(2,3)=AIWWWW(2)
 221 C
 222       FR(1,3)=FR(1,2)
 223       FI(1,3)=FI(1,2)
 224       FR(3,1)=FR(1,3)
 225       FI(3,1)=FI(1,3)
 226       FR(2,1)=FR(1,2)
 227       FI(2,1)=FI(1,2)
 228 C
 229       FR(3,3)=FR(2,2)
 230       FI(3,3)=FI(2,2)
 231       FR(3,2)=FR(2,3)
 232       FI(3,2)=FI(2,3)
 233 C
 234 C          DIFFERENTIAL DISTRIBUTION FROM DENSITY MATRIX
 235       DIFF=0.
 236       DO 140 I1=1,3
 237       L1=LAM(I1)
 238       DO 140 I2=1,3
 239       L2=LAM(I2)
 240       DO 140 I3=1,3
 241       L3=LAM(I3)
 242       DO 140 I4=1,3
 243       L4=LAM(I4)
 244       L12=L1-L2
 245       I12=IABS(L12)+1
 246       IF(I12.EQ.0) I12=3
 247       L34=L3-L4
 248       I34=IABS(L34)+1
 249       IF(I34.EQ.0) I34=3
 250       C1234=CPHI12(I12)*CPHI34(I34)
 251      $-SPHI12(I12)*ISIGN(1,L12)*SPHI34(I34)*ISIGN(1,L34)
 252       S1234=SPHI12(I12)*ISIGN(1,L12)*CPHI34(I34)
 253      $+CPHI12(I12)*SPHI34(I34)*ISIGN(1,L34)
 254       DIFF=DIFF+(FR(I1,I2)*FR(I3,I4)+FI(I1,I2)*FI(I3,I4))
 255      $*T12(I3,I1)*T34(I4,I2)*C1234
 256      $+(FR(I1,I2)*FI(I3,I4)-FI(I1,I2)*FR(I3,I4))
 257      $*T12(I3,I1)*T34(I4,I2)*S1234
 258 140   CONTINUE
 259 C          INTEGRATED DISTRIBUTION
 260       TOTAL=0.
 261       DO 150 I1=1,3
 262       DO 150 I2=1,3
 263       TOTAL=TOTAL+FR(I1,I2)**2+FI(I1,I2)**2
 264 150   CONTINUE
 265       FAC=(16.*PI/3.*4.*PI*ALFA)**2
 266       FAC=FAC*(A12**2+B12**2)*(A34**2+B34**2)
 267       TOTAL=TOTAL*FAC
 268       WWSIG=DIFF/TOTAL*SIGLLQ
 269       RETURN
 270       END