lib/RT/Util.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2012 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 package RT::Util;
  50 use strict;
  51 use warnings;
  52
  53
  54 use base 'Exporter';
  55 our @EXPORT = qw/safe_run_child mime_recommended_filename/;
  56
  57 sub safe_run_child (&) {
  58     my $our_pid = $$;
  59
  60     # situation here is wierd, running external app
  61     # involves fork+exec. At some point after fork,
  62     # but before exec (or during) code can die in a
  63     # child. Local is no help here as die throws
  64     # error out of scope and locals are reset to old
  65     # values. Instead we set values, eval code, check pid
  66     # on failure and reset values only in our original
  67     # process
  68     my $dbh = $RT::Handle->dbh;
  69     $dbh->{'InactiveDestroy'} = 1 if $dbh;
  70     $RT::Handle->{'DisconnectHandleOnDestroy'} = 0;
  71
  72     my ($reader, $writer);
  73     pipe( $reader, $writer );
  74
  75     my @res;
  76     my $want = wantarray;
  77     eval {
  78         my $code = shift;
  79         local @ENV{ 'LANG', 'LC_ALL' } = ( 'C', 'C' );
  80         unless ( defined $want ) {
  81             $code->();
  82         } elsif ( $want ) {
  83             @res = $code->();
  84         } else {
  85             @res = ( scalar $code->() );
  86         }
  87         exit 0 if $our_pid != $$;
  88         1;
  89     } or do {
  90         my $err = $@;
  91         $err =~ s/^Stack:.*$//ms;
  92         if ( $our_pid == $$ ) {
  93             $dbh->{'InactiveDestroy'} = 0 if $dbh;
  94             $RT::Handle->{'DisconnectHandleOnDestroy'} = 1;
  95             die "System Error: $err";
  96         } else {
  97             print $writer "System Error: $err";
  98             exit 1;
  99         }
 100     };
 101
 102     close($writer);
 103     $reader->blocking(0);
 104     my ($response) = $reader->getline;
 105     warn $response if $response;
 106
 107     $dbh->{'InactiveDestroy'} = 0 if $dbh;
 108     $RT::Handle->{'DisconnectHandleOnDestroy'} = 1;
 109     return $want? (@res) : $res[0];
 110 }
 111
 112 =head2 mime_recommended_filename( MIME::Head|MIME::Entity )
 113
 114 # mimic our own recommended_filename
 115 # since MIME-tools 5.501, head->recommended_filename requires the head are
 116 # mime encoded, we don't meet this yet.
 117
 118 =cut
 119
 120 sub mime_recommended_filename {
 121     my $head = shift;
 122     $head = $head->head if $head->isa('MIME::Entity');
 123
 124     for my $attr_name (qw( content-disposition.filename content-type.name )) {
 125         my $value = $head->mime_attr($attr_name);
 126         if ( defined $value && $value =~ /\S/ ) {
 127             return $value;
 128         }
 129     }
 130     return;
 131 }
 132
 133 RT::Base->_ImportOverlays();
 134
 135 1;