Fixes for object target dependencies
[u/mrichter/AliRoot.git] / MUON / MUONcalib / CMakeLists.txt
1 # **************************************************************************
2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
3 # *                                                                        *
4 # * Author: The ALICE Off-line Project.                                    *
5 # * Contributors are mentioned in the code where appropriate.              *
6 # *                                                                        *
7 # * Permission to use, copy, modify and distribute this software and its   *
8 # * documentation strictly for non-commercial purposes is hereby granted   *
9 # * without fee, provided that the above copyright notice appears in all   *
10 # * copies and that both the copyright notice and this permission notice   *
11 # * appear in the supporting documentation. The authors make no claims     *
12 # * about the suitability of this software for any purpose. It is          *
13 # * provided "as is" without express or implied warranty.                  *
14 # **************************************************************************
15
16 # Module
17 set(MODULE MUONcalib)
18
19 # Module include folder
20 include_directories(${AliRoot_SOURCE_DIR}/MUON/${MODULE})
21
22 # Additional include folders in alphabetical order except ROOT
23 include_directories(${ROOT_INCLUDE_DIRS}
24                     ${AliRoot_SOURCE_DIR}/MUON/MUONcore
25                     ${AliRoot_SOURCE_DIR}/MUON/MUONmapping
26                     ${AliRoot_SOURCE_DIR}/STEER/CDB
27                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
28                    )
29
30 # Sources in alphabetical order
31 set(SRCS
32     AliMUON2DStoreValidator.cxx
33     AliMUONCalibParamND.cxx
34     AliMUONCalibParamNF.cxx
35     AliMUONCalibParamNI.cxx
36     AliMUONCalibrationData.cxx
37     AliMUONErrorCounter.cxx
38     AliMUONGain.cxx
39     AliMUONGlobalCrateConfig.cxx
40     AliMUONPedestal.cxx
41     AliMUONRegionalTriggerConfig.cxx
42     AliMUONRejectList.cxx
43     AliMUONSparseHisto.cxx
44     AliMUONTrackerData.cxx
45     AliMUONTrackerIO.cxx
46     AliMUONTriggerChamberEfficiency.cxx
47     AliMUONTriggerCrateConfig.cxx
48     AliMUONTriggerDisplay.cxx
49     AliMUONTriggerEfficiencyCells.cxx
50     AliMUONTriggerIO.cxx
51     AliMUONTriggerLut.cxx
52     AliMUONVCalibParam.cxx
53     AliMUONVTrackerData.cxx
54    )
55
56 # Headers from sources
57 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
58
59 # Generate the dictionary
60 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
61 get_directory_property(incdirs INCLUDE_DIRECTORIES)
62 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
63
64 # Dependencies
65 set(ROOT_DEPENDENCIES Core Gpad Hist MathCore Physics RIO Tree)
66 set(ALIROOT_DEPENDENCIES STEERBase CDB MUONcore MUONmapping)
67
68 # Generate the ROOT map
69 # Dependecies
70 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
71 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
72
73 # Create an object to be reused in case of static libraries 
74 # Otherwise the sources will be compiled twice
75 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
76 # Follow headers dependencies
77 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
78 # Add a library to the project using the object
79 add_library(${MODULE} SHARED $<TARGET_OBJECTS:MUONcalib-object>)
80
81 # linking
82 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
83
84 # Setting the correct headers for the object as gathered from the dependencies
85 target_include_directories(${MODULE}-object PUBLIC $<TARGET_PROPERTY:${MODULE},INCLUDE_DIRECTORIES>)
86 set_target_properties(${MODULE}-object PROPERTIES COMPILE_DEFINITIONS $<TARGET_PROPERTY:${MODULE},COMPILE_DEFINITIONS>)
87
88 # Additional compilation flags
89 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS " ")
90
91 # System dependent: Modify the way the library is build
92 if(${CMAKE_SYSTEM} MATCHES Darwin)
93     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
94 endif(${CMAKE_SYSTEM} MATCHES Darwin)
95
96 # Installation
97 install(TARGETS ${MODULE}
98         ARCHIVE DESTINATION lib
99         LIBRARY DESTINATION lib)
100
101 install(FILES ${HDRS} DESTINATION include)
102
103 # Static version if DA enabled
104 if(ALIROOT_STATIC)
105     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:MUONcalib-object>)
106     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
107
108     # list of shared dependencies / the name of the variable containing the list of static ones
109     generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")
110     target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root)
111     
112     # Public include folders that will be propagated to the dependecies
113     target_include_directories(${MODULE}-static PUBLIC ${incdirs})
114
115     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
116
117     # Installation
118     install(TARGETS ${MODULE}-static
119             ARCHIVE DESTINATION lib
120             LIBRARY DESTINATION lib)
121 endif(ALIROOT_STATIC)
122