Upgrade to 4.0.10.
[usit-rt.git] / sbin / rt-server.fcgi
1 #!/usr/bin/perl -w
2 # BEGIN BPS TAGGED BLOCK {{{
3 #
4 # COPYRIGHT:
5 #
6 # This software is Copyright (c) 1996-2013 Best Practical Solutions, LLC
7 #                                          <sales@bestpractical.com>
8 #
9 # (Except where explicitly superseded by other copyright notices)
10 #
11 #
12 # LICENSE:
13 #
14 # This work is made available to you under the terms of Version 2 of
15 # the GNU General Public License. A copy of that license should have
16 # been provided with this software, but in any event can be snarfed
17 # from www.gnu.org.
18 #
19 # This work is distributed in the hope that it will be useful, but
20 # WITHOUT ANY WARRANTY; without even the implied warranty of
21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
22 # General Public License for more details.
23 #
24 # You should have received a copy of the GNU General Public License
25 # along with this program; if not, write to the Free Software
26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
27 # 02110-1301 or visit their web page on the internet at
28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
29 #
30 #
31 # CONTRIBUTION SUBMISSION POLICY:
32 #
33 # (The following paragraph is not intended to limit the rights granted
34 # to you to modify and distribute this software under the terms of
35 # the GNU General Public License and is only of importance to you if
36 # you choose to contribute your changes and enhancements to the
37 # community by submitting them to Best Practical Solutions, LLC.)
38 #
39 # By intentionally submitting any modifications, corrections or
40 # derivatives to this work, or any other work intended for use with
41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
42 # you are the copyright holder for those contributions and you grant
43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
44 # royalty-free, perpetual, license to use, copy, create derivative
45 # works based on those contributions, and sublicense and distribute
46 # those contributions and any derivatives thereof.
47 #
48 # END BPS TAGGED BLOCK }}}
49 use warnings;
50 use strict;
51
52 # fix lib paths, some may be relative
53 BEGIN {
54     die <<EOT if ${^TAINT};
55 RT does not run under Perl's "taint mode".  Remove -T from the command
56 line, or remove the PerlTaintCheck parameter from your mod_perl
57 configuration.
58 EOT
59
60     require File::Spec;
61     my @libs = ("lib", "local/lib");
62     my $bin_path;
63
64     for my $lib (@libs) {
65         unless ( File::Spec->file_name_is_absolute($lib) ) {
66             unless ($bin_path) {
67                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
68                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
69                 }
70                 else {
71                     require FindBin;
72                     no warnings "once";
73                     $bin_path = $FindBin::Bin;
74                 }
75             }
76             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
77         }
78         unshift @INC, $lib;
79     }
80
81 }
82
83 use Getopt::Long;
84 no warnings 'once';
85
86 if (grep { m/help/ } @ARGV) {
87     require Pod::Usage;
88     print Pod::Usage::pod2usage( { verbose => 2 } );
89     exit;
90 }
91
92 require RT;
93 RT->LoadConfig();
94 RT->InitPluginPaths();
95 RT->InitLogging();
96 require Module::Refresh if RT->Config->Get('DevelMode');
97
98 require RT::Handle;
99 my ($integrity, $state, $msg) = RT::Handle->CheckIntegrity;
100
101 unless ( $integrity ) {
102     print STDERR <<EOF;
103     
104 RT couldn't connect to the database where tickets are stored.
105 If this is a new installation of RT, you should visit the URL below
106 to configure RT and initialize your database.
107
108 If this is an existing RT installation, this may indicate a database
109 connectivity problem.
110
111 The error RT got back when trying to connect to your database was:
112
113 $msg
114
115 EOF
116
117     require RT::Installer;
118     # don't enter install mode if the file exists but is unwritable
119     if (-e RT::Installer->ConfigFile && !-w _) {
120         die 'Since your configuration exists ('
121           . RT::Installer->ConfigFile
122           . ") but is not writable, I'm refusing to do anything.\n";
123     }
124
125     RT->Config->Set( 'LexiconLanguages' => '*' );
126     RT::I18N->Init;
127
128     RT->InstallMode(1);
129 } else {
130     RT->Init();
131
132     my ($status, $msg) = RT::Handle->CheckCompatibility( $RT::Handle->dbh, 'post');
133     unless ( $status ) {
134         print STDERR $msg, "\n\n";
135         exit -1;
136     }
137 }
138
139 # we must disconnect DB before fork
140 if ($RT::Handle) {
141     $RT::Handle->dbh(undef);
142     undef $RT::Handle;
143 }
144
145 require RT::Interface::Web::Handler;
146 my $app = RT::Interface::Web::Handler->PSGIApp;
147
148 if ($ENV{RT_TESTING}) {
149     my $screen_logger = $RT::Logger->remove('screen');
150     require Log::Dispatch::Perl;
151     $RT::Logger->add(
152         Log::Dispatch::Perl->new(
153             name      => 'rttest',
154             min_level => $screen_logger->min_level,
155             action    => {
156                 error    => 'warn',
157                 critical => 'warn'
158             }
159         )
160     );
161     require Plack::Middleware::Test::StashWarnings;
162     $app = Plack::Middleware::Test::StashWarnings->wrap($app);
163 }
164
165 # when used as a psgi file
166 if (caller) {
167     return $app;
168 }
169
170
171 # load appropriate server
172
173 require Plack::Runner;
174
175 my $is_fastcgi = $0 =~ m/fcgi$/;
176 my $r = Plack::Runner->new( $0 =~ /standalone/ ? ( server => 'Standalone' ) :
177                             $is_fastcgi        ? ( server => 'FCGI' )
178                                                : (),
179                             env => 'deployment' );
180
181 # figure out the port
182 my $port;
183
184 # handle "rt-server 8888" for back-compat, but complain about it
185 if ($ARGV[0] && $ARGV[0] =~ m/^\d+$/) {
186     warn "Deprecated: please run $0 --port $ARGV[0] instead\n";
187     unshift @ARGV, '--port';
188 }
189
190 my @args = @ARGV;
191
192 use List::MoreUtils 'last_index';
193 my $last_index = last_index { $_ eq '--port' } @args;
194
195 my $explicit_port;
196
197 if ( $last_index != -1 && $args[$last_index+1] =~ /^\d+$/ ) {
198     $explicit_port = $args[$last_index+1];
199     $port = $explicit_port;
200
201     # inform the rest of the system what port we manually chose
202     my $old_app = $app;
203     $app = sub {
204         my $env = shift;
205
206         $env->{'rt.explicit_port'} = $port;
207
208         $old_app->($env, @_);
209     };
210 }
211 else {
212     # default to the configured WebPort and inform Plack::Runner
213     $port = RT->Config->Get('WebPort') || '8080';
214     push @args, '--port', $port;
215 }
216
217 push @args, '--server', 'Standalone' if RT->InstallMode;
218 push @args, '--server', 'Starlet' unless $r->{server} || grep { m/--server/ } @args;
219
220 $r->parse_options(@args);
221
222 delete $r->{options} if $is_fastcgi; ### mangle_host_port_socket ruins everything
223
224 unless ($r->{env} eq 'development') {
225     push @{$r->{options}}, server_ready => sub {
226         my($args) = @_;
227         my $name  = $args->{server_software} || ref($args); # $args is $server
228         my $host  = $args->{host} || 0;
229         my $proto = $args->{proto} || 'http';
230         print STDERR "$name: Accepting connections at $proto://$host:$args->{port}/\n";
231     };
232 }
233 eval { $r->run($app) };
234 if (my $err = $@) {
235     handle_startup_error($err);
236 }
237
238 exit 0;
239
240 sub handle_startup_error {
241     my $err = shift;
242     if ( $err =~ /listen/ ) {
243         handle_bind_error();
244     } else {
245         die
246             "Something went wrong while trying to run RT's standalone web server:\n\t"
247             . $err;
248     }
249 }
250
251
252 sub handle_bind_error {
253
254     print STDERR <<EOF;
255 WARNING: RT couldn't start up a web server on port @{[$port]}.
256 This is often the case if the port is already in use or you're running @{[$0]} 
257 as someone other than your system's "root" user.  You may also specify a
258 temporary port with: $0 --port <port>
259 EOF
260
261     if ($explicit_port) {
262         print STDERR
263             "Please check your system configuration or choose another port\n\n";
264     }
265 }
266
267 __END__
268
269 =head1 NAME
270
271 rt-server - RT standalone server
272
273 =head1 SYNOPSIS
274
275     # runs prefork server listening on port 8080, requires Starlet
276     rt-server --port 8080
277
278     # runs server listening on port 8080
279     rt-server --server Standalone --port 8080
280     # or
281     standalone_httpd --port 8080
282
283     # runs other PSGI server on port 8080
284     rt-server --server Starman --port 8080