FMD/FMDbase/CMakeLists.txt

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # Module
  17 set(MODULE FMDbase)
  18
  19 # Module include folder
  20 include_directories(${AliRoot_SOURCE_DIR}/FMD/${MODULE})
  21
  22 # Additional include folders in alphabetical order except ROOT
  23 include_directories(${ROOT_INCLUDE_DIRS}
  24                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
  25                     ${AliRoot_SOURCE_DIR}/STEER/CDB
  26                     ${AliRoot_SOURCE_DIR}/STEER/ESD
  27                     ${AliRoot_SOURCE_DIR}/STEER/STEER
  28                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
  29                    )
  30
  31 # Sources in alphabetical order
  32 set(SRCS
  33     AliFMD1.cxx
  34     AliFMD2.cxx
  35     AliFMD3.cxx
  36     AliFMDAltroMapping.cxx
  37     AliFMDBaseDigit.cxx
  38     AliFMDBoolMap.cxx
  39     AliFMDCalibGain.cxx
  40     AliFMDCalibPedestal.cxx
  41     AliFMDCalibSampleRate.cxx
  42     AliFMDCalibStripRange.cxx
  43     AliFMDDetector.cxx
  44     AliFMDDigit.cxx
  45     AliFMDGeometryBuilder.cxx
  46     AliFMDGeometry.cxx
  47     AliFMDIndex.cxx
  48     AliFMDParameters.cxx
  49     AliFMDPreprocessor.cxx
  50     AliFMDRing.cxx
  51     AliFMDSDigit.cxx
  52     AliFMDSurveyToAlignObjs.cxx
  53     AliFMDUShortMap.cxx
  54    )
  55
  56 # Headers from sources
  57 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
  58 set(HDRS ${HDRS} AliFMDCalibFwd.h)
  59
  60 # Generate the dictionary
  61 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
  62 get_directory_property(incdirs INCLUDE_DIRECTORIES)
  63 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
  64
  65 # Dependencies
  66 set(ROOT_DEPENDENCIES)
  67 set(ALIROOT_DEPENDENCIES STEERBase STEER ESD CDB RAWDatabase)
  68
  69 # Generate the ROOT map
  70 # Dependecies
  71 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  72 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
  73
  74 # Create an object to be reused in case of static libraries
  75 # Otherwise the sources will be compiled twice
  76 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
  77 # Follow headers dependencies
  78 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
  79 # Add a library to the project using the object
  80 add_library(${MODULE} SHARED $<TARGET_OBJECTS:${MODULE}-object>)
  81
  82 # linking
  83 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  84
  85 # Setting the correct headers for the object as gathered from the dependencies
  86 target_include_directories(${MODULE}-object PUBLIC $<TARGET_PROPERTY:${MODULE},INCLUDE_DIRECTORIES>)
  87 set_target_properties(${MODULE}-object PROPERTIES COMPILE_DEFINITIONS $<TARGET_PROPERTY:${MODULE},COMPILE_DEFINITIONS>)
  88
  89 # Additional compilation flags
  90 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS " ")
  91
  92 # System dependent: Modify the way the library is build
  93 if(${CMAKE_SYSTEM} MATCHES Darwin)
  94     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
  95 endif(${CMAKE_SYSTEM} MATCHES Darwin)
  96
  97 # Installation
  98 install(TARGETS ${MODULE}
  99         ARCHIVE DESTINATION lib
 100         LIBRARY DESTINATION lib)
 101
 102 install(FILES ${HDRS} DESTINATION include)
 103
 104 # Static version if DA enabled
 105 if(ALIROOT_STATIC)
 106     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:${MODULE}-object>)
 107     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
 108
 109     # list of shared dependencies / the name of the variable containing the list of static ones
 110     generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")
 111     target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root)
 112
 113     # Public include folders that will be propagated to the dependecies
 114     target_include_directories(${MODULE}-static PUBLIC ${incdirs})
 115
 116     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
 117
 118     # Installation
 119     install(TARGETS ${MODULE}-static
 120             ARCHIVE DESTINATION lib
 121             LIBRARY DESTINATION lib)
 122 endif(ALIROOT_STATIC)