Fixes for object target dependencies
[u/mrichter/AliRoot.git] / MUON / MUONraw / CMakeLists.txt
1 # **************************************************************************
2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
3 # *                                                                        *
4 # * Author: The ALICE Off-line Project.                                    *
5 # * Contributors are mentioned in the code where appropriate.              *
6 # *                                                                        *
7 # * Permission to use, copy, modify and distribute this software and its   *
8 # * documentation strictly for non-commercial purposes is hereby granted   *
9 # * without fee, provided that the above copyright notice appears in all   *
10 # * copies and that both the copyright notice and this permission notice   *
11 # * appear in the supporting documentation. The authors make no claims     *
12 # * about the suitability of this software for any purpose. It is          *
13 # * provided "as is" without express or implied warranty.                  *
14 # **************************************************************************
15
16 # Module
17 set(MODULE MUONraw)
18
19 # Module include folder
20 include_directories(${AliRoot_SOURCE_DIR}/MUON/${MODULE})
21
22 # Additional include folders in alphabetical order except ROOT
23 include_directories(${ROOT_INCLUDE_DIRS}
24                     ${AliRoot_SOURCE_DIR}/MUON/MUONcore
25                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
26                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatarec
27                     ${AliRoot_SOURCE_DIR}/STEER/ESD
28                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
29                    )
30
31 # Sources in alphabetical order
32 set(SRCS
33     AliMUONBlockHeader.cxx
34     AliMUONBusStruct.cxx
35     AliMUONDarcHeader.cxx
36     AliMUONDDLTracker.cxx
37     AliMUONDDLTrigger.cxx
38     AliMUONDspHeader.cxx
39     AliMUONLocalStruct.cxx
40     AliMUONPayloadTracker.cxx
41     AliMUONPayloadTrigger.cxx
42     AliMUONRawStream.cxx
43     AliMUONRawStreamTracker.cxx
44     AliMUONRawStreamTrackerHP.cxx
45     AliMUONRawStreamTrigger.cxx
46     AliMUONRawStreamTriggerHP.cxx
47     AliMUONRegHeader.cxx
48     AliMUONVRawStreamTracker.cxx
49     AliMUONVRawStreamTrigger.cxx
50    )
51
52 # Headers from sources
53 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
54
55 # Generate the dictionary
56 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
57 get_directory_property(incdirs INCLUDE_DIRECTORIES)
58 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
59
60 # Dependencies
61 set(ROOT_DEPENDENCIES Core)
62 set(ALIROOT_DEPENDENCIES STEERBase ESD RAWDatabase RAWDatarec MUONcore)
63
64 # Generate the ROOT map
65 # Dependecies
66 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
67 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
68
69 # Create an object to be reused in case of static libraries 
70 # Otherwise the sources will be compiled twice
71 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
72 # Follow headers dependencies
73 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
74 # Add a library to the project using the object
75 add_library(${MODULE} SHARED $<TARGET_OBJECTS:MUONraw-object>)
76
77 # linking
78 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
79
80 # Setting the correct headers for the object as gathered from the dependencies
81 target_include_directories(${MODULE}-object PUBLIC $<TARGET_PROPERTY:${MODULE},INCLUDE_DIRECTORIES>)
82 set_target_properties(${MODULE}-object PROPERTIES COMPILE_DEFINITIONS $<TARGET_PROPERTY:${MODULE},COMPILE_DEFINITIONS>)
83
84 # Additional compilation flags
85 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS " ")
86
87 # System dependent: Modify the way the library is build
88 if(${CMAKE_SYSTEM} MATCHES Darwin)
89     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
90 endif(${CMAKE_SYSTEM} MATCHES Darwin)
91
92 # Installation
93 install(TARGETS ${MODULE}
94         ARCHIVE DESTINATION lib
95         LIBRARY DESTINATION lib)
96
97 install(FILES ${HDRS} DESTINATION include)
98
99 # Static version if DA enabled
100 if(ALIROOT_STATIC)
101     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:MUONraw-object>)
102     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
103
104     # list of shared dependencies / the name of the variable containing the list of static ones
105     generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")
106     target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root)
107     
108     # Public include folders that will be propagated to the dependecies
109     target_include_directories(${MODULE}-static PUBLIC ${incdirs})
110
111     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
112
113     # Installation
114     install(TARGETS ${MODULE}-static
115             ARCHIVE DESTINATION lib
116             LIBRARY DESTINATION lib)
117 endif(ALIROOT_STATIC)
118