ISAJET/isasusy/ssqkbf.F

   1 #include "isajet/pilot.h"
   2         SUBROUTINE SSQKBF
   3 C-----------------------------------------------------------------------
   4 C
   5 C        This program gives squark branching fractions to gauginos
   6 C        according to Baer,Barger,Karatas,Tata (Phys.Rev.D36,96(1987)
   7 C        Updated for b_1,b_2 and non-degenerate sq masses 8/13/96
   8 C        Baer's SQUBF
   9 C
  10 C-----------------------------------------------------------------------
  11 #if defined(CERNLIB_IMPNONE)
  12       IMPLICIT NONE
  13 #endif
  14 #include "isajet/sslun.inc"
  15 #include "isajet/ssmode.inc"
  16 #include "isajet/sssm.inc"
  17 #include "isajet/sspar.inc"
  18 #include "isajet/sstype.inc"
  19 C
  20       COMPLEX ZI,ZONE,ZA,ZB,ZAUIZ,ZADIZ,ZBUIZ,ZBDIZ
  21       DOUBLE PRECISION SSALFS,SSMQCD
  22       REAL SSXLAM,WID,AUIZS,ADIZS,BUIZS,BDIZS
  23       REAL PI,SR2,G,GP,COSA,SINA,SNZI,THIZ
  24      $,TANB,COTB,XM,YM,THX,THY,FT,FB
  25       REAL MZIZ,CS2THW,TN2THW,BETA,BH,A,AS
  26       REAL ASMB,MBMB,MBQ,ASMT,MTMT,MTQ,SUALFS
  27       INTEGER IZ
  28       REAL MW1,MW2,SNW1,SNW2,COST,SINT,COSB,SINB
  29       REAL AWD(2),AWU(2),BW(2),BWP(2)
  30       INTEGER ISZIZ(4)
  31       DATA ZI/(0.,1.)/,ZONE/(1.,0.)/
  32 C
  33 C          Partly duplicated from SSMASS
  34 C
  35       PI=4.*ATAN(1.)
  36       SR2=SQRT(2.)
  37       G=SQRT(4*PI*ALFAEM/SN2THW)
  38       GP=G*SQRT(SN2THW/(1.-SN2THW))
  39       CS2THW=1.-SN2THW
  40       TN2THW=SN2THW/CS2THW
  41       TANB=1./RV2V1
  42       COTB=RV2V1
  43       BETA=ATAN(TANB)
  44 C          Reconstruct masses from SSMASS
  45       MW1=ABS(AMW1SS)
  46       MW2=ABS(AMW2SS)
  47       COST=COS(THETAT)
  48       SINT=SIN(THETAT)
  49       COSB=COS(THETAB)
  50       SINB=SIN(THETAB)
  51       COSA=COS(ALFAH)
  52       SINA=SIN(ALFAH)
  53       SNW1=SIGN(1.,AMW1SS)
  54       SNW2=SIGN(1.,AMW2SS)
  55       XM=1./TAN(GAMMAL)
  56       YM=1./TAN(GAMMAR)
  57       THX=SIGN(1.,XM)
  58       THY=SIGN(1.,YM)
  59       ASMB=SUALFS(AMBT**2,.36,AMTP,3)
  60       MBMB=AMBT*(1.-4*ASMB/3./PI)
  61       MBQ=SSMQCD(DBLE(MBMB),DBLE(AMULSS))
  62       ASMT=SUALFS(AMTP**2,.36,AMTP,3)
  63       MTMT=AMTP/(1.+4*ASMT/3./PI+(16.11-1.04*(5.-6.63/AMTP))*
  64      $(ASMT/PI)**2)
  65       MTQ=SSMQCD(DBLE(MTMT),DBLE(AMULSS))
  66       FB=G*MBQ/SR2/AMW/COS(BETA)
  67       FT=G*MTQ/SR2/AMW/SIN(BETA)
  68       AWD(1)=-G*SNW1*SIN(GAMMAR)
  69       AWD(2)=-G*SNW2*THY*COS(GAMMAR)
  70       AWU(1)=-G*SIN(GAMMAL)
  71       AWU(2)=-G*THX*COS(GAMMAL)
  72       BW(1)=-FT*SNW1*COS(GAMMAR)
  73       BW(2)=FT*SNW2*THY*SIN(GAMMAR)
  74       BWP(1)=-FB*COS(GAMMAL)
  75       BWP(2)=FB*THX*SIN(GAMMAL)
  76 C
  77 C          Compute squark branching fractions to zi
  78 C
  79       ISZIZ(1)=ISZ1
  80       ISZIZ(2)=ISZ2
  81       ISZIZ(3)=ISZ3
  82       ISZIZ(4)=ISZ4
  83       DO 100 IZ=1,4
  84         MZIZ=ABS(AMZISS(IZ))
  85         SNZI=SIGN(1.,AMZISS(IZ))
  86         IF (SNZI.EQ.1.) THEN
  87            THIZ=0.
  88         ELSE
  89            THIZ=1.
  90         END IF
  91         ZAUIZ=ZI**(THIZ-1.)*(-1)*SNZI
  92      $  *(G/SR2*ZMIXSS(3,IZ)+GP/3./SR2*ZMIXSS(4,IZ))
  93         ZBUIZ=ZI**(THIZ-1.)*4*GP*ZMIXSS(4,IZ)/3./SR2
  94         ZADIZ=ZI**(THIZ-1.)*(-1)*SNZI
  95      $  *(-G/SR2*ZMIXSS(3,IZ)+GP/3./SR2*ZMIXSS(4,IZ))
  96         ZBDIZ=ZI**(THIZ-1.)*(-2)*GP*ZMIXSS(4,IZ)/3./SR2
  97         AUIZS=ZAUIZ*CONJG(ZAUIZ)
  98         ADIZS=ZADIZ*CONJG(ZADIZ)
  99         BUIZS=ZBUIZ*CONJG(ZBUIZ)
 100         BDIZS=ZBDIZ*CONJG(ZBDIZ)
 101 C          squark --> q + qb + zi, q = u, d, s
 102         IF (AMULSS.GT.MZIZ) THEN
 103           WID=AUIZS*AMULSS*(1.-MZIZ**2/AMULSS**2)**2/16./PI
 104           CALL SSSAVE(ISUPL,WID,ISZIZ(IZ),IDUP,0,0,0)
 105         END IF
 106         IF (AMDLSS.GT.MZIZ) THEN
 107           WID=ADIZS*AMDLSS*(1.-MZIZ**2/AMDLSS**2)**2/16./PI
 108           CALL SSSAVE(ISDNL,WID,ISZIZ(IZ),IDDN,0,0,0)
 109         END IF
 110         IF (AMSLSS.GT.MZIZ) THEN
 111           WID=ADIZS*AMSLSS*(1.-MZIZ**2/AMSLSS**2)**2/16./PI
 112           CALL SSSAVE(ISSTL,WID,ISZIZ(IZ),IDST,0,0,0)
 113         END IF
 114         IF (AMURSS.GT.MZIZ) THEN
 115           WID=BUIZS*AMURSS*(1.-MZIZ**2/AMURSS**2)**2/16./PI
 116           CALL SSSAVE(ISUPR,WID,ISZIZ(IZ),IDUP,0,0,0)
 117         END IF
 118         IF (AMDRSS.GT.MZIZ) THEN
 119           WID=BDIZS*AMDRSS*(1.-MZIZ**2/AMDRSS**2)**2/16./PI
 120           CALL SSSAVE(ISDNR,WID,ISZIZ(IZ),IDDN,0,0,0)
 121         END IF
 122         IF (AMSRSS.GT.MZIZ) THEN
 123           WID=BDIZS*AMSRSS*(1.-MZIZ**2/AMSRSS**2)**2/16./PI
 124           CALL SSSAVE(ISSTR,WID,ISZIZ(IZ),IDST,0,0,0)
 125         END IF
 126 C          squark --> q + zi, q = c
 127         IF (AMCLSS.GT.(MZIZ+AMCH)) THEN
 128           WID=AUIZS*AMCLSS*(1.-MZIZ**2/AMCLSS**2-AMCH**2/AMCLSS**2)
 129      $    *SQRT(SSXLAM(1.,MZIZ**2/AMCLSS**2,AMCH**2/AMCLSS**2))/16./PI
 130           CALL SSSAVE(ISCHL,WID,ISZIZ(IZ),IDCH,0,0,0)
 131         END IF
 132         IF (AMCRSS.GT.(MZIZ+AMCH)) THEN
 133           WID=BUIZS*AMCRSS*(1.-MZIZ**2/AMCRSS**2-AMCH**2/AMCRSS**2)
 134      $    *SQRT(SSXLAM(1.,MZIZ**2/AMCRSS**2,AMCH**2/AMCRSS**2))/16./PI
 135           CALL SSSAVE(ISCHR,WID,ISZIZ(IZ),IDCH,0,0,0)
 136         END IF
 137 C          sbottom_1 --> b + zi
 138         IF (AMB1SS.GT.(MZIZ+AMBT)) THEN
 139           ZA=(ZI*ZADIZ-FB*ZMIXSS(2,IZ)*ZI**THIZ)*COSB/2.-
 140      $       (ZI*ZBDIZ-FB*ZMIXSS(2,IZ)*(-ZI)**THIZ)*SINB/2.
 141           ZB=(-ZI*ZADIZ-FB*ZMIXSS(2,IZ)*ZI**THIZ)*COSB/2.-
 142      $       (ZI*ZBDIZ+FB*ZMIXSS(2,IZ)*(-ZI)**THIZ)*SINB/2.
 143           WID=(ZA*CONJG(ZA)*(AMB1SS**2-(AMBT+MZIZ)**2)+
 144      $     ZB*CONJG(ZB)*(AMB1SS**2-(MZIZ-AMBT)**2))/8./PI/AMB1SS
 145      $    *SQRT(SSXLAM(1.,MZIZ**2/AMB1SS**2,AMBT**2/AMB1SS**2))
 146           CALL SSSAVE(ISBT1,WID,ISZIZ(IZ),IDBT,0,0,0)
 147         END IF
 148 C          sbottom_2 --> b + zi
 149         IF (AMB2SS.GT.(MZIZ+AMBT)) THEN
 150           ZA=(ZI*ZADIZ-FB*ZMIXSS(2,IZ)*ZI**THIZ)*SINB/2.+
 151      $       (ZI*ZBDIZ-FB*ZMIXSS(2,IZ)*(-ZI)**THIZ)*COSB/2.
 152           ZB=(-ZI*ZADIZ-FB*ZMIXSS(2,IZ)*ZI**THIZ)*SINB/2.+
 153      $       (ZI*ZBDIZ+FB*ZMIXSS(2,IZ)*(-ZI)**THIZ)*COSB/2.
 154           WID=(ZA*CONJG(ZA)*(AMB2SS**2-(AMBT+MZIZ)**2)+
 155      $     ZB*CONJG(ZB)*(AMB2SS**2-(MZIZ-AMBT)**2))/8./PI/AMB2SS
 156      $    *SQRT(SSXLAM(1.,MZIZ**2/AMB2SS**2,AMBT**2/AMB2SS**2))
 157           CALL SSSAVE(ISBT2,WID,ISZIZ(IZ),IDBT,0,0,0)
 158         END IF
 159 100   CONTINUE
 160 C
 161 C          Compute squark branching fractions to gluinos
 162 C
 163       IF (AMULSS.GT.AMGLSS) THEN
 164         WID=2*SSALFS(DBLE(AMULSS**2))*AMULSS*
 165      $  (1.-AMGLSS**2/AMULSS**2)**2/3.
 166         CALL SSSAVE(ISUPL,WID,ISGL,IDUP,0,0,0)
 167       END IF
 168       IF (AMDLSS.GT.AMGLSS) THEN
 169         WID=2*SSALFS(DBLE(AMDLSS**2))*AMDLSS*
 170      $  (1.-AMGLSS**2/AMDLSS**2)**2/3.
 171         CALL SSSAVE(ISDNL,WID,ISGL,IDDN,0,0,0)
 172       END IF
 173       IF (AMSLSS.GT.AMGLSS) THEN
 174         WID=2*SSALFS(DBLE(AMSLSS**2))*AMSLSS*
 175      $  (1.-AMGLSS**2/AMSLSS**2)**2/3.
 176         CALL SSSAVE(ISSTL,WID,ISGL,IDST,0,0,0)
 177       END IF
 178       IF (AMURSS.GT.AMGLSS) THEN
 179         WID=2*SSALFS(DBLE(AMURSS**2))*AMURSS*
 180      $  (1.-AMGLSS**2/AMURSS**2)**2/3.
 181         CALL SSSAVE(ISUPR,WID,ISGL,IDUP,0,0,0)
 182       END IF
 183       IF (AMDRSS.GT.AMGLSS) THEN
 184         WID=2*SSALFS(DBLE(AMDRSS**2))*AMDRSS*
 185      $  (1.-AMGLSS**2/AMDRSS**2)**2/3.
 186         CALL SSSAVE(ISDNR,WID,ISGL,IDDN,0,0,0)
 187       END IF
 188       IF (AMSRSS.GT.AMGLSS) THEN
 189         WID=2*SSALFS(DBLE(AMSRSS**2))*AMSRSS*
 190      $  (1.-AMGLSS**2/AMSRSS**2)**2/3.
 191         CALL SSSAVE(ISSTR,WID,ISGL,IDST,0,0,0)
 192       END IF
 193 C
 194       IF (AMCLSS.GT.(AMGLSS+AMCH)) THEN
 195         WID=2*SSALFS(DBLE(AMCLSS**2))*AMCLSS*(1.-AMGLSS**2/AMCLSS**2-
 196      $  AMCH**2/AMCLSS**2)*SQRT(SSXLAM(1.,AMGLSS**2/AMCLSS**2,
 197      $  AMCH**2/AMCLSS**2))/3.
 198         CALL SSSAVE(ISCHL,WID,ISGL,IDCH,0,0,0)
 199       END IF
 200       IF (AMCRSS.GT.(AMGLSS+AMCH)) THEN
 201         WID=2*SSALFS(DBLE(AMCRSS**2))*AMCRSS*(1.-AMGLSS**2/AMCRSS**2-
 202      $  AMCH**2/AMCRSS**2)*SQRT(SSXLAM(1.,AMGLSS**2/AMCRSS**2,
 203      $  AMCH**2/AMCRSS**2))/3.
 204         CALL SSSAVE(ISCHR,WID,ISGL,IDCH,0,0,0)
 205       END IF
 206 C
 207       IF (AMB1SS.GT.(AMGLSS+AMBT)) THEN
 208         WID=2*SSALFS(DBLE(AMB1SS**2))*AMB1SS*(1.-AMGLSS**2/AMB1SS**2-
 209      $  AMBT**2/AMB1SS**2)*SQRT(SSXLAM(1.,AMGLSS**2/AMB1SS**2,
 210      $  AMBT**2/AMB1SS**2))/3.
 211         CALL SSSAVE(ISBT1,WID,ISGL,IDBT,0,0,0)
 212       END IF
 213 C
 214       IF (AMB2SS.GT.(AMGLSS+AMBT)) THEN
 215         WID=2*SSALFS(DBLE(AMB2SS**2))*AMB2SS*(1.-AMGLSS**2/AMB2SS**2-
 216      $  AMBT**2/AMB2SS**2)*SQRT(SSXLAM(1.,AMGLSS**2/AMB2SS**2,
 217      $  AMBT**2/AMB2SS**2))/3.
 218         CALL SSSAVE(ISBT2,WID,ISGL,IDBT,0,0,0)
 219       END IF
 220 C
 221 C           Compute branching fractions to wi --- theta-C = 0
 222 C
 223       IF (AMULSS.GT.MW1) THEN
 224         WID=G**2*SIN(GAMMAR)**2*AMULSS*(1.-MW1**2/AMULSS**2)**2/16./PI
 225         CALL SSSAVE(ISUPL,WID,ISW1,IDDN,0,0,0)
 226       END IF
 227       IF (AMCLSS.GT.MW1) THEN
 228         WID=G**2*SIN(GAMMAR)**2*AMCLSS*(1.-MW1**2/AMCLSS**2)**2/16./PI
 229         CALL SSSAVE(ISCHL,WID,ISW1,IDST,0,0,0)
 230       END IF
 231       IF (AMDLSS.GT.MW1) THEN
 232         WID=G**2*SIN(GAMMAL)**2*AMDLSS*(1.-MW1**2/AMDLSS**2)**2/16./PI
 233         CALL SSSAVE(ISDNL,WID,-ISW1,IDUP,0,0,0)
 234       END IF
 235 C
 236       IF (AMSLSS.GT.(MW1+AMCH)) THEN
 237         WID=G**2*SIN(GAMMAL)**2*AMSLSS*(1.-MW1**2/AMSLSS**2
 238      $  -AMCH**2/AMSLSS**2)
 239      $  *SQRT(SSXLAM(1.,MW1**2/AMSLSS**2,AMCH**2/AMSLSS**2))/16./PI
 240         CALL SSSAVE(ISSTL,WID,-ISW1,IDCH,0,0,0)
 241       ENDIF
 242 C
 243        IF (AMB1SS.GT.(MW1+AMTP)) THEN
 244          A=AWU(1)*COSB-BWP(1)*SINB
 245          AS=A*A
 246          WID=AMB1SS*((AS+BW(1)**2*COSB**2)*(1.-MW1**2/AMB1SS**2
 247      $  -AMTP**2/AMB1SS**2)-4*AMTP*MW1*BW(1)*A*COSB/AMB1SS**2)
 248      $   *SQRT(SSXLAM(1.,MW1**2/AMB1SS**2,AMTP**2/AMB1SS**2))/16./PI
 249         CALL SSSAVE(ISBT1,WID,-ISW1,IDTP,0,0,0)
 250       ENDIF
 251 C
 252        IF (AMB2SS.GT.(MW1+AMTP)) THEN
 253          A=AWU(1)*SINB+BWP(1)*COSB
 254          AS=A*A
 255          WID=AMB2SS*((AS+BW(1)**2*SINB**2)*(1.-MW1**2/AMB2SS**2
 256      $  -AMTP**2/AMB2SS**2)-4*AMTP*MW1*BW(1)*A*SINB/AMB2SS**2)
 257      $   *SQRT(SSXLAM(1.,MW1**2/AMB2SS**2,AMTP**2/AMB2SS**2))/16./PI
 258         CALL SSSAVE(ISBT2,WID,-ISW1,IDTP,0,0,0)
 259       ENDIF
 260 C
 261       IF (AMULSS.GT.MW2) THEN
 262         WID=G**2*COS(GAMMAR)**2*AMULSS*(1.-MW2**2/AMULSS**2)**2/16./PI
 263         CALL SSSAVE(ISUPL,WID,ISW2,IDDN,0,0,0)
 264       END IF
 265       IF (AMCLSS.GT.MW2) THEN
 266         WID=G**2*COS(GAMMAR)**2*AMCLSS*(1.-MW2**2/AMCLSS**2)**2/16./PI
 267         CALL SSSAVE(ISCHL,WID,ISW2,IDST,0,0,0)
 268       END IF
 269       IF (AMDLSS.GT.MW2) THEN
 270         WID=G**2*COS(GAMMAL)**2*AMDLSS*(1.-MW2**2/AMDLSS**2)**2/16./PI
 271         CALL SSSAVE(ISDNL,WID,-ISW2,IDUP,0,0,0)
 272       END IF
 273 C
 274       IF (AMSLSS.GT.(MW2+AMCH)) THEN
 275         WID=G**2*COS(GAMMAL)**2*AMSLSS*(1.-MW2**2/AMSLSS**2
 276      $  -AMCH**2/AMSLSS**2)
 277      $  *SQRT(SSXLAM(1.,MW2**2/AMSLSS**2,AMCH**2/AMSLSS**2))/16./PI
 278         CALL SSSAVE(ISSTL,WID,-ISW2,IDCH,0,0,0)
 279       ENDIF
 280 C
 281       IF (AMB1SS.GT.(MW2+AMTP)) THEN
 282          A=AWU(2)*COSB-BWP(2)*SINB
 283          AS=A*A
 284          WID=AMB1SS*((AS+BW(2)**2*COSB**2)*(1.-MW2**2/AMB1SS**2
 285      $  -AMTP**2/AMB1SS**2)-4*AMTP*MW2*BW(2)*A*COSB/AMB1SS**2)
 286      $   *SQRT(SSXLAM(1.,MW2**2/AMB1SS**2,AMTP**2/AMB1SS**2))/16./PI
 287         CALL SSSAVE(ISBT1,WID,-ISW2,IDTP,0,0,0)
 288       ENDIF
 289 C
 290       IF (AMB2SS.GT.(MW2+AMTP)) THEN
 291          A=AWU(2)*SINB+BWP(2)*COSB
 292          AS=A*A
 293          WID=AMB2SS*((AS+BW(2)**2*SINB**2)*(1.-MW2**2/AMB2SS**2
 294      $  -AMTP**2/AMB2SS**2)-4*AMTP*MW2*BW(2)*A*SINB/AMB2SS**2)
 295      $   *SQRT(SSXLAM(1.,MW2**2/AMB2SS**2,AMTP**2/AMB2SS**2))/16./PI
 296         CALL SSSAVE(ISBT2,WID,-ISW2,IDTP,0,0,0)
 297       ENDIF
 298 C
 299       IF (AMB1SS.GT.(AMW+AMT1SS)) THEN
 300         WID=G**2*COST**2*COSB**2*(SSXLAM(AMB1SS**2,AMW**2,
 301      $   AMT1SS**2))**1.5/32./PI/AMB1SS**3/AMW**2
 302         CALL SSSAVE(ISBT1,WID,-IDW,ISTP1,0,0,0)
 303       ENDIF
 304 C
 305       IF (AMB1SS.GT.(AMW+AMT2SS)) THEN
 306         WID=G**2*SINT**2*COSB**2*(SSXLAM(AMB1SS**2,AMW**2,
 307      $   AMT2SS**2))**1.5/32./PI/AMB1SS**3/AMW**2
 308         CALL SSSAVE(ISBT1,WID,-IDW,ISTP2,0,0,0)
 309       ENDIF
 310 C
 311       IF (AMB2SS.GT.(AMW+AMT1SS)) THEN
 312         WID=G**2*COST**2*SINB**2*(SSXLAM(AMB2SS**2,AMW**2,
 313      $   AMT1SS**2))**1.5/32./PI/AMB2SS**3/AMW**2
 314         CALL SSSAVE(ISBT2,WID,-IDW,ISTP1,0,0,0)
 315       ENDIF
 316 C
 317       IF (AMB2SS.GT.(AMW+AMT2SS)) THEN
 318         WID=G**2*SINT**2*SINB**2*(SSXLAM(AMB2SS**2,AMW**2,
 319      $   AMT2SS**2))**1.5/32./PI/AMB2SS**3/AMW**2
 320         CALL SSSAVE(ISBT2,WID,-IDW,ISTP2,0,0,0)
 321       ENDIF
 322 C
 323       IF (AMB2SS.GT.(AMZ+AMB1SS)) THEN
 324         WID=G**2*COSB**2*SINB**2*(SSXLAM(AMB2SS**2,AMZ**2,
 325      $   AMB1SS**2))**1.5/64./PI/AMB2SS**3/AMZ**2/CS2THW
 326         CALL SSSAVE(ISBT2,WID,IDZ,ISBT1,0,0,0)
 327       ENDIF
 328 C
 329       IF (AMB2SS.GT.(AMHL+AMB1SS)) THEN
 330         BH=G*AMW*SIN(BETA-ALFAH)*(-1.+TN2THW/3.)*SINB*COSB/2.+G*
 331      $  AMBT*(TWOM1*COSA+AAB*SINA)*COS(2*THETAB)/2./AMW/COS(BETA)
 332         WID=BH**2*SQRT(SSXLAM(AMB2SS**2,AMHL**2,AMB1SS**2))/
 333      $      16./PI/AMB2SS**3
 334         CALL SSSAVE(ISBT2,WID,ISHL,ISBT1,0,0,0)
 335       ENDIF
 336 C
 337       IF (AMB2SS.GT.(AMHA+AMB1SS)) THEN
 338         BH=G*AMBT*(TWOM1-AAB*TANB)/2./AMW
 339         WID=BH**2*SQRT(SSXLAM(AMB2SS**2,AMHA**2,AMB1SS**2))/
 340      $      16./PI/AMB2SS**3
 341         CALL SSSAVE(ISBT2,WID,ISHA,ISBT1,0,0,0)
 342       ENDIF
 343 C
 344       IF (AMB2SS.GT.(AMHH+AMB1SS)) THEN
 345         BH=-G*AMW*COS(BETA-ALFAH)*(-1.+TN2THW/3.)*SINB*COSB/2.+G*
 346      $  AMBT*(-TWOM1*SINA+AAB*COSA)*COS(2*THETAB)/2./AMW/COS(BETA)
 347         WID=BH**2*SQRT(SSXLAM(AMB2SS**2,AMHH**2,AMB1SS**2))/
 348      $      16./PI/AMB2SS**3
 349         CALL SSSAVE(ISBT2,WID,ISHH,ISBT1,0,0,0)
 350       ENDIF
 351 C
 352 C     b_i -> H^- t_i
 353 C
 354       IF (AMB1SS.GT.(AMT1SS+AMHC)) THEN
 355         A=G/SR2/AMW*(AMTP*AMBT*(COTB+TANB)*SINT*SINB+
 356      $(AMBT**2*TANB+AMTP**2*COTB-AMW**2*SIN(2*BETA))*
 357      $COST*COSB-AMTP*(TWOM1-AAT*COTB)*SINT*COSB-AMBT*
 358      $(TWOM1-AAB*TANB)*SINB*COST)
 359         AS=A*A
 360         WID=AS*SQRT(SSXLAM(AMB1SS**2,AMT1SS**2,AMHC**2))/
 361      $      16./PI/AMB1SS**3
 362         CALL SSSAVE(ISBT1,WID,-ISHC,ISTP1,0,0,0)
 363       END IF
 364 C
 365       IF (AMB1SS.GT.(AMT2SS+AMHC)) THEN
 366         A=G/SR2/AMW*(-AMTP*AMBT*(COTB+TANB)*COST*SINT+
 367      $(AMBT**2*TANB+AMTP**2*COTB-AMW**2*SIN(2*BETA))*
 368      $SINT*COSB+AMTP*(TWOM1-AAT*COTB)*COST*COSB-AMBT*
 369      $(TWOM1-AAB*TANB)*SINT*SINB)
 370         AS=A*A
 371         WID=AS*SQRT(SSXLAM(AMB1SS**2,AMT2SS**2,AMHC**2))/
 372      $      16./PI/AMB1SS**3
 373         CALL SSSAVE(ISBT1,WID,-ISHC,ISTP2,0,0,0)
 374       END IF
 375 C
 376       IF (AMB2SS.GT.(AMT1SS+AMHC)) THEN
 377         A=G/SR2/AMW*(-AMTP*AMBT*(COTB+TANB)*SINT*COSB+
 378      $(AMBT**2*TANB+AMTP**2*COTB-AMW**2*SIN(2*BETA))*
 379      $COST*SINB-AMTP*(TWOM1-AAT*COTB)*SINT*SINB+AMBT*
 380      $(TWOM1-AAB*TANB)*COST*COSB)
 381         AS=A*A
 382         WID=AS*SQRT(SSXLAM(AMB2SS**2,AMT1SS**2,AMHC**2))/
 383      $      16./PI/AMB2SS**3
 384         CALL SSSAVE(ISBT2,WID,-ISHC,ISTP1,0,0,0)
 385       END IF
 386 C
 387       IF (AMB2SS.GT.(AMT2SS+AMHC)) THEN
 388         A=G/SR2/AMW*(AMTP*AMBT*(COTB+TANB)*COST*COSB+
 389      $(AMBT**2*TANB+AMTP**2*COTB-AMW**2*SIN(2*BETA))*
 390      $SINT*SINB+AMTP*(TWOM1-AAT*COTB)*SINB*COST+AMBT*
 391      $(TWOM1-AAB*TANB)*COSB*SINT)
 392         AS=A*A
 393         WID=AS*SQRT(SSXLAM(AMB2SS**2,AMT2SS**2,AMHC**2))/
 394      $      16./PI/AMB2SS**3
 395         CALL SSSAVE(ISBT2,WID,-ISHC,ISTP2,0,0,0)
 396       END IF
 397 C
 398 C          Normalize branching ratios
 399 C
 400       CALL SSNORM(ISUPL)
 401       CALL SSNORM(ISDNL)
 402       CALL SSNORM(ISSTL)
 403       CALL SSNORM(ISCHL)
 404       CALL SSNORM(ISBT1)
 405       CALL SSNORM(ISUPR)
 406       CALL SSNORM(ISDNR)
 407       CALL SSNORM(ISSTR)
 408       CALL SSNORM(ISCHR)
 409       CALL SSNORM(ISBT2)
 410 C
 411        RETURN
 412        END