CDECK  ID>, HWWARN.

*CMZ :-        -26/04/91  10.18.58  by  Bryan Webber

*-- Author :    Bryan Webber

C-----------------------------------------------------------------------

      SUBROUTINE HWWARN(SUBRTN,ICODE,*)

C-----------------------------------------------------------------------

C     DEALS WITH ERRORS DURING EXECUTION

C     SUBRTN = NAME OF CALLING SUBROUTINE

C     ICODE  = ERROR CODE:    - -1 NONFATAL, KILL EVENT & PRINT NOTHING

C                            0- 49 NONFATAL, PRINT WARNING & CONTINUE

C                           50- 99 NONFATAL, PRINT WARNING & JUMP

C                          100-199 NONFATAL, DUMP & KILL EVENT

C                          200-299    FATAL, TERMINATE RUN

C                          300-399    FATAL, DUMP EVENT & TERMINATE RUN

C                          400-499    FATAL, DUMP EVENT & STOP DEAD

C                          500-       FATAL, STOP DEAD WITH NO DUMP

C-----------------------------------------------------------------------

      INCLUDE 'HERWIG61.INC'

      INTEGER ICODE

      CHARACTER*6 SUBRTN

      IF (ICODE.GE.0) WRITE (6,10) SUBRTN,ICODE

   10 FORMAT(/' HWWARN CALLED FROM SUBPROGRAM ',A6,': CODE =',I4)

      IF (ICODE.LT.0) THEN

         IERROR=ICODE

         RETURN 1

      ELSEIF (ICODE.LT.100) THEN

         WRITE (6,20) NEVHEP,NRN,EVWGT

   20    FORMAT(' EVENT',I8,':   SEEDS =',I11,' &',I11,

     &'  WEIGHT =',E11.4/' EVENT SURVIVES. EXECUTION CONTINUES')

         IF (ICODE.GT.49) RETURN 1

      ELSEIF (ICODE.LT.200) THEN

         WRITE (6,30) NEVHEP,NRN,EVWGT

   30    FORMAT(' EVENT',I8,':   SEEDS =',I11,' &',I11,

     &'  WEIGHT =',E11.4/' EVENT KILLED.   EXECUTION CONTINUES')

         IERROR=ICODE

         RETURN 1

      ELSEIF (ICODE.LT.300) THEN

         WRITE (6,40)

   40    FORMAT(' EVENT SURVIVES.  RUN ENDS GRACEFULLY')

         CALL HWEFIN

c-jgc         CALL HWAEND

         STOP

      ELSEIF (ICODE.LT.400) THEN

         WRITE (6,50)

   50    FORMAT(' EVENT KILLED: DUMP FOLLOWS.  RUN ENDS GRACEFULLY')

         IERROR=ICODE

         CALL HWUEPR

         CALL HWUBPR

         CALL HWEFIN

c-jgc         CALL HWAEND

         STOP

      ELSEIF (ICODE.LT.500) THEN

         WRITE (6,60)

   60    FORMAT(' EVENT KILLED: DUMP FOLLOWS.  RUN STOPS DEAD')

         IERROR=ICODE

         CALL HWUEPR

         CALL HWUBPR

         STOP

      ELSE

         WRITE (6,70)

   70    FORMAT(' RUN CANNOT CONTINUE')

         STOP

      ENDIF

      END