be9203eb616b83143553f2bda3289fee1387d829
[u/mrichter/AliRoot.git] / RAW / RAWDatasim / CMakeLists.txt
1 # **************************************************************************
2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
3 # *                                                                        *
4 # * Author: The ALICE Off-line Project.                                    *
5 # * Contributors are mentioned in the code where appropriate.              *
6 # *                                                                        *
7 # * Permission to use, copy, modify and distribute this software and its   *
8 # * documentation strictly for non-commercial purposes is hereby granted   *
9 # * without fee, provided that the above copyright notice appears in all   *
10 # * copies and that both the copyright notice and this permission notice   *
11 # * appear in the supporting documentation. The authors make no claims     *
12 # * about the suitability of this software for any purpose. It is          *
13 # * provided "as is" without express or implied warranty.                  *
14 # **************************************************************************
15
16 # Module
17 set(MODULE RAWDatasim)
18
19 # Module include folder
20 include_directories(${AliRoot_SOURCE_DIR}/RAW/${MODULE})
21
22 # Additional include folders in alphabetical order except ROOT
23 include_directories(${ROOT_INCLUDE_DIRS}
24                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
25                     ${AliRoot_SOURCE_DIR}/STEER/STEER
26                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
27                    )
28
29 # Sources in alphabetical order
30 set(SRCS
31     AliAltroBuffer.cxx
32     AliAltroBufferV3.cxx
33     AliBitPacking.cxx
34    )
35
36 # Headers from sources
37 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
38
39 # Generate the dictionary
40 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
41 get_directory_property(incdirs INCLUDE_DIRECTORIES)
42 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
43
44 set(ROOT_DEPENDENCIES)
45 set(ALIROOT_DEPENDENCIES RAWDatabase STEERBase STEER)
46
47 # Generate the ROOT map
48 # Dependecies
49 set(LIBDEPS ${ROOT_DEPENDENCIES} ${ALIROOT_DEPENDENCIES})
50 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
51
52 # Create an object to be reused in case of static libraries 
53 # Otherwise the sources will be compiled twice
54 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
55 # Follow headers dependencies
56 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
57 # Add a library to the project using the object
58 add_library(${MODULE} SHARED $<TARGET_OBJECTS:RAWDatasim-object>)
59 target_link_libraries(${MODULE} ${ROOT_DEPENDENCIES} ${ALIROOT_DEPENDENCIES})
60
61 # Public include folders that will be propagated to the dependecies
62 target_include_directories(${MODULE} PUBLIC ${incdirs})
63
64 # Compile and link flags
65 set(MODULE_COMPILE_FLAGS)
66 set(MODULE_LINK_FLAGS)
67
68 if(DATE_FOUND)
69     set(MODULE_COMPILE_FLAGS "${DATE_CFLAGS}")
70     set(MODULE_LINK_FLAGS "${DATE_LDFLAGS} ${DATE_LIBS}")
71 endif(DATE_FOUND)
72
73 # Additional compilation and linking flags
74 set(MODULE_COMPILE_FLAGS "-O -g ${MODULE_COMPILE_FLAGS}")
75
76 # System dependent: Modify the way the library is build
77 if(${CMAKE_SYSTEM} MATCHES Darwin)
78     set(MODULE_LINK_FLAGS "-undefined dynamic_lookup ${MODULE_LINK_FLAGS}")
79 endif(${CMAKE_SYSTEM} MATCHES Darwin)
80
81 # Setting target compile for the object
82 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS "${MODULE_COMPILE_FLAGS}")
83
84 # Setting linking flags for the library
85 set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "${MODULE_LINK_FLAGS}")
86
87 # Installation
88 install(TARGETS ${MODULE}
89         ARCHIVE DESTINATION lib
90         LIBRARY DESTINATION lib)
91
92 install(FILES ${HDRS} DESTINATION include)
93
94 # Static version if DA enabled
95 if(ALIROOT_STATIC)
96     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:RAWDatasim-object>)
97     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
98     
99     # list of shared dependencies / the name of the variable containing the list of static ones
100     generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")
101     target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root)
102     
103     # Public include folders that will be propagated to the dependecies
104     target_include_directories(${MODULE}-static PUBLIC ${incdirs})
105     
106     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
107
108     # Installation
109     install(TARGETS ${MODULE}-static
110             ARCHIVE DESTINATION lib
111             LIBRARY DESTINATION lib)
112 endif(ALIROOT_STATIC)