Fixes for object target dependencies
[u/mrichter/AliRoot.git] / TRD / TRDrec / CMakeLists.txt
1 # **************************************************************************
2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
3 # *                                                                        *
4 # * Author: The ALICE Off-line Project.                                    *
5 # * Contributors are mentioned in the code where appropriate.              *
6 # *                                                                        *
7 # * Permission to use, copy, modify and distribute this software and its   *
8 # * documentation strictly for non-commercial purposes is hereby granted   *
9 # * without fee, provided that the above copyright notice appears in all   *
10 # * copies and that both the copyright notice and this permission notice   *
11 # * appear in the supporting documentation. The authors make no claims     *
12 # * about the suitability of this software for any purpose. It is          *
13 # * provided "as is" without express or implied warranty.                  *
14 # **************************************************************************
15
16 # Module
17 set(MODULE TRDrec)
18
19 # Module include folder
20 include_directories(${AliRoot_SOURCE_DIR}/TRD/${MODULE})
21
22 # Additional include folders in alphabetical order except ROOT
23 include_directories(${ROOT_INCLUDE_DIRS}
24                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatarec
25                     ${AliRoot_SOURCE_DIR}/STAT
26                     ${AliRoot_SOURCE_DIR}/STEER/ESD
27                     ${AliRoot_SOURCE_DIR}/STEER/STEER
28                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
29                     ${AliRoot_SOURCE_DIR}/TRD/TRDbase
30                    )
31
32 # Sources in alphabetical order
33 set(SRCS
34     AliTRDCalPIDLQ.cxx
35     AliTRDCalPIDNN.cxx
36     AliTRDpidESD.cxx
37     AliTRDqaBuildReference.cxx
38     AliTRDQADataMakerRec.cxx
39     AliTRDqaRecPoints.cxx
40    )
41
42 # Headers from sources
43 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
44
45 # Generate the dictionary
46 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
47 get_directory_property(incdirs INCLUDE_DIRECTORIES)
48 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
49
50 set(ROOT_DEPENDENCIES Core Gpad Hist MLP RIO)
51 set(ALIROOT_DEPENDENCIES STEERBase STEER ESD RAWDatarec STAT TRDbase)
52
53 # Generate the ROOT map
54 # Dependecies
55 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
56 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
57
58 # Create an object to be reused in case of static libraries 
59 # Otherwise the sources will be compiled twice
60 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
61 # Follow headers dependencies
62 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
63 # Add a library to the project using the object
64 add_library(${MODULE} SHARED $<TARGET_OBJECTS:${MODULE}-object>)
65
66 # Linking
67 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
68
69 # Setting the correct headers for the object as gathered from the dependencies
70 target_include_directories(${MODULE}-object PUBLIC $<TARGET_PROPERTY:${MODULE},INCLUDE_DIRECTORIES>)
71
72 # Public include folders that will be propagated to the dependecies
73 target_include_directories(${MODULE} PUBLIC ${incdirs})
74
75 # Additional compilation flags
76 #set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS "")
77
78 # System dependent: Modify the way the library is build
79 if(${CMAKE_SYSTEM} MATCHES Darwin)
80     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
81 endif(${CMAKE_SYSTEM} MATCHES Darwin)
82
83 # Installation
84 install(TARGETS ${MODULE}
85         ARCHIVE DESTINATION lib
86         LIBRARY DESTINATION lib)