lib/RT/Action/AutoOpen.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2012 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 # This Action will open the BASE if a dependent is resolved.
  50 package RT::Action::AutoOpen;
  51
  52 use strict;
  53 use warnings;
  54 use base qw(RT::Action);
  55
  56 =head1 DESCRIPTION
  57
  58 This action automatically moves a ticket to an active status.
  59
  60 Status is not changed if there is no active statuses in the lifecycle.
  61
  62 Status is not changed if the current status is first active for ticket's status
  63 lifecycle. For example if ticket's status is 'processing' and active statuses are
  64 'processing', 'on hold' and 'waiting' then status is not changed, but for ticket
  65 with status 'on hold' other rules are checked.
  66
  67 Status is not changed if it's in the list of C<initial> statuses for the
  68 current scheme and creator of the current transaction
  69 is one of the ticket's requestors.
  70
  71 Status is not changed if message's head has field C<RT-Control> with C<no-autoopen>
  72 substring.
  73
  74 Status is set to the first possible active status. If the ticket's
  75 status is C<Stalled> then RT finds all possible transitions from C<Stalled>
  76 status and selects first one that results in the ticket having an
  77 active status.
  78
  79 =cut
  80
  81 sub Prepare {
  82     my $self = shift;
  83
  84     my $ticket = $self->TicketObj;
  85     my $next = $ticket->FirstActiveStatus;
  86     return 1 unless defined $next;
  87
  88     # no change if the ticket is in initial status and the message is a mail
  89     # from a requestor
  90     return 1 if $ticket->QueueObj->Lifecycle->IsInitial($ticket->Status)
  91         && $self->TransactionObj->IsInbound;
  92
  93     if ( my $msg = $self->TransactionObj->Message->First ) {
  94         return 1 if ($msg->GetHeader('RT-Control') || '') =~ /\bno-autoopen\b/i;
  95     }
  96
  97     $self->{'set_status_to'} = $next;
  98
  99     return 1;
 100 }
 101
 102 sub Commit {
 103     my $self = shift;
 104
 105     return 1 unless my $new_status = $self->{'set_status_to'};
 106
 107     my ($val, $msg) = $self->TicketObj->SetStatus( $new_status );
 108     unless ( $val ) {
 109         $RT::Logger->error( "Couldn't auto-open ticket: ". $msg );
 110         return 0;
 111     }
 112     return 1;
 113 }
 114
 115 RT::Base->_ImportOverlays();
 116
 117 1;