Upgrade to 4.2.2
[usit-rt.git] / sbin / rt-serializer
1 #!/usr/bin/perl
2 # BEGIN BPS TAGGED BLOCK {{{
3 #
4 # COPYRIGHT:
5 #
6 # This software is Copyright (c) 1996-2014 Best Practical Solutions, LLC
7 #                                          <sales@bestpractical.com>
8 #
9 # (Except where explicitly superseded by other copyright notices)
10 #
11 #
12 # LICENSE:
13 #
14 # This work is made available to you under the terms of Version 2 of
15 # the GNU General Public License. A copy of that license should have
16 # been provided with this software, but in any event can be snarfed
17 # from www.gnu.org.
18 #
19 # This work is distributed in the hope that it will be useful, but
20 # WITHOUT ANY WARRANTY; without even the implied warranty of
21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
22 # General Public License for more details.
23 #
24 # You should have received a copy of the GNU General Public License
25 # along with this program; if not, write to the Free Software
26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
27 # 02110-1301 or visit their web page on the internet at
28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
29 #
30 #
31 # CONTRIBUTION SUBMISSION POLICY:
32 #
33 # (The following paragraph is not intended to limit the rights granted
34 # to you to modify and distribute this software under the terms of
35 # the GNU General Public License and is only of importance to you if
36 # you choose to contribute your changes and enhancements to the
37 # community by submitting them to Best Practical Solutions, LLC.)
38 #
39 # By intentionally submitting any modifications, corrections or
40 # derivatives to this work, or any other work intended for use with
41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
42 # you are the copyright holder for those contributions and you grant
43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
44 # royalty-free, perpetual, license to use, copy, create derivative
45 # works based on those contributions, and sublicense and distribute
46 # those contributions and any derivatives thereof.
47 #
48 # END BPS TAGGED BLOCK }}}
49 use strict;
50 use warnings;
51
52 # fix lib paths, some may be relative
53 BEGIN {
54     require File::Spec;
55     my @libs = ("lib", "local/lib");
56     my $bin_path;
57
58     for my $lib (@libs) {
59         unless ( File::Spec->file_name_is_absolute($lib) ) {
60             unless ($bin_path) {
61                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
62                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
63                 }
64                 else {
65                     require FindBin;
66                     no warnings "once";
67                     $bin_path = $FindBin::Bin;
68                 }
69             }
70             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
71         }
72         unshift @INC, $lib;
73     }
74
75 }
76
77 use RT;
78 RT::LoadConfig();
79 RT->Config->Set(RecordBaseClass => "DBIx::SearchBuilder::Record");
80 RT::Init();
81
82 use RT::Migrate;
83 use RT::Migrate::Serializer::File;
84 use Getopt::Long;
85 use Pod::Usage qw//;
86 use Time::HiRes qw//;
87
88 my %OPT;
89 GetOptions(
90     \%OPT,
91     "help|?",
92     "verbose|v!",
93     "quiet|q!",
94
95     "directory|d=s",
96     "force|f!",
97     "size|s=i",
98
99     "users!",
100     "groups!",
101     "deleted!",
102
103     "scrips!",
104     "tickets!",
105     "acls!",
106
107     "clone",
108     "incremental",
109
110     "gc=i",
111     "page=i",
112 ) or Pod::Usage::pod2usage();
113
114 Pod::Usage::pod2usage(-verbose => 1) if $OPT{help};
115
116 my %args;
117 $args{Directory}   = $OPT{directory};
118 $args{Force}       = $OPT{force};
119 $args{MaxFileSize} = $OPT{size} if $OPT{size};
120
121 $args{AllUsers}      = $OPT{users}    if defined $OPT{users};
122 $args{AllGroups}     = $OPT{groups}   if defined $OPT{groups};
123 $args{FollowDeleted} = $OPT{deleted}  if defined $OPT{deleted};
124
125 $args{FollowScrips}  = $OPT{scrips}   if defined $OPT{scrips};
126 $args{FollowTickets} = $OPT{tickets}  if defined $OPT{tickets};
127 $args{FollowACL}     = $OPT{acls}     if defined $OPT{acls};
128
129 $args{Clone}         = $OPT{clone}       if $OPT{clone};
130 $args{Incremental}   = $OPT{incremental} if $OPT{incremental};
131
132 $args{GC}   = defined $OPT{gc}   ? $OPT{gc}   : 5000;
133 $args{Page} = defined $OPT{page} ? $OPT{page} : 100;
134
135 if (($OPT{clone} or $OPT{incremental})
136         and grep { /^(users|groups|deleted|scrips|tickets|acls)$/ } keys %OPT) {
137     die "You cannot specify object types when cloning.\n\nPlease see $0 --help.\n";
138 }
139
140 my $walker;
141
142 my $gnuplot = `which gnuplot`;
143 my $msg = "";
144 if (-t STDOUT and not $OPT{verbose} and not $OPT{quiet}) {
145     $args{Progress} = RT::Migrate::progress(
146         top    => \&gnuplot,
147         bottom => sub { print "\n$msg"; $msg = ""; },
148         counts => sub { $walker->ObjectCount },
149         max    => { estimate() },
150     );
151     $args{MessageHandler} = sub {
152         print "\r", " "x60, "\r", $_[-1]; $msg = $_[-1];
153     };
154     $args{Verbose}  = 0;
155 }
156 $args{Verbose} = 0 if $OPT{quiet};
157
158
159 $walker = RT::Migrate::Serializer::File->new( %args );
160
161 my $log = RT::Migrate::setup_logging( $walker->{Directory} => 'serializer.log' );
162 print "Logging warnings and errors to $log\n" if $log;
163
164 print "Beginning database serialization...";
165 my %counts = $walker->Export;
166
167 my @files = $walker->Files;
168 print "Wrote @{[scalar @files]} files:\n";
169 print "    $_\n" for @files;
170 print "\n";
171
172 print "Total object counts:\n";
173 for (sort {$counts{$b} <=> $counts{$a}} keys %counts) {
174     printf "%8d %s\n", $counts{$_}, $_;
175 }
176
177 if ($log and -s $log) {
178     print STDERR "\n! Some warnings or errors occurred during serialization."
179                 ."\n! Please see $log for details.\n\n";
180 } else {
181     unlink $log;
182 }
183
184 sub estimate {
185     $| = 1;
186     my %e;
187
188     # Expected types we'll serialize
189     my @types = map {"RT::$_"} qw/
190         Queue Ticket Transaction Attachment Link
191         User  Group  GroupMember Attribute
192         CustomField CustomFieldValue
193         ObjectCustomField ObjectCustomFieldValue
194                                  /;
195
196     for my $class (@types) {
197         print "Estimating $class count...";
198         my $collection = $class . "s";
199         eval "require $collection";
200         unless ($@) {
201             my $objs = $collection->new( RT->SystemUser );
202             $objs->FindAllRows;
203             $objs->UnLimit;
204             $objs->{allow_deleted_search} = 1 if $class eq "RT::Ticket";
205             $e{$class} = $objs->DBIx::SearchBuilder::Count;
206         }
207         print "\r", " "x60, "\r";
208     }
209
210     return %e;
211 }
212
213
214 sub gnuplot {
215     my ($elapsed, $rows, $cols) = @_;
216     my $length = $walker->StackSize;
217     my $file = $walker->Directory . "/progress.plot";
218     open(my $dat, ">>", $file);
219     printf $dat "%10.3f\t%8d\n", $elapsed, $length;
220     close $dat;
221
222     if ($rows <= 24 or not $gnuplot) {
223         print "\n\n";
224     } elsif ($elapsed) {
225         my $gnuplot = qx|
226             gnuplot -e '
227                 set term dumb $cols @{[$rows - 12]};
228                 set xlabel "Seconds";
229                 unset key;
230                 set xrange [0:*];
231                 set yrange [0:*];
232                 set title "Queue length";
233                 plot "$file" using 1:2 with lines
234             '
235         |;
236         if ($? == 0 and $gnuplot) {
237             $gnuplot =~ s/^(\s*\n)//;
238             print $gnuplot;
239             unlink $file;
240         } else {
241             warn "Couldn't run gnuplot (\$? == $?): $!\n";
242         }
243     } else {
244         print "\n" for 1..($rows - 13);
245     }
246 }
247
248 =head1 NAME
249
250 rt-serializer - Serialize an RT database to disk
251
252 =head1 SYNOPSIS
253
254     rt-validator --check && rt-serializer
255
256 This script is used to write out the entire RT database to disk, for
257 later import into a different RT instance.  It requires that the data in
258 the database be self-consistent, in order to do so; please make sure
259 that the database being exported passes validation by L<rt-validator>
260 before attempting to use C<rt-serializer>.
261
262 While running, it will attempt to estimate the number of remaining
263 objects to be serialized; these estimates are pessimistic, and will be
264 incorrect if C<--no-users>, C<--no-groups>, or C<--no-tickets> are used.
265
266 If the controlling terminal is large enough (more than 25 columns high)
267 and the C<gnuplot> program is installed, it will also show a textual
268 graph of the queue size over time.
269
270 =head2 OPTIONS
271
272 =over
273
274 =item B<--directory> I<name>
275
276 The name of the output directory to write data files to, which should
277 not exist yet; it is a fatal error if it does.  Defaults to
278 C<< ./I<$Organization>:I<Date>/ >>, where I<$Organization> is as set in
279 F<RT_SiteConfig.pm>, and I<Date> is today's date.
280
281 =item B<--force>
282
283 Remove the output directory before starting.
284
285 =item B<--size> I<megabytes>
286
287 By default, C<rt-serializer> chunks its output into data files which are
288 around 32Mb in size; this option is used to set a different threshold
289 size, in megabytes.  Note that this is the threshold after which it
290 rotates to writing a new file, and is as such the I<lower bound> on the
291 size of each output file.
292
293 =item B<--no-users>
294
295 By default, all privileged users are serialized; passing C<--no-users>
296 limits it to only those users which are strictly necessary.
297
298 =item B<--no-groups>
299
300 By default, all groups are serialized; passing C<--no-groups> limits it
301 to only those groups which are strictly necessary.
302
303 =item B<--no-deleted>
304
305 By default, all tickets, including deleted tickets, are serialized;
306 passing C<--no-deleted> skips deleted tickets during serialization.
307
308 =item B<--scrips>
309
310 No scrips or templates are serialized by default; this option forces all
311 scrips and templates to be serialized.
312
313 =item B<--acls>
314
315 No ACLs are serialized by default; this option forces all ACLs to be
316 serialized.
317
318 =item B<--no-tickets>
319
320 Skip serialization of all ticket data.
321
322 =item B<--clone>
323
324 Serializes your entire database, creating a clone.  This option should
325 be used if you want to migrate your RT database from one database type
326 to another (e.g.  MySQL to Postgres).  It is an error to combine
327 C<--clone> with any option that limits object types serialized.  No
328 dependency walking is performed when cloning. C<rt-importer> will detect
329 that your serialized data set was generated by a clone.
330
331 =item B<--incremental>
332
333 Will generate an incremenal serialized dataset using the data stored in
334 your IncrementalRecords database table.  This assumes that you have created
335 that table and run RT using the Record_Local.pm shim as documented in
336 C<docs/incremental-export/>.
337
338 =item B<--gc> I<n>
339
340 Adjust how often the garbage collection sweep is done; lower numbers are
341 more frequent.  See L</GARBAGE COLLECTION>.
342
343 =item B<--page> I<n>
344
345 Adjust how many rows are pulled from the database in a single query.  Disable
346 paging by setting this to 0.  Defaults to 100.
347
348 Keep in mind that rows from RT's Attachments table are the limiting factor when
349 determining page size.  You should likely be aiming for 60-75% of your total
350 memory on an otherwise unloaded box.
351
352 =item B<--quiet>
353
354 Do not show graphical progress UI.
355
356 =item B<--verbose>
357
358 Do not show graphical progress UI, but rather log was each row is
359 written out.
360
361 =back
362
363 =head1 GARBAGE COLLECTION
364
365 C<rt-serializer> maintains a priority queue of objects to serialize, or
366 searches which may result in objects to serialize.  When inserting into
367 this queue, it does no checking if the object in question is already in
368 the queue, or if the search will contain any results.  These checks are
369 done when the object reaches the front of the queue, or during periodic
370 garbage collection.
371
372 During periodic garbage collection, the entire queue is swept for
373 objects which have already been serialized, occur more than once in the
374 queue, and searches which contain no results in the database.  This is
375 done to reduce the memory footprint of the serialization process, and is
376 triggered when enough new objects have been placed in the queue.  This
377 parameter is tunable via the C<--gc> parameter, which defaults to
378 running garbage collection every 5,000 objects inserted into the queue;
379 smaller numbers will result in more frequent garbage collection.
380
381 The default of 5,000 is roughly tuned based on a database with several
382 thousand tickets, but optimal values will vary wildly depending on
383 database configuration and size.  Values as low as 25 have provided
384 speedups with smaller databases; if speed is a factor, experimenting
385 with different C<--gc> values may be helpful.  Note that there are
386 significant boundary condition changes in serialization rate, as the
387 queue empties and fills, causing the time estimates to be rather
388 imprecise near the start and end of the process.
389
390 Setting C<--gc> to 0 turns off all garbage collection.  Be aware that
391 this will bloat the memory usage of the serializer.  Any negative value
392 for C<--gc> turns off periodic garbage collection and instead objects
393 already serialized or in the queue are checked for at the time they
394 would be inserted.
395
396 =cut
397