ISAJET/isasusy/sshsf.F

   1 #include "isajet/pilot.h"
   2       SUBROUTINE SSHSF
   3 C-----------------------------------------------------------------------
   4 C
   5 C          Calculates the partial decay widths of
   6 C          the Higgs bosons into sfermions.
   7 C          calculated by X. Tata
   8 C          program by M. Bisset
   9 C
  10 C          10/23/93: modified by H. Baer, 10/8/96
  11 C          Intra-flavor sfermion mixing is neglected
  12 C          for all flavors EXCEPT for stops, sbottoms and staus.
  13 C
  14 C
  15 C         10/23/93
  16 C          It is assumed that the A-terms are real.
  17 C          In addition, all coefficients of the sfermion
  18 C          trilinear terms from the superpotential
  19 C          EXCEPT the stop (AAT), sbottom (AAB) and stau (AAL)
  20 C          coefficients are set to zero.
  21 C
  22 C     ===> Code for the general case removing all these
  23 C          artificial restrictions is present below.
  24 C          The preceeding restrictions are specified
  25 C          by giving special values to some variables
  26 C          This is discussed in two sections beginning
  27 C          with the symbols  (*@&*)  in the code below.
  28 C
  29 C-----------------------------------------------------------------------
  30 #if defined(CERNLIB_IMPNONE)
  31       IMPLICIT NONE
  32 #endif
  33 #include "isajet/sslun.inc"
  34 #include "isajet/sssm.inc"
  35 #include "isajet/sspar.inc"
  36 #include "isajet/sstype.inc"
  37 C
  38 C
  39       REAL SR2,PI,GG,TW2,BETA,DSA,DCA,DSB,DCB,MH
  40       REAL EP,TANB,COTB,ATERM,MSFMIX,THETSF,SIN2B
  41       REAL TEMP,TEMP1,TEMP2,YA1,YA2
  42       REAL SINA,COSA,SINA2,COSA2,M1,M2,M12,LAMB
  43       REAL SINAU,COSAU,SINAD,COSAD
  44       REAL A11,A22,A12,B11,B22,B12,C11,C12,C21,C22
  45       REAL ASQ,BSQ,CSQ,DWSF
  46       REAL DWSFL,DWSFH,DWSFP,DWSFC,SSXLAM
  47       REAL ASMB,MBMB,MBQ,ASMT,MTMT,MTQ,SUALFS
  48       DOUBLE PRECISION SSMQCD
  49       DIMENSION ATERM(12),MSFMIX(12,2),THETSF(12)
  50       DIMENSION ASQ(10,3),BSQ(9),CSQ(6,4)
  51       DIMENSION DWSF(12,4),DWSFL(12,4),DWSFH(12,4)
  52       DIMENSION DWSFP(12,4),DWSFC(6,4)
  53       INTEGER II,IJ,JJ,IC,IJU,IJD,NUMH
  54 C
  55 C
  56       SR2=SQRT(2.0)
  57       PI=4.0*ATAN(1.0)
  58       TW2=SN2THW/(1.0-SN2THW)
  59       GG=SQRT(4.0*PI*ALFAEM/SN2THW)
  60       EP=TWOM1
  61 C
  62       TANB=1.0/RV2V1
  63       COTB=RV2V1
  64       BETA=ATAN(1.0/RV2V1)
  65       DSA=SIN(ALFAH)
  66       DCA=COS(ALFAH)
  67       DSB=SIN(BETA)
  68       DCB=COS(BETA)
  69       SIN2B=2.0*DSB*DCB
  70 C
  71 C      Set A-terms.
  72 C      (all A-terms are assumed to be real)
  73 C      The A-terms are loaded into the array ATERM(12)
  74 C      in the following way:
  75 C          ATERM(1)=selectron A-term
  76 C          ATERM(2)=smuon A-term
  77 C          ATERM(3)=stau A-term
  78 C          ATERM(4)=up squark A-term
  79 C          ATERM(5)=charm squark A-term
  80 C          ATERM(6)=down squark A-term
  81 C          ATERM(7)=strange squark A-term
  82 C          ATERM(8)=sbottom A-term
  83 C          ATERM(9)=stop A-term
  84 C          ATERM(10)=selectronic sneutrino A-term
  85 C          ATERM(11)=smuonic sneutrino A-term
  86 C          ATERM(12)=stauonic sneutrino A-term
  87 C
  88       DO 10 II=1,7
  89         ATERM(II)=0.0
  90 10    CONTINUE
  91       ATERM(3)=AAL
  92       ATERM(8)=AAB
  93       ATERM(9)=AAT
  94       DO 20 II=10,12
  95         ATERM(II)=0.0
  96 20    CONTINUE
  97 C
  98 C      Set mixing parameters.
  99 C      The intra-flavor-mixed sfermion masses are loaded into
 100 C      the array MSFMIX(12,2) where (#,1) is the lighter
 101 C      mixed sfermion mass of a given flavor and (#,2) is the
 102 C      heavier sfermion mass.  The sfermionic mixing angles are
 103 C      loaded into the array THETSF(12).  The identities of the
 104 C      elements of these arrays are given below:
 105 C        MSFMIX(1,*)=mixed selectron masses
 106 C                                 THETSF(1)=selectron mixing angle
 107 C        MSFMIX(2,*)=mixed smuon masses
 108 C                                 THETSF(2)=smuon mixing angle
 109 C        MSFMIX(3,*)=mixed stau masses
 110 C                                 THETSF(3)=stau mixing angle
 111 C        MSFMIX(4,*)=mixed up squark masses
 112 C                                 THETSF(4)=up squark mixing angle
 113 C        MSFMIX(5,*)=mixed charm squark masses
 114 C                                 THETSF(5)=charm squark mixing angle
 115 C        MSFMIX(6,*)=mixed down squark masses
 116 C                                 THETSF(6)=down squark mixing angle
 117 C        MSFMIX(7,*)=mixed strange squark masses
 118 C                                 THETSF(7)=strange squark mixing angle
 119 C        MSFMIX(8,*)=mixed sbottom masses
 120 C                                 THETSF(8)=sbottom mixing angle
 121 C        MSFMIX(9,*)=mixed stop masses
 122 C                                 THETSF(9)=stop mixing angle
 123 C        For sneuterinos MSFMIX(#,2)=0.0, THETSF(#)=0.0 ; #=10-12
 124 C        Yukawa contributions from D-terms to the sneutrino masses
 125 C        are supposed to be added in here.
 126 C        MSFMIX(10,1)= selectronic sneutrino mass with D-terms
 127 C        MSFMIX(11,1)= smuonic sneutrino mass with D-terms
 128 C        MSFMIX(12,1)= stauonic sneutrino mass with D-terms
 129 C
 130       DO 30 II=10,12
 131         MSFMIX(II,2)=0.0
 132         THETSF(II)=0.0
 133 30    CONTINUE
 134 C
 135 C
 136 C       (*@&*) 10/24/93 - Special conditions used ---
 137 C        set all mixing angles EXCEPT stop, sbottom, stau to zero.
 138 C        For all EXCEPT st, sb and stau, set mixed sfermion masses
 139 C        to bare sfermion masses:
 140 C            MSFMIX(#,1) = Left sfermion mass
 141 C            MSFMIX(#,2) = Right sfermion mass  ;  # = 1-8
 142 C         but
 143 C            MSFMIX(9,1) = AMT1SS
 144 C            MSFMIX(9,2) = AMT2SS              , etc.
 145 C
 146 C        (The choice of which to call Left and which to call
 147 C         Right is based on the definition of the sfermion
 148 C         mixing angle theta_sf :
 149 C            sfermion_1 = cos(theta_sf) * sfermion_L
 150 C                            - sin(theta_sf) * sfermion_R
 151 C            sfermion_2 = sin(theta_sf) * sfermion_L
 152 C                            + cos(theta_sf) * sfermion_R
 153 C          Thus if we set theta_sf = 0, then
 154 C                 sfermion_1 = sfermion_L
 155 C           and   sfermion_2 = sfermion_R .               )
 156 C
 157       DO 40 II=1,7
 158         THETSF(II)=0.0
 159 40    CONTINUE
 160       MSFMIX(1,1)=AMELSS
 161       MSFMIX(1,2)=AMERSS
 162       MSFMIX(2,1)=AMMLSS
 163       MSFMIX(2,2)=AMMRSS
 164       MSFMIX(3,1)=AML1SS
 165       MSFMIX(3,2)=AML2SS
 166       THETSF(3)=THETAL
 167       MSFMIX(4,1)=AMULSS
 168       MSFMIX(4,2)=AMURSS
 169       MSFMIX(5,1)=AMCLSS
 170       MSFMIX(5,2)=AMCRSS
 171       MSFMIX(6,1)=AMDLSS
 172       MSFMIX(6,2)=AMDRSS
 173       MSFMIX(7,1)=AMSLSS
 174       MSFMIX(7,2)=AMSRSS
 175       MSFMIX(8,1)=AMB1SS
 176       MSFMIX(8,2)=AMB2SS
 177       THETSF(8)=THETAB
 178       MSFMIX(9,1)=AMT1SS
 179       MSFMIX(9,2)=AMT2SS
 180       THETSF(9)=THETAT
 181       MSFMIX(10,1)=AMN1SS
 182       MSFMIX(11,1)=AMN2SS
 183       MSFMIX(12,1)=AMN3SS
 184 C
 185       DO 1000 NUMH=1,4
 186         IF(NUMH.EQ.1) THEN
 187           MH=AMHL
 188         ELSE IF(NUMH.EQ.2) THEN
 189           MH=AMHH
 190         ELSE IF(NUMH.EQ.3) THEN
 191           MH=AMHA
 192           GO TO 233
 193         ELSE IF(NUMH.EQ.4) THEN
 194           MH=AMHC
 195           GO TO 333
 196         ENDIF
 197       ASMB=SUALFS(AMBT**2,.36,AMTP,3)
 198       MBMB=AMBT*(1.-4*ASMB/3./PI)
 199       MBQ=SSMQCD(DBLE(MBMB),DBLE(MH))
 200       ASMT=SUALFS(AMTP**2,.36,AMTP,3)
 201       MTMT=AMTP/(1.+4*ASMT/3./PI+(16.11-1.04*(5.-6.63/AMTP))*
 202      $(ASMT/PI)**2)
 203       MTQ=SSMQCD(DBLE(MTMT),DBLE(MH))
 204
 205 C
 206 C         Scalar neutral Higgses --> sfermions
 207 C          partial decay widths
 208 C
 209         IF(NUMH.EQ.1) THEN
 210           TEMP=GG*AMW*SIN(BETA-ALFAH)/2.0
 211           YA1=DCA
 212           YA2=DSA
 213         ELSE IF(NUMH.EQ.2) THEN
 214           TEMP=-GG*AMW*COS(BETA-ALFAH)/2.0
 215           YA1=-DSA
 216           YA2=DCA
 217         ENDIF
 218 C
 219         TEMP1=TEMP*(1.0-TW2/3.0)
 220         TEMP2=GG*YA1/(AMW*DSB)
 221         ASQ(4,1)=TEMP1-TEMP2*AMUP**2
 222         ASQ(5,1)=TEMP1-TEMP2*AMCH**2
 223         ASQ(9,1)=TEMP1-TEMP2*MTQ**2
 224 C
 225         TEMP1=-TEMP*(1.0+TW2/3.0)
 226         TEMP2=GG*YA2/(AMW*DCB)
 227         ASQ(6,1)=-TEMP1-TEMP2*AMDN**2
 228         ASQ(7,1)=-TEMP1-TEMP2*AMST**2
 229         ASQ(8,1)=-TEMP1-TEMP2*MBQ**2
 230 C
 231         ASQ(10,1)=TEMP*(1.0+TW2)
 232         TEMP1=TEMP*(TW2-1.0)
 233         TEMP2=GG*YA2/(AMW*DCB)
 234         ASQ(1,1)=TEMP1-TEMP2*AME**2
 235         ASQ(2,1)=TEMP1-TEMP2*AMMU**2
 236         ASQ(3,1)=TEMP1-TEMP2*AMTAU**2
 237 C
 238         TEMP1=4.0*TEMP*TW2/3.0
 239         TEMP2=GG*YA1/(AMW*DSB)
 240         ASQ(4,2)=TEMP1-TEMP2*AMUP**2
 241         ASQ(5,2)=TEMP1-TEMP2*AMCH**2
 242         ASQ(9,2)=TEMP1-TEMP2*MTQ**2
 243 C
 244         TEMP1=-2.0*TEMP*TW2/3.0
 245         TEMP2=GG*YA2/(AMW*DCB)
 246         ASQ(6,2)=TEMP1-TEMP2*AMDN**2
 247         ASQ(7,2)=TEMP1-TEMP2*AMST**2
 248         ASQ(8,2)=TEMP1-TEMP2*MBQ**2
 249 C
 250         ASQ(10,2)=0.0
 251         TEMP1=-2.0*TEMP*TW2
 252         TEMP2=GG*YA2/(AMW*DCB)
 253         ASQ(1,2)=TEMP1-TEMP2*AME**2
 254         ASQ(2,2)=TEMP1-TEMP2*AMMU**2
 255         ASQ(3,2)=TEMP1-TEMP2*AMTAU**2
 256 C
 257         TEMP1=GG/(2.0*AMW*DSB)
 258         ASQ(4,3)=(EP*YA2 + ATERM(4)*YA1)*TEMP1*AMUP
 259         ASQ(5,3)=(EP*YA2 + ATERM(5)*YA1)*TEMP1*AMCH
 260         ASQ(9,3)=(EP*YA2 + ATERM(9)*YA1)*TEMP1*MTQ
 261 C
 262         TEMP1=GG/(2.0*AMW*DCB)
 263         ASQ(6,3)=(ATERM(6)*YA2 + EP*YA1)*TEMP1*AMDN
 264         ASQ(7,3)=(ATERM(7)*YA2 + EP*YA1)*TEMP1*AMST
 265         ASQ(8,3)=(ATERM(8)*YA2 + EP*YA1)*TEMP1*MBQ
 266 C
 267         ASQ(10,3)=0.0
 268         ASQ(1,3)=(ATERM(1)*YA2 + EP*YA1)*TEMP1*AME
 269         ASQ(2,3)=(ATERM(2)*YA2 + EP*YA1)*TEMP1*AMMU
 270         ASQ(3,3)=(ATERM(3)*YA2 + EP*YA1)*TEMP1*AMTAU
 271 C
 272 C
 273         DO 150 IJ=1,9
 274           IF(IJ.LT.4) THEN
 275             TEMP1=1.0/(16.0*PI*MH**3)
 276           ELSE
 277             TEMP1=3.0/(16.0*PI*MH**3)
 278           ENDIF
 279           SINA=SIN(THETSF(IJ))
 280           COSA=COS(THETSF(IJ))
 281           SINA2=SINA**2
 282           COSA2=COSA**2
 283           M1=MSFMIX(IJ,1)
 284           M2=MSFMIX(IJ,1)
 285           M12=M1+M2
 286           IF(MH.GT.M12) THEN
 287             A11=ASQ(IJ,1)*COSA2+ASQ(IJ,2)*SINA2
 288      $              -2.0*ASQ(IJ,3)*SINA*COSA
 289             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 290             DWSF(IJ,1)=TEMP1*SQRT(LAMB)*A11**2
 291           ELSE IF(MH.LE.M12) THEN
 292             DWSF(IJ,1)=0.0
 293           ENDIF
 294 C
 295           M1=MSFMIX(IJ,2)
 296           M2=MSFMIX(IJ,2)
 297           M12=M1+M2
 298           IF(MH.GT.M12) THEN
 299             A22=ASQ(IJ,1)*SINA2+ASQ(IJ,2)*COSA2
 300      $                 +2.0*ASQ(IJ,3)*SINA*COSA
 301             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 302             DWSF(IJ,2)=TEMP1*SQRT(LAMB)*A22**2
 303           ELSE IF(MH.LE.M12) THEN
 304             DWSF(IJ,2)=0.0
 305           ENDIF
 306 C
 307           M1=MSFMIX(IJ,1)
 308           M2=MSFMIX(IJ,2)
 309           M12=M1+M2
 310           IF(MH.GT.M12) THEN
 311             A12=(ASQ(IJ,1)-ASQ(IJ,2))*SINA*COSA
 312      $                +ASQ(IJ,3)*(COSA2-SINA2)
 313             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 314             DWSF(IJ,3)=TEMP1*SQRT(LAMB)*A12**2
 315           ELSE IF(MH.LE.M12) THEN
 316                DWSF(IJ,3)=0.0
 317           ENDIF
 318 C
 319           DWSF(IJ,4)=DWSF(IJ,3)
 320 C
 321           IF(NUMH.EQ.1) THEN
 322             DO 121 JJ=1,4
 323               DWSFL(IJ,JJ)=DWSF(IJ,JJ)
 324 121         CONTINUE
 325           ELSE IF(NUMH.EQ.2) THEN
 326             DO 122 JJ=1,4
 327               DWSFH(IJ,JJ)=DWSF(IJ,JJ)
 328 122         CONTINUE
 329           ENDIF
 330 C
 331 150     CONTINUE
 332 C
 333 C          Now take care of sneutrinos.
 334 C
 335         DO 155 IJ=10,12
 336           M1=MSFMIX(IJ,1)
 337           M2=MSFMIX(IJ,1)
 338           M12=M1+M2
 339           IF(MH.GT.M12) THEN
 340             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 341             DWSF(IJ,1)=SQRT(LAMB)*(ASQ(10,1))**2
 342      $                           /(16.0*PI*MH**3)
 343           ELSE IF(MH.LE.M12) THEN
 344             DWSF(IJ,1) = 0.0
 345           ENDIF
 346           DWSF(IJ,2)=0.0
 347           DWSF(IJ,3)=0.0
 348           DWSF(IJ,4)=0.0
 349           IF(NUMH.EQ.1) THEN
 350             DO 151 JJ=1,4
 351               DWSFL(IJ,JJ)=DWSF(IJ,JJ)
 352 151         CONTINUE
 353           ELSE IF(NUMH.EQ.2) THEN
 354             DO 152 JJ=1,4
 355               DWSFH(IJ,JJ)=DWSF(IJ,JJ)
 356 152         CONTINUE
 357           ENDIF
 358 C
 359 155     CONTINUE
 360         GO TO 1000
 361 C
 362 C
 363 C          Pseudocalar neutral Higgses --> sfermions
 364 C           partial decay widths
 365 C
 366 233     TEMP1=GG/(2.0*AMW)
 367         BSQ(1)=TEMP1*AME*(EP-TANB*ATERM(1))
 368         BSQ(2)=TEMP1*AMMU*(EP-TANB*ATERM(2))
 369         BSQ(3)=TEMP1*AMTAU*(EP-TANB*ATERM(3))
 370         BSQ(4)=TEMP1*AMUP*(EP-COTB*ATERM(4))
 371         BSQ(5)=TEMP1*AMCH*(EP-COTB*ATERM(5))
 372         BSQ(6)=TEMP1*AMDN*(EP-TANB*ATERM(6))
 373         BSQ(7)=TEMP1*AMST*(EP-TANB*ATERM(7))
 374         BSQ(8)=TEMP1*MBQ*(EP-TANB*ATERM(8))
 375         BSQ(9)=TEMP1*MTQ*(EP-COTB*ATERM(9))
 376 C
 377         DO 260 IJ=1,9
 378           IF(IJ.LT.4) THEN
 379             TEMP1=1.0/(16.0*PI*MH**3)
 380           ELSE
 381             TEMP1=3.0/(16.0*PI*MH**3)
 382           ENDIF
 383           SINA=SIN(THETSF(IJ))
 384           COSA=COS(THETSF(IJ))
 385           SINA2=SINA**2
 386           COSA2=COSA**2
 387           M1=MSFMIX(IJ,1)
 388           M2=MSFMIX(IJ,1)
 389           M12=M1+M2
 390           IF(MH.GT.M12) THEN
 391             B11=-2.0*COSA*SINA*BSQ(IJ)
 392             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 393             DWSFP(IJ,1)=TEMP1*SQRT(LAMB)*B11**2
 394           ELSE IF(MH.LE.M12) THEN
 395             DWSFP(IJ,1)=0.0
 396           ENDIF
 397 C
 398           M1=MSFMIX(IJ,2)
 399           M2=MSFMIX(IJ,2)
 400           M12=M1+M2
 401           IF(MH.GT.M12) THEN
 402             B22=-B11
 403             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 404             DWSFP(IJ,2)=TEMP1*SQRT(LAMB)*B22**2
 405           ELSE IF(MH.LE.M12) THEN
 406             DWSFP(IJ,2)=0.0
 407           ENDIF
 408           M1=MSFMIX(IJ,1)
 409           M2=MSFMIX(IJ,2)
 410           M12=M1+M2
 411           IF(MH.GT.M12) THEN
 412             B12=(COSA2-SINA2)*BSQ(IJ)
 413             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 414             DWSFP(IJ,3)=TEMP1*SQRT(LAMB)*B12**2
 415           ELSE IF(MH.LE.M12) THEN
 416             DWSFP(IJ,3)=0.0
 417           ENDIF
 418           DWSFP(IJ,4)=DWSFP(IJ,3)
 419 260     CONTINUE
 420         DO 265 IJ=10,12
 421            DO 264 JJ=1,4
 422              DWSFP(IJ,JJ)=0.0
 423 264        CONTINUE
 424 265     CONTINUE
 425         GO TO 1000
 426 C
 427 C          Charged Higgses --> sfermions
 428 C           partial decay widths
 429 C
 430 333     TEMP1=-AMW*SIN2B
 431         CSQ(1,1)=GG*(TEMP1+(TANB*AMDN**2 + COTB*AMUP**2)/AMW)/SR2
 432         CSQ(2,1)=GG*(TEMP1+(TANB*AMST**2 + COTB*AMCH**2)/AMW)/SR2
 433         CSQ(3,1)=GG*(TEMP1+(TANB*MBQ**2 + COTB*MTQ**2)/AMW)/SR2
 434         CSQ(4,1)=GG*(TEMP1 + (TANB*AME**2)/AMW)/SR2
 435         CSQ(5,1)=GG*(TEMP1 + (TANB*AMMU**2)/AMW)/SR2
 436         CSQ(6,1)=GG*(TEMP1 + (TANB*AMTAU**2)/AMW)/SR2
 437 C
 438         TEMP1=GG*(COTB+TANB)/(SR2*AMW)
 439         CSQ(1,2)=TEMP1*AMUP*AMDN
 440         CSQ(2,2)=TEMP1*AMCH*AMST
 441         CSQ(3,2)=TEMP1*MTQ*MBQ
 442         CSQ(4,2)=0.0
 443         CSQ(5,2)=0.0
 444         CSQ(6,2)=0.0
 445 C
 446         TEMP1=GG/(SR2*AMW)
 447         CSQ(1,3)=TEMP1*AMUP*(EP-COTB*ATERM(4))
 448         CSQ(2,3)=TEMP1*AMCH*(EP-COTB*ATERM(5))
 449         CSQ(3,3)=TEMP1*MTQ*(EP-COTB*ATERM(9))
 450         CSQ(4,3)=0.0
 451         CSQ(5,3)=0.0
 452         CSQ(6,3)=0.0
 453 C
 454         CSQ(1,4)=TEMP1* AMDN*(EP-TANB*ATERM(6))
 455         CSQ(2,4)=TEMP1* AMST*(EP-TANB*ATERM(7))
 456         CSQ(3,4)=TEMP1* MBQ*(EP-TANB*ATERM(8))
 457         CSQ(4,4)=TEMP1* AME*(EP-TANB*ATERM(1))
 458         CSQ(5,4)=TEMP1* AMMU*(EP-TANB*ATERM(2))
 459         CSQ(6,4)=TEMP1* AMTAU*(EP-TANB*ATERM(3))
 460 C
 461         DO 350 IC=1,3
 462           TEMP1=3.0/(16.0*PI*MH**3)
 463           IF(IC.EQ.1) THEN
 464             IJU=4
 465             IJD=6
 466           ELSE IF(IC.EQ.2) THEN
 467             IJU=5
 468             IJD=7
 469           ELSE IF(IC.EQ.3) THEN
 470             IJU=9
 471             IJD=8
 472           ENDIF
 473           SINAU=SIN(THETSF(IJU))
 474           COSAU=COS(THETSF(IJU))
 475           SINAD=SIN(THETSF(IJD))
 476           COSAD=COS(THETSF(IJD))
 477 C
 478           M1=MSFMIX(IJU,1)
 479           M2=MSFMIX(IJD,1)
 480           M12=M1+M2
 481           IF(MH.GT.M12) THEN
 482             C11=COSAU*COSAD*CSQ(IC,1)
 483      $            + SINAU*SINAD*CSQ(IC,2)
 484      $                - SINAU*COSAD*CSQ(IC,3)
 485      $                    - COSAU*SINAD*CSQ(IC,4)
 486             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 487             DWSFC(IC,1)=TEMP1*SQRT(LAMB)*C11**2
 488           ELSE IF(MH.LE.M12) THEN
 489             DWSFC(IC,1) = 0.0
 490           ENDIF
 491 C
 492           M1=MSFMIX(IJU,1)
 493           M2=MSFMIX(IJD,2)
 494           M12=M1+M2
 495           IF(MH.GT.M12) THEN
 496             C12=COSAU*SINAD*CSQ(IC,1)
 497      $            - SINAU*COSAD*CSQ(IC,2)
 498      $                - SINAU*SINAD*CSQ(IC,3)
 499      $                    + COSAU*COSAD*CSQ(IC,4)
 500             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 501             DWSFC(IC,2)=TEMP1*SQRT(LAMB)*C12**2
 502           ELSE IF(MH.LE.M12) THEN
 503             DWSFC(IC,2)=0.0
 504           ENDIF
 505 C
 506           M1=MSFMIX(IJU,2)
 507           M2=MSFMIX(IJD,1)
 508           M12=M1+M2
 509           IF(MH.GT.M12) THEN
 510             C21=SINAU*COSAD*CSQ(IC,1)
 511      $            - COSAU*SINAD*CSQ(IC,2)
 512      $                + COSAU*COSAD*CSQ(IC,3)
 513      $                    - SINAU*SINAD*CSQ(IC,4)
 514             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 515             DWSFC(IC,3)=TEMP1*SQRT(LAMB)*C21**2
 516           ELSE IF(MH.LE.M12) THEN
 517             DWSFC(IC,3)=0.0
 518           ENDIF
 519 C
 520           M1=MSFMIX(IJU,2)
 521           M2=MSFMIX(IJD,2)
 522           M12=M1+M2
 523           IF(MH.GT.M12) THEN
 524             C22=SINAU*SINAD*CSQ(IC,1)
 525      $            + COSAU*COSAD*CSQ(IC,2)
 526      $                + COSAU*SINAD*CSQ(IC,3)
 527      $                    - SINAU*COSAD*CSQ(IC,4)
 528             LAMB=SSXLAM(MH**2,M1**2,M2**2)
 529             DWSFC(IC,4)=TEMP1*SQRT(LAMB)*C22**2
 530           ELSE IF(MH.LE.M12) THEN
 531             DWSFC(IC,4)=0.0
 532           ENDIF
 533 C
 534 350     CONTINUE
 535 C
 536 C
 537 C         Now calculate the sleptonic
 538 C          partial decay widths of the
 539 C          charged Higgs.
 540 C
 541         DO 355 IC = 4,6
 542           TEMP1=1.0/(16.0*PI*MH**3)
 543             IF(IC.EQ.4) THEN
 544               IJU=10
 545               IJD=1
 546             ELSE IF(IC.EQ.5) THEN
 547               IJU=11
 548               IJD=2
 549             ELSE IF(IC.EQ.6) THEN
 550               IJU=12
 551               IJD=3
 552             ENDIF
 553             SINAD=SIN(THETSF(IJD))
 554             COSAD=COS(THETSF(IJD))
 555 C
 556             M1=MSFMIX(IJU,1)
 557             M2=MSFMIX(IJD,1)
 558             M12=M1+M2
 559             IF(MH.GT.M12) THEN
 560               C11=COSAD*CSQ(IC,1)-SINAD*CSQ(IC,4)
 561               LAMB=SSXLAM(MH**2,M1**2,M2**2)
 562               DWSFC(IC,1)=TEMP1*SQRT(LAMB)*C11**2
 563             ELSE IF(MH.LE.M12) THEN
 564               DWSFC(IC,1)=0.0
 565             ENDIF
 566 C
 567             M1=MSFMIX(IJU,1)
 568             M2=MSFMIX(IJD,2)
 569             M12=M1+M2
 570             IF(MH.GT.M12) THEN
 571               C12=SINAD*CSQ(IC,1)+COSAD*CSQ(IC,4)
 572               LAMB=SSXLAM(MH**2,M1**2,M2**2)
 573               DWSFC(IC,2)=TEMP1*SQRT(LAMB)*C12**2
 574             ELSE IF(MH.LE.M12) THEN
 575               DWSFC(IC,2)=0.0
 576             ENDIF
 577             DWSFC(IC,3)=0.0
 578             DWSFC(IC,4)=0.0
 579 355     CONTINUE
 580 1000  CONTINUE
 581 C          H_l decays
 582       CALL SSSAVE(ISHL,DWSFL(1,1),ISEL,-ISEL,0,0,0)
 583       CALL SSSAVE(ISHL,DWSFL(1,2),ISER,-ISER,0,0,0)
 584       CALL SSSAVE(ISHL,DWSFL(2,1),ISMUL,-ISMUL,0,0,0)
 585       CALL SSSAVE(ISHL,DWSFL(2,2),ISMUR,-ISMUR,0,0,0)
 586       CALL SSSAVE(ISHL,DWSFL(3,1),ISTAU1,-ISTAU1,0,0,0)
 587       CALL SSSAVE(ISHL,DWSFL(3,2),ISTAU2,-ISTAU2,0,0,0)
 588       CALL SSSAVE(ISHL,DWSFL(3,3),ISTAU1,-ISTAU2,0,0,0)
 589       CALL SSSAVE(ISHL,DWSFL(3,4),ISTAU2,-ISTAU1,0,0,0)
 590       CALL SSSAVE(ISHL,DWSFL(4,1),ISUPL,-ISUPL,0,0,0)
 591       CALL SSSAVE(ISHL,DWSFL(4,2),ISUPR,-ISUPR,0,0,0)
 592       CALL SSSAVE(ISHL,DWSFL(5,1),ISCHL,-ISCHL,0,0,0)
 593       CALL SSSAVE(ISHL,DWSFL(5,2),ISCHR,-ISCHR,0,0,0)
 594       CALL SSSAVE(ISHL,DWSFL(6,1),ISDNL,-ISDNL,0,0,0)
 595       CALL SSSAVE(ISHL,DWSFL(6,2),ISDNR,-ISDNR,0,0,0)
 596       CALL SSSAVE(ISHL,DWSFL(7,1),ISSTL,-ISSTL,0,0,0)
 597       CALL SSSAVE(ISHL,DWSFL(7,2),ISSTR,-ISSTR,0,0,0)
 598       CALL SSSAVE(ISHL,DWSFL(8,1),ISBT1,-ISBT1,0,0,0)
 599       CALL SSSAVE(ISHL,DWSFL(8,2),ISBT2,-ISBT2,0,0,0)
 600       CALL SSSAVE(ISHL,DWSFL(8,3),ISBT1,-ISBT2,0,0,0)
 601       CALL SSSAVE(ISHL,DWSFL(8,4),ISBT2,-ISBT1,0,0,0)
 602       CALL SSSAVE(ISHL,DWSFL(9,1),ISTP1,-ISTP1,0,0,0)
 603       CALL SSSAVE(ISHL,DWSFL(9,2),ISTP2,-ISTP2,0,0,0)
 604       CALL SSSAVE(ISHL,DWSFL(9,3),ISTP1,-ISTP2,0,0,0)
 605       CALL SSSAVE(ISHL,DWSFL(9,4),ISTP2,-ISTP1,0,0,0)
 606       CALL SSSAVE(ISHL,DWSFL(10,1),ISNEL,-ISNEL,0,0,0)
 607       CALL SSSAVE(ISHL,DWSFL(11,1),ISNML,-ISNML,0,0,0)
 608       CALL SSSAVE(ISHL,DWSFL(12,1),ISNTL,-ISNTL,0,0,0)
 609 C         H_h decays
 610       CALL SSSAVE(ISHH,DWSFH(1,1),ISEL,-ISEL,0,0,0)
 611       CALL SSSAVE(ISHH,DWSFH(1,2),ISER,-ISER,0,0,0)
 612       CALL SSSAVE(ISHH,DWSFH(2,1),ISMUL,-ISMUL,0,0,0)
 613       CALL SSSAVE(ISHH,DWSFH(2,2),ISMUR,-ISMUR,0,0,0)
 614       CALL SSSAVE(ISHH,DWSFH(3,1),ISTAU1,-ISTAU1,0,0,0)
 615       CALL SSSAVE(ISHH,DWSFH(3,2),ISTAU2,-ISTAU2,0,0,0)
 616       CALL SSSAVE(ISHH,DWSFH(3,3),ISTAU1,-ISTAU2,0,0,0)
 617       CALL SSSAVE(ISHH,DWSFH(3,4),ISTAU2,-ISTAU1,0,0,0)
 618       CALL SSSAVE(ISHH,DWSFH(4,1),ISUPL,-ISUPL,0,0,0)
 619       CALL SSSAVE(ISHH,DWSFH(4,2),ISUPR,-ISUPR,0,0,0)
 620       CALL SSSAVE(ISHH,DWSFH(5,1),ISCHL,-ISCHL,0,0,0)
 621       CALL SSSAVE(ISHH,DWSFH(5,2),ISCHR,-ISCHR,0,0,0)
 622       CALL SSSAVE(ISHH,DWSFH(6,1),ISDNL,-ISDNL,0,0,0)
 623       CALL SSSAVE(ISHH,DWSFH(6,2),ISDNR,-ISDNR,0,0,0)
 624       CALL SSSAVE(ISHH,DWSFH(7,1),ISSTL,-ISSTL,0,0,0)
 625       CALL SSSAVE(ISHH,DWSFH(7,2),ISSTR,-ISSTR,0,0,0)
 626       CALL SSSAVE(ISHH,DWSFH(8,1),ISBT1,-ISBT1,0,0,0)
 627       CALL SSSAVE(ISHH,DWSFH(8,2),ISBT2,-ISBT2,0,0,0)
 628       CALL SSSAVE(ISHH,DWSFH(8,3),ISBT1,-ISBT2,0,0,0)
 629       CALL SSSAVE(ISHH,DWSFH(8,4),ISBT2,-ISBT1,0,0,0)
 630       CALL SSSAVE(ISHH,DWSFH(9,1),ISTP1,-ISTP1,0,0,0)
 631       CALL SSSAVE(ISHH,DWSFH(9,2),ISTP2,-ISTP2,0,0,0)
 632       CALL SSSAVE(ISHH,DWSFH(9,3),ISTP1,-ISTP2,0,0,0)
 633       CALL SSSAVE(ISHH,DWSFH(9,4),ISTP2,-ISTP1,0,0,0)
 634       CALL SSSAVE(ISHH,DWSFH(10,1),ISNEL,-ISNEL,0,0,0)
 635       CALL SSSAVE(ISHH,DWSFH(11,1),ISNML,-ISNML,0,0,0)
 636       CALL SSSAVE(ISHH,DWSFH(12,1),ISNTL,-ISNTL,0,0,0)
 637 C          Decay of H_p
 638       CALL SSSAVE(ISHA,DWSFP(1,3),ISEL,-ISER,0,0,0)
 639       CALL SSSAVE(ISHA,DWSFP(1,4),ISER,-ISEL,0,0,0)
 640       CALL SSSAVE(ISHA,DWSFP(2,3),ISMUL,-ISMUR,0,0,0)
 641       CALL SSSAVE(ISHA,DWSFP(2,4),ISMUR,-ISMUL,0,0,0)
 642       CALL SSSAVE(ISHA,DWSFP(3,1),ISTAU1,-ISTAU1,0,0,0)
 643       CALL SSSAVE(ISHA,DWSFP(3,2),ISTAU2,-ISTAU2,0,0,0)
 644       CALL SSSAVE(ISHA,DWSFP(3,3),ISTAU1,-ISTAU2,0,0,0)
 645       CALL SSSAVE(ISHA,DWSFP(3,4),ISTAU2,-ISTAU1,0,0,0)
 646       CALL SSSAVE(ISHA,DWSFP(4,3),ISUPL,-ISUPR,0,0,0)
 647       CALL SSSAVE(ISHA,DWSFP(4,4),ISUPR,-ISUPL,0,0,0)
 648       CALL SSSAVE(ISHA,DWSFP(5,3),ISCHL,-ISCHR,0,0,0)
 649       CALL SSSAVE(ISHA,DWSFP(5,4),ISCHR,-ISCHL,0,0,0)
 650       CALL SSSAVE(ISHA,DWSFP(6,3),ISDNL,-ISDNR,0,0,0)
 651       CALL SSSAVE(ISHA,DWSFP(6,4),ISDNR,-ISDNL,0,0,0)
 652       CALL SSSAVE(ISHA,DWSFP(7,3),ISSTL,-ISSTR,0,0,0)
 653       CALL SSSAVE(ISHA,DWSFP(7,4),ISSTR,-ISSTL,0,0,0)
 654       CALL SSSAVE(ISHA,DWSFP(8,1),ISBT1,-ISBT1,0,0,0)
 655       CALL SSSAVE(ISHA,DWSFP(8,2),ISBT2,-ISBT2,0,0,0)
 656       CALL SSSAVE(ISHA,DWSFP(8,3),ISBT1,-ISBT2,0,0,0)
 657       CALL SSSAVE(ISHA,DWSFP(8,4),ISBT2,-ISBT1,0,0,0)
 658       CALL SSSAVE(ISHA,DWSFP(9,1),ISTP1,-ISTP1,0,0,0)
 659       CALL SSSAVE(ISHA,DWSFP(9,2),ISTP2,-ISTP2,0,0,0)
 660       CALL SSSAVE(ISHA,DWSFP(9,3),ISTP1,-ISTP2,0,0,0)
 661       CALL SSSAVE(ISHA,DWSFP(9,4),ISTP2,-ISTP1,0,0,0)
 662 C          Decay of H+
 663       CALL SSSAVE(ISHC,DWSFC(1,1),ISUPL,-ISDNL,0,0,0)
 664       CALL SSSAVE(ISHC,DWSFC(1,2),ISUPR,-ISDNR,0,0,0)
 665       CALL SSSAVE(ISHC,DWSFC(2,1),ISCHL,-ISSTL,0,0,0)
 666       CALL SSSAVE(ISHC,DWSFC(2,2),ISCHR,-ISSTR,0,0,0)
 667       CALL SSSAVE(ISHC,DWSFC(3,1),ISTP1,-ISBT1,0,0,0)
 668       CALL SSSAVE(ISHC,DWSFC(3,2),ISTP1,-ISBT2,0,0,0)
 669       CALL SSSAVE(ISHC,DWSFC(3,3),ISTP2,-ISBT1,0,0,0)
 670       CALL SSSAVE(ISHC,DWSFC(3,4),ISTP2,-ISBT2,0,0,0)
 671       CALL SSSAVE(ISHC,DWSFC(4,1),-ISEL,ISNEL,0,0,0)
 672       CALL SSSAVE(ISHC,DWSFC(5,1),-ISMUL,ISNML,0,0,0)
 673       CALL SSSAVE(ISHC,DWSFC(6,1),-ISTAU1,ISNTL,0,0,0)
 674       CALL SSSAVE(ISHC,DWSFC(6,2),-ISTAU2,ISNTL,0,0,0)
 675       RETURN
 676       END