be99e1f743db53a578f62fad746997c1591dd463
[u/mrichter/AliRoot.git] / cmake / FindFASTJET.cmake
1 # **************************************************************************
2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
3 # *                                                                        *
4 # * Author: The ALICE Off-line Project.                                    *
5 # * Contributors are mentioned in the code where appropriate.              *
6 # *                                                                        *
7 # * Permission to use, copy, modify and distribute this software and its   *
8 # * documentation strictly for non-commercial purposes is hereby granted   *
9 # * without fee, provided that the above copyright notice appears in all   *
10 # * copies and that both the copyright notice and this permission notice   *
11 # * appear in the supporting documentation. The authors make no claims     *
12 # * about the suitability of this software for any purpose. It is          *
13 # * provided "as is" without express or implied warranty.                  *
14 # **************************************************************************
15
16 # AliRoot Build System Module to find and configure FASTJET
17 # Author: Marco van Leeuwen 
18 # FastJet installation is pointed during cmake configuration -DFASTJET
19 # Variables set during Find:
20 # - FASTJET_CONFIG - fastjet-config location
21 # - FASTJET_VERSION
22 # - FASTJET_VERSION_MAJOR
23 # - FASTJET_VERSION_MINOR
24 # - FASTJET_VERSION_PATCH
25 # - FASTJET_INCLUDE_DIR - fastjet headers location
26 # - FASTJET_LIBS_DIR - fastjet libraries location
27 # - FASTJET_DEFINITIONS - fastjet definition flags
28 # - FASTJET_CXXFLAGS - fastjet compilation flags
29 # - FASTJET_LIBS - fastjet libraries - array
30
31 set(FASTJET_FOUND FALSE)
32
33 if(FASTJET)
34     # Check for fastjet-config script
35     find_program(FASTJET_CONFIG NAMES fastjet-config PATHS ${FASTJET}/bin NO_DEFAULT_PATH)
36     if(NOT FASTJET_CONFIG)
37         message(FATAL_ERROR "Could not find fastjet-config executable")
38     endif(NOT FASTJET_CONFIG)
39
40     # Check for header installation
41     find_path(FASTJETHH include/fastjet/PseudoJet.hh PATHS ${FASTJET})
42
43     if (FASTJETHH-NOTFOUND)
44         message(FATAL_ERROR "Header file fastjet/PseudoJet.hh not found in ${FASTJET}/include. Please check your FASTJET installation")
45     endif(FASTJETHH-NOTFOUND)
46
47     # FastJet version
48     execute_process(COMMAND ${FASTJET_CONFIG} --version OUTPUT_VARIABLE FASTJET_VERSION ERROR_VARIABLE error OUTPUT_STRIP_TRAILING_WHITESPACE )
49     if(error)
50         message(FATAL_ERROR "Error retrieving FastJet version : ${error}")
51     endif(error)
52
53     # Extract major, minor, and patch versions from
54     string(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+.*" "\\1" FASTJET_VERSION_MAJOR "${FASTJET_VERSION}")
55     string(REGEX REPLACE "^[0-9]+\\.([0-9])+\\.[0-9]+.*" "\\1" FASTJET_VERSION_MINOR "${FASTJET_VERSION}")
56     string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1" FASTJET_VERSION_PATCH "${FASTJET_VERSION}")
57     
58     if(FASTJET_VERSION_MAJOR LESS 3)
59         message(FATAL_ERROR "FastJet ${FASTJET_VERSION_MAJOR}.${FASTJET_VERSION_MINOR}.${FASTJET_VERSION_PATCH} version is not suported. Please install a version >= 3.*")
60     endif()
61
62     # Extracting compilation flags
63     execute_process(COMMAND ${FASTJET_CONFIG} --cxxflags OUTPUT_VARIABLE FASTJET_CXXFLAGS ERROR_VARIABLE error OUTPUT_STRIP_TRAILING_WHITESPACE )
64     if(error)
65         message(FATAL_ERROR "Error retrieving FastJet compilation flags : ${error}")
66     endif(error)
67     
68     # Extracting the include path from the CXX flags
69     set(FASTJET_INCLUDE_DIR)
70     if(FASTJET_CXXFLAGS)
71         string(STRIP ${FASTJET_CXXFLAGS} FASTJET_CXXFLAGS)
72         string(REGEX MATCHALL  "[-][I]([^ ])+" incfolders ${FASTJET_CXXFLAGS})
73         
74         foreach(incfolder ${incfolders})
75             string(REPLACE "-I" "" incfolder ${incfolder})
76             set(FASTJET_INCLUDE_DIR ${incfolder} ${FASTJET_INCLUDE_DIR})
77         endforeach()
78     endif(FASTJET_CXXFLAGS)
79
80     # Extracting libraries and linking options
81     execute_process(COMMAND ${FASTJET_CONFIG} --libs OUTPUT_VARIABLE FASTJET_CONFIGLIBS ERROR_VARIABLE error OUTPUT_STRIP_TRAILING_WHITESPACE )
82     if(error)
83         message(FATAL_ERROR "Error retrieving FastJet libs : ${error}")
84     endif(error)
85     
86     # Extracting the list of needed libraries during linking and the linking folders
87     set(FASTJET_LIBS)
88     set(FASTJET_LIBS_DIR)
89     if(FASTJET_CONFIGLIBS)
90         string(STRIP ${FASTJET_CONFIGLIBS} FASTJET_CONFIGLIBS)
91         
92         # Extracting the list of libraries needed during linking
93         # -l strings
94         string(REGEX MATCHALL "[-][l]([^ ])+" fjlibs "${FASTJET_CONFIGLIBS}")
95     
96         foreach(flib ${fjlibs})
97             string(REPLACE "-l" "" flib "${flib}")
98             set(FASTJET_LIBS ${FASTJET_LIBS} ${flib})
99         endforeach()
100
101         # Extracting the list of libraries folders
102         # -L strings
103         string(REGEX MATCHALL "[-][L]([^ ])+" fjlibdirs "${FASTJET_CONFIGLIBS}")
104         
105         foreach(fjlibdir ${fjlibdirs})
106             string(REPLACE "-L" "" fjlibdir ${fjlibdir})
107             set(FASTJET_LIBS_DIR ${fjlibdir} ${FASTJET_LIBS_DIR})
108         endforeach()
109     endif()
110
111     set(FASTJET_FOUND TRUE)
112     set(FASTJET_DEFINITIONS "-DHAVE_FASTJET")
113     message(STATUS "FastJet ${FASTJET_VERSION_MAJOR}.${FASTJET_VERSION_MINOR}.${FASTJET_VERSION_PATCH} installation found: ${FASTJET}")
114 else()
115     message(STATUS "FastJet not found: disabling dependencies")
116 endif(FASTJET)