lib/RT/Action/ExtractSubjectTag.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2014 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 =head1 NAME
  50
  51   RT::Action::ExtractSubjectTag
  52
  53 =head1 DESCRIPTION
  54
  55 ExtractSubjectTag is a ScripAction which allows ticket bonding between
  56 two RT instances or between RT and other Ticket systems like Siebel
  57 or Remedy.
  58
  59 By default this ScripAction is set up to run on every transaction on
  60 every Correspondence.
  61
  62 One can configure this ScripActions behaviour by changing the
  63 global C<$ExtractSubjectTagMatch> in C<RT_Config.pm>.
  64
  65 If a transaction's subject matches this regexp, we append the match
  66 tag to the ticket's current subject. This helps ensure that
  67 further communication on the ticket will include the remote
  68 system's subject tag.
  69
  70 If you modify this code, be careful not to remove the code where it
  71 ensures that it only examines remote systems' tags.
  72
  73 =head1 EXAMPLE
  74
  75 As an example, Siebel will set their subject tag to something
  76 like:
  77
  78     B<[SR ID:1-554]>
  79
  80 To record this tag in the local ticket's subject, we need to change
  81 ExtractSubjectTagMatch to something like:
  82
  83     Set($ExtractSubjectTagMatch, qr/\[[^\]]+[#:][0-9-]+\]/);
  84
  85 =cut
  86
  87 package RT::Action::ExtractSubjectTag;
  88 use base 'RT::Action';
  89 use strict;
  90 use warnings;
  91
  92 sub Describe {
  93     my $self = shift;
  94     return ( ref $self );
  95 }
  96
  97 sub Prepare {
  98     return (1);
  99 }
 100
 101 sub Commit {
 102     my $self            = shift;
 103     my $Transaction     = $self->TransactionObj;
 104     my $FirstAttachment = $Transaction->Attachments->First;
 105     return 1 unless $FirstAttachment;
 106
 107     my $TransactionSubject = $FirstAttachment->Subject;
 108     return 1 unless $TransactionSubject;
 109
 110     my $Ticket = $self->TicketObj;
 111
 112     my $TicketSubject      = $self->TicketObj->Subject;
 113     my $origTicketSubject  = $TicketSubject;
 114
 115     my $match   = RT->Config->Get('ExtractSubjectTagMatch');
 116     my $nomatch = RT->Config->Get('ExtractSubjectTagNoMatch');
 117     TAGLIST: while ( $TransactionSubject =~ /($match)/g ) {
 118         my $tag = $1;
 119         next if $tag =~ /$nomatch/;
 120         foreach my $subject_tag ( RT->System->SubjectTag ) {
 121             if ($tag =~ /\[\Q$subject_tag\E\s+\#(\d+)\s*\]/) {
 122                 next TAGLIST;
 123             }
 124         }
 125         $TicketSubject .= " $tag" unless ( $TicketSubject =~ /\Q$tag\E/ );
 126     }
 127
 128     $self->TicketObj->SetSubject($TicketSubject)
 129         if ( $TicketSubject ne $origTicketSubject );
 130
 131     return (1);
 132 }
 133
 134 RT::Base->_ImportOverlays();
 135
 136 1;