sbin/rt-shredder

   1 #!/usr/bin/perl
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2013 Best Practical Solutions, LLC
   7 #                                          <sales@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 =head1 NAME
  50
  51 rt-shredder - Script which wipe out tickets from RT DB
  52
  53 =head1 SYNOPSIS
  54
  55   rt-shredder --plugin list
  56   rt-shredder --plugin help-Tickets
  57   rt-shredder --plugin 'Tickets=query,Queue="general" and Status="deleted"'
  58
  59   rt-shredder --sqldump unshred.sql --plugin ...
  60   rt-shredder --force --plugin ...
  61
  62 =head1 DESCRIPTION
  63
  64 rt-shredder - is script that allow you to wipe out objects
  65 from RT DB. This script uses API that L<RT::Shredder> module adds to RT.
  66 Script can be used as example of usage of the shredder API.
  67
  68 =head1 USAGE
  69
  70 You can use several options to control which objects script
  71 should wipeout.
  72
  73 =head1 OPTIONS
  74
  75 =head2 --sqldump <filename>
  76
  77 Outputs INSERT queries into file. This dump can be used to restore data
  78 after wiping out.
  79
  80 By default creates files
  81 F<< <RT_home>/var/data/RT-Shredder/<ISO_date>-XXXX.sql >>
  82
  83 =head2 --object (DEPRECATED)
  84
  85 Option has been deprecated, use plugin C<Objects> instead.
  86
  87 =head2 --plugin '<plugin name>[=<arg>,<val>[;<arg>,<val>]...]'
  88
  89 You can use plugins to select RT objects with various conditions.
  90 See also --plugin list and --plugin help options.
  91
  92 =head2 --plugin list
  93
  94 Output list of the available plugins.
  95
  96 =head2 --plugin help-<plugin name>
  97
  98 Outputs help for specified plugin.
  99
 100 =head2 --force
 101
 102 Script doesn't ask any questions.
 103
 104 =head1 SEE ALSO
 105
 106 L<RT::Shredder>
 107
 108 =cut
 109
 110 use strict;
 111 use warnings FATAL => 'all';
 112 use lib '/www/data/rt/rt-perl/current-perl10/share/perl5';
 113 use lib '/www/data/rt/rt-perl/current-perl10/lib/perl5';
 114 use lib '/www/data/rt/rt-perl/current-perl10/lib64/perl5';
 115
 116 use lib ("/www/var/rt/local/lib", "/www/var/rt/lib");
 117
 118 # fix lib paths, some may be relative
 119 BEGIN {
 120     require File::Spec;
 121     my @libs = ("lib", "local/lib");
 122     my $bin_path;
 123
 124     for my $lib (@libs) {
 125         unless ( File::Spec->file_name_is_absolute($lib) ) {
 126             unless ($bin_path) {
 127                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
 128                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
 129                 }
 130                 else {
 131                     require FindBin;
 132                     no warnings "once";
 133                     $bin_path = $FindBin::Bin;
 134                 }
 135             }
 136             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
 137         }
 138         unshift @INC, $lib;
 139     }
 140
 141 }
 142
 143 use RT -init;
 144
 145 require RT::Shredder;
 146
 147 use Getopt::Long qw(GetOptions);
 148 use File::Spec ();
 149
 150 use RT::Shredder::Plugin ();
 151 # prefetch list of plugins
 152 our %plugins = RT::Shredder::Plugin->List;
 153
 154 our %opt;
 155 parse_args();
 156
 157 my $shredder = RT::Shredder->new;
 158
 159 {
 160     my $plugin = eval { $shredder->AddDumpPlugin( Arguments => {
 161         file_name    => $opt{'sqldump'},
 162         from_storage => 0,
 163     } ) };
 164         if( $@ ) {
 165         print STDERR "ERROR: Couldn't open SQL dump file: $@\n";
 166         exit 1 if $opt{'sqldump'};
 167
 168         print STDERR "WARNING: It's strongly recommended to use '--sqldump <filename>' option\n";
 169         unless( $opt{'force'} ) {
 170             exit 0 unless prompt_yN( "Do you want to proceed?" );
 171         }
 172         } else {
 173         print "SQL dump file is '". $plugin->FileName ."'\n";
 174     }
 175 }
 176
 177 my @objs = process_plugins( $shredder );
 178 prompt_delete_objs( \@objs ) unless $opt{'force'};
 179
 180 $shredder->PutObjects( Objects => $_ ) foreach @objs;
 181 eval { $shredder->WipeoutAll };
 182 if( $@ ) {
 183     require RT::Shredder::Exceptions;
 184     if( my $e = RT::Shredder::Exception::Info->caught ) {
 185         print "\nERROR: $e\n\n";
 186         exit 1;
 187     }
 188     die $@;
 189 }
 190
 191 sub prompt_delete_objs
 192 {
 193         my( $objs ) = @_;
 194         unless( @$objs ) {
 195                 print "Objects list is empty, try refine search options\n";
 196                 exit 0;
 197         }
 198         my $list = "Next ". scalar( @$objs ) ." objects would be deleted:\n";
 199         foreach my $o( @$objs ) {
 200                 $list .= "\t". $o->_AsString ." object\n";
 201         }
 202         print $list;
 203         exit(0) unless prompt_yN( "Do you want to proceed?" );
 204 }
 205
 206 sub prompt_yN
 207 {
 208         my $text = shift;
 209         print "$text [y/N] ";
 210         unless( <STDIN> =~ /^(?:y|yes)$/i ) {
 211                 return 0;
 212         }
 213         return 1;
 214 }
 215
 216 sub usage
 217 {
 218         require RT::Shredder::POD;
 219         RT::Shredder::POD::shredder_cli( $0, \*STDOUT );
 220         exit 1;
 221 }
 222
 223 sub parse_args
 224 {
 225         my $tmp;
 226         Getopt::Long::Configure( "pass_through" );
 227         my @objs = ();
 228         if( GetOptions( 'object=s' => \@objs ) && @objs ) {
 229                 print STDERR "Option --object had been deprecated, use plugin 'Objects' instead\n";
 230         exit(1);
 231         }
 232
 233         my @plugins = ();
 234         if( GetOptions( 'plugin=s' => \@plugins ) && @plugins ) {
 235                 $opt{'plugin'} = \@plugins;
 236                 foreach my $str( @plugins ) {
 237                         if( $str =~ /^\s*list\s*$/ ) {
 238                                 show_plugin_list();
 239                         } elsif( $str =~ /^\s*help-(\w+)\s*$/ ) {
 240                                 show_plugin_help( $1 );
 241                         } elsif( $str =~ /^(\w+)(=.*)?$/ && !$plugins{$1} ) {
 242                                 print "Couldn't find plugin '$1'\n";
 243                                 show_plugin_list();
 244                         }
 245                 }
 246         }
 247
 248         # other options make no sense without previouse
 249         usage() unless keys %opt;
 250
 251         if( GetOptions( 'force' => \$tmp ) && $tmp ) {
 252                 $opt{'force'}++;
 253         }
 254         $tmp = undef;
 255         if( GetOptions( 'sqldump=s' => \$tmp ) && $tmp ) {
 256                 $opt{'sqldump'} = $tmp;
 257         }
 258         return;
 259 }
 260
 261 sub process_plugins
 262 {
 263         my $shredder = shift;
 264
 265         my @res;
 266         foreach my $str( @{ $opt{'plugin'} } ) {
 267                 my $plugin = RT::Shredder::Plugin->new;
 268                 my( $status, $msg ) = $plugin->LoadByString( $str );
 269                 unless( $status ) {
 270                         print STDERR "Couldn't load plugin\n";
 271                         print STDERR "Error: $msg\n";
 272                         exit(1);
 273                 }
 274         if ( lc $plugin->Type eq 'search' ) {
 275             push @res, _process_search_plugin( $shredder, $plugin );
 276         }
 277         elsif ( lc $plugin->Type eq 'dump' ) {
 278             _process_dump_plugin( $shredder, $plugin );
 279         }
 280         }
 281         return RT::Shredder->CastObjectsToRecords( Objects => \@res );
 282 }
 283
 284 sub _process_search_plugin {
 285     my ($shredder, $plugin) = @_;
 286     my ($status, @objs) = $plugin->Run;
 287     unless( $status ) {
 288         print STDERR "Couldn't run plugin\n";
 289         print STDERR "Error: $objs[1]\n";
 290         exit(1);
 291     }
 292
 293     my $msg;
 294     ($status, $msg) = $plugin->SetResolvers( Shredder => $shredder );
 295     unless( $status ) {
 296         print STDERR "Couldn't set conflicts resolver\n";
 297         print STDERR "Error: $msg\n";
 298         exit(1);
 299     }
 300     return @objs;
 301 }
 302
 303 sub _process_dump_plugin {
 304     my ($shredder, $plugin) = @_;
 305     $shredder->AddDumpPlugin(
 306         Object => $plugin,
 307     );
 308 }
 309
 310 sub show_plugin_list
 311 {
 312         print "Plugins list:\n";
 313         print "\t$_\n" foreach( grep !/^Base$/, keys %plugins );
 314         exit(1);
 315 }
 316
 317 sub show_plugin_help
 318 {
 319         my( $name ) = @_;
 320         require RT::Shredder::POD;
 321         unless( $plugins{ $name } ) {
 322                 print "Couldn't find plugin '$name'\n";
 323                 show_plugin_list();
 324         }
 325         RT::Shredder::POD::plugin_cli( $plugins{'Base'}, \*STDOUT, 1 );
 326         RT::Shredder::POD::plugin_cli( $plugins{ $name }, \*STDOUT );
 327         exit(1);
 328 }
 329
 330 exit(0);