STEER/CDB/CMakeLists.txt

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # Module
  17 set(MODULE CDB)
  18
  19 # Module include folders
  20 include_directories(${AliRoot_SOURCE_DIR}/STEER/${MODULE})
  21
  22 # Additional include directories
  23 include_directories(${ROOT_INCLUDE_DIRS}
  24                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
  25                     ${CMAKE_BINARY_DIR}/version/
  26                    )
  27
  28
  29 # Sources - alphabetical order
  30 set(SRCS
  31     AliBaseCalibViewer.cxx
  32     AliBaseCalibViewerGUI.cxx
  33     AliCalibViewerGUItime.cxx
  34     AliCDBDump.cxx
  35     AliCDBEntry.cxx
  36     AliCDBGrid.cxx
  37     AliCDBHandler.cxx
  38     AliCDBId.cxx
  39     AliCDBLocal.cxx
  40     AliCDBManager.cxx
  41     AliCDBMetaData.cxx
  42     AliCDBPath.cxx
  43     AliCDBRunRange.cxx
  44     AliCDBStorage.cxx
  45     AliDCSGenDB.cxx
  46     AliDCSSensorArray.cxx
  47     AliDCSSensor.cxx
  48     AliDCSValue.cxx
  49     AliGRPDCS.cxx
  50     AliOCDBtoolkit.cxx
  51     AliPreprocessor.cxx
  52     AliShuttleInterface.cxx
  53     AliSplineFit.cxx
  54    )
  55
  56 # Headers from sources
  57 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
  58
  59 # Generate the dictionary
  60 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
  61 get_directory_property(incdirs INCLUDE_DIRECTORIES)
  62 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
  63
  64 set(ROOT_DEPENDENCIES Core GenVector Gpad Graf Gui Hist MathCore Matrix Minuit Net RIO Tree XMLParser)
  65 set(ALIROOT_DEPENDENCIES STEERBase)
  66
  67 # Generate the ROOT map
  68 # Dependecies
  69 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  70 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
  71
  72 # Create an object to be reused in case of static libraries
  73 # Otherwise the sources will be compiled twice
  74 add_library(CDB-object OBJECT ${SRCS} G__${MODULE}.cxx)
  75 # Add a library to the project using the object
  76 add_library(CDB SHARED $<TARGET_OBJECTS:CDB-object>)
  77
  78 # Linking library
  79 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  80
  81 # Additional compilation flags
  82 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS "-fPIC -O -g")
  83
  84 # System dependent: Modify the way the library is build
  85 if(${CMAKE_SYSTEM} MATCHES Darwin)
  86     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
  87 endif(${CMAKE_SYSTEM} MATCHES Darwin)
  88
  89 # Installation
  90 install(TARGETS ${MODULE}
  91   ARCHIVE DESTINATION lib
  92   LIBRARY DESTINATION lib)
  93 install(FILES ${HDRS} DESTINATION include)
  94
  95 # Static version if DA enabled
  96 if(ALIROOT_STATIC)
  97     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:CDB-object>)
  98     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
  99
 100     # list of shared dependencies / the name of the variable containing the list of static ones
 101     generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")
 102
 103     target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root RootExtra)
 104     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
 105
 106     # Installation
 107     install(TARGETS ${MODULE}-static
 108             ARCHIVE DESTINATION lib
 109             LIBRARY DESTINATION lib)
 110 endif(ALIROOT_STATIC)