PYTHIA/pythia/pygvmd.F

   1
   2 C*********************************************************************
   3
   4       SUBROUTINE PYGVMD(ISET,KF,X,Q2,P2,ALAM,XPGA)
   5 C...Purpose: to evaluate the VMD parton distributions of a photon,
   6 C...evolved homogeneously from an initial scale P2 to Q2.
   7 C...Does not include dipole suppression factor.
   8 C...ISET is parton distribution set, see above;
   9 C...additionally ISET=0 is used for the evolution of an anomalous photon
  10 C...which branched at a scale P2 and then evolved homogeneously to Q2.
  11 C...ALAM is the 4-flavour Lambda, which is automatically converted
  12 C...to 3- and 5-flavour equivalents as needed.
  13       DIMENSION XPGA(-6:6)
  14       DATA PMC/1.3/, PMB/4.6/, AEM/0.007297/, AEM2PI/0.0011614/
  15
  16 C...Reset output.
  17       DO 100 KFL=-6,6
  18       XPGA(KFL)=0.
  19   100 CONTINUE
  20       KFA=IABS(KF)
  21
  22 C...Calculate Lambda; protect against unphysical Q2 and P2 input.
  23       ALAM3=ALAM*(PMC/ALAM)**(2./27.)
  24       ALAM5=ALAM*(ALAM/PMB)**(2./23.)
  25       P2EFF=MAX(P2,1.2*ALAM3**2)
  26       IF(KFA.EQ.4) P2EFF=MAX(P2EFF,PMC**2)
  27       IF(KFA.EQ.5) P2EFF=MAX(P2EFF,PMB**2)
  28       Q2EFF=MAX(Q2,P2EFF)
  29
  30 C...Find number of flavours at lower and upper scale.
  31       NFP=4
  32       IF(P2EFF.LT.PMC**2) NFP=3
  33       IF(P2EFF.GT.PMB**2) NFP=5
  34       NFQ=4
  35       IF(Q2EFF.LT.PMC**2) NFQ=3
  36       IF(Q2EFF.GT.PMB**2) NFQ=5
  37
  38 C...Find s as sum of 3-, 4- and 5-flavour parts.
  39       S=0.
  40       IF(NFP.EQ.3) THEN
  41         Q2DIV=PMC**2
  42         IF(NFQ.EQ.3) Q2DIV=Q2EFF
  43         S=S+(6./27.)*LOG(LOG(Q2DIV/ALAM3**2)/LOG(P2EFF/ALAM3**2))
  44       ENDIF
  45       IF(NFP.LE.4.AND.NFQ.GE.4) THEN
  46         P2DIV=P2EFF
  47         IF(NFP.EQ.3) P2DIV=PMC**2
  48         Q2DIV=Q2EFF
  49         IF(NFQ.EQ.5) Q2DIV=PMB**2
  50         S=S+(6./25.)*LOG(LOG(Q2DIV/ALAM**2)/LOG(P2DIV/ALAM**2))
  51       ENDIF
  52       IF(NFQ.EQ.5) THEN
  53         P2DIV=PMB**2
  54         IF(NFP.EQ.5) P2DIV=P2EFF
  55         S=S+(6./23.)*LOG(LOG(Q2EFF/ALAM5**2)/LOG(P2DIV/ALAM5**2))
  56       ENDIF
  57
  58 C...Calculate frequent combinations of x and s.
  59       X1=1.-X
  60       XL=-LOG(X)
  61       S2=S**2
  62       S3=S**3
  63       S4=S**4
  64
  65 C...Evaluate homogeneous anomalous parton distributions below or
  66 C...above threshold.
  67       IF(ISET.EQ.0) THEN
  68       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
  69      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
  70         XVAL = X * 1.5 * (X**2+X1**2)
  71         XGLU = 0.
  72         XSEA = 0.
  73       ELSE
  74         XVAL = (1.5/(1.-0.197*S+4.33*S2)*X**2 + (1.5+2.10*S)/
  75      &  (1.+3.29*S)*X1**2 + 5.23*S/(1.+1.17*S+19.9*S3)*X*X1) *
  76      &  X**(1./(1.+1.5*S)) * (1.-X**2)**(2.667*S)
  77         XGLU = 4.*S/(1.+4.76*S+15.2*S2+29.3*S4) *
  78      &  X**(-2.03*S/(1.+2.44*S)) * (X1*XL)**(1.333*S) *
  79      &  ((4.*X**2+7.*X+4.)*X1/3. - 2.*X*(1.+X)*XL)
  80         XSEA = S2/(1.+4.54*S+8.19*S2+8.05*S3) *
  81      &  X**(-1.54*S/(1.+1.29*S)) * X1**(2.667*S) *
  82      &  ((8.-73.*X+62.*X**2)*X1/9. + (3.-8.*X**2/3.)*X*XL +
  83      &  (2.*X-1.)*X*XL**2)
  84       ENDIF
  85
  86 C...Evaluate set 1D parton distributions below or above threshold.
  87       ELSEIF(ISET.EQ.1) THEN
  88       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
  89      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
  90         XVAL = 1.294 * X**0.80 * X1**0.76
  91         XGLU = 1.273 * X**0.40 * X1**1.76
  92         XSEA = 0.100 * X1**3.76
  93       ELSE
  94         XVAL = 1.294/(1.+0.252*S+3.079*S2) * X**(0.80-0.13*S) *
  95      &  X1**(0.76+0.667*S) * XL**(2.*S)
  96         XGLU = 7.90*S/(1.+5.50*S) * EXP(-5.16*S) *
  97      &  X**(-1.90*S/(1.+3.60*S)) * X1**1.30 * XL**(0.50+3.*S) +
  98      &  1.273 * EXP(-10.*S) * X**0.40 * X1**(1.76+3.*S)
  99         XSEA = (0.1-0.397*S2+1.121*S3)/(1.+5.61*S2+5.26*S3) *
 100      &  X**(-7.32*S2/(1.+10.3*S2)) *
 101      &  X1**((3.76+15.*S+12.*S2)/(1.+4.*S))
 102         XSEA0 = 0.100 * X1**3.76
 103       ENDIF
 104
 105 C...Evaluate set 1M parton distributions below or above threshold.
 106       ELSEIF(ISET.EQ.2) THEN
 107       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
 108      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
 109         XVAL = 0.8477 * X**0.51 * X1**1.37
 110         XGLU = 3.42 * X**0.255 * X1**2.37
 111         XSEA = 0.
 112       ELSE
 113         XVAL = 0.8477/(1.+1.37*S+2.18*S2+3.73*S3) * X**(0.51+0.21*S)
 114      &  * X1**1.37 * XL**(2.667*S)
 115         XGLU = 24.*S/(1.+9.6*S+0.92*S2+14.34*S3) * EXP(-5.94*S) *
 116      &  X**((-0.013-1.80*S)/(1.+3.14*S)) * X1**(2.37+0.4*S) *
 117      &  XL**(0.32+3.6*S) + 3.42 * EXP(-12.*S) * X**0.255 *
 118      &  X1**(2.37+3.*S)
 119         XSEA = 0.842*S/(1.+21.3*S-33.2*S2+229.*S3) *
 120      &  X**((0.13-2.90*S)/(1.+5.44*S)) * X1**(3.45+0.5*S) *
 121      &  XL**(2.8*S)
 122         XSEA0 = 0.
 123       ENDIF
 124
 125 C...Evaluate set 2D parton distributions below or above threshold.
 126       ELSEIF(ISET.EQ.3) THEN
 127       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
 128      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
 129         XVAL = X**0.46 * X1**0.64 + 0.76 * X
 130         XGLU = 1.925 * X1**2
 131         XSEA = 0.242 * X1**4
 132       ELSE
 133         XVAL = (1.+0.186*S)/(1.-0.209*S+1.495*S2) * X**(0.46+0.25*S)
 134      &  * X1**((0.64+0.14*S+5.*S2)/(1.+S)) * XL**(1.9*S) +
 135      &  (0.76+0.4*S) * X * X1**(2.667*S)
 136         XGLU = (1.925+5.55*S+147.*S2)/(1.-3.59*S+3.32*S2) *
 137      &  EXP(-18.67*S) * X**((-5.81*S-5.34*S2)/(1.+29.*S-4.26*S2))
 138      &  * X1**((2.-5.9*S)/(1.+1.7*S)) * XL**(9.3*S/(1.+1.7*S))
 139         XSEA = (0.242-0.252*S+1.19*S2)/(1.-0.607*S+21.95*S2) *
 140      &  X**(-12.1*S2/(1.+2.62*S+16.7*S2)) * X1**4 * XL**S
 141         XSEA0 = 0.242 * X1**4
 142       ENDIF
 143
 144 C...Evaluate set 2M parton distributions below or above threshold.
 145       ELSEIF(ISET.EQ.4) THEN
 146       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
 147      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
 148         XVAL = 1.168 * X**0.50 * X1**2.60 + 0.965 * X
 149         XGLU = 1.808 * X1**2
 150         XSEA = 0.209 * X1**4
 151       ELSE
 152         XVAL = (1.168+1.771*S+29.35*S2) * EXP(-5.776*S) *
 153      &  X**((0.5+0.208*S)/(1.-0.794*S+1.516*S2)) *
 154      &  X1**((2.6+7.6*S)/(1.+5.*S)) * XL**(5.15*S/(1.+2.*S)) +
 155      &  (0.965+22.35*S)/(1.+18.4*S) * X * X1**(2.667*S)
 156         XGLU = (1.808+29.9*S)/(1.+26.4*S) * EXP(-5.28*S) *
 157      &  X**((-5.35*S-10.11*S2)/(1.+31.71*S)) *
 158      &  X1**((2.-7.3*S+4.*S2)/(1.+2.5*S)) *
 159      &  XL**(10.9*S/(1.+2.5*S))
 160         XSEA = (0.209+0.644*S2)/(1.+0.319*S+17.6*S2) *
 161      &  X**((-0.373*S-7.71*S2)/(1.+0.815*S+11.0*S2)) *
 162      &  X1**(4.+S) * XL**(0.45*S)
 163         XSEA0 = 0.209 * X1**4
 164       ENDIF
 165       ENDIF
 166
 167 C...Threshold factors for c and b sea.
 168       SLL=LOG(LOG(Q2EFF/ALAM**2)/LOG(P2EFF/ALAM**2))
 169       XCHM=0.
 170       IF(Q2.GT.PMC**2.AND.Q2.GT.1.001*P2EFF) THEN
 171         SCH=MAX(0.,LOG(LOG(PMC**2/ALAM**2)/LOG(P2EFF/ALAM**2)))
 172         IF(ISET.EQ.0) THEN
 173           XCHM=XSEA*(1.-(SCH/SLL)**2)
 174         ELSE
 175           XCHM=MAX(0.,XSEA-XSEA0*X1**(2.667*S))*(1.-SCH/SLL)
 176         ENDIF
 177       ENDIF
 178       XBOT=0.
 179       IF(Q2.GT.PMB**2.AND.Q2.GT.1.001*P2EFF) THEN
 180         SBT=MAX(0.,LOG(LOG(PMB**2/ALAM**2)/LOG(P2EFF/ALAM**2)))
 181         IF(ISET.EQ.0) THEN
 182           XBOT=XSEA*(1.-(SBT/SLL)**2)
 183         ELSE
 184           XBOT=MAX(0.,XSEA-XSEA0*X1**(2.667*S))*(1.-SBT/SLL)
 185         ENDIF
 186       ENDIF
 187
 188 C...Fill parton distributions.
 189       XPGA(0)=XGLU
 190       XPGA(1)=XSEA
 191       XPGA(2)=XSEA
 192       XPGA(3)=XSEA
 193       XPGA(4)=XCHM
 194       XPGA(5)=XBOT
 195       XPGA(KFA)=XPGA(KFA)+XVAL
 196       DO 110 KFL=1,5
 197       XPGA(-KFL)=XPGA(KFL)
 198   110 CONTINUE
 199
 200       RETURN
 201       END