TPC/TPCrec/CMakeLists.txt

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # Module
  17 set(MODULE TPCrec)
  18
  19 # Module include folder
  20 include_directories(${AliRoot_SOURCE_DIR}/TPC/${MODULE})
  21
  22 # Additional include folders in alphabetical order except ROOT
  23 include_directories(${ROOT_INCLUDE_DIRS}
  24                     ${AliRoot_SOURCE_DIR}/ANALYSIS/ANALYSIS
  25                     ${AliRoot_SOURCE_DIR}/ANALYSIS/ANALYSISalice
  26                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
  27                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatarec
  28                     ${AliRoot_SOURCE_DIR}/STEER/CDB
  29                     ${AliRoot_SOURCE_DIR}/STEER/ESD
  30                     ${AliRoot_SOURCE_DIR}/STEER/STEER
  31                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
  32                     ${AliRoot_SOURCE_DIR}/TPC/TPCbase
  33                    )
  34
  35 # Sources in alphabetical order
  36 set(SRCS
  37     AliCosmicTracker.cxx
  38     AliPadMax.cxx
  39     AliTPCclusterer.cxx
  40     AliTPCclustererKr.cxx
  41     AliTPCclusterKr.cxx
  42     AliTPCCosmicTrackfit.cxx
  43     AliTPCCosmicUtils.cxx
  44     AliTPCpolyTrack.cxx
  45     AliTPCReconstructor.cxx
  46     AliTPCseed.cxx
  47     AliTPCtrack.cxx
  48     AliTPCtracker.cxx
  49     AliTPCtrackerSector.cxx
  50     AliTPCTracklet.cxx
  51     AliTPCvtpr.cxx
  52    )
  53
  54 # Headers from sources
  55 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
  56
  57 # Additional headers, with no corresponding sources
  58 list(APPEND HDRS "AliTPCreco.h")
  59
  60 # Generate the dictionary
  61 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
  62 get_directory_property(incdirs INCLUDE_DIRECTORIES)
  63 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
  64
  65 set(ROOT_DEPENDENCIES Core Gpad Graf Hist MathCore Matrix Minuit Physics RIO Tree)
  66 set(ALIROOT_DEPENDENCIES STEERBase STEER CDB ESD RAWDatabase RAWDatarec ANALYSIS ANALYSISalice TPCbase)
  67
  68 # Generate the ROOT map
  69 # Dependecies
  70 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  71 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
  72
  73 # Create an object to be reused in case of static libraries
  74 # Otherwise the sources will be compiled twice
  75 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
  76 # Follow headers dependencies
  77 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
  78 # Add a library to the project using the object
  79 add_library(${MODULE} SHARED $<TARGET_OBJECTS:TPCrec-object>)
  80
  81 # Linking
  82 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  83
  84 # Public include folders that will be propagated to the dependecies
  85 target_include_directories(${MODULE} PUBLIC ${incdirs})
  86
  87 # Additional compilation flags
  88 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS "")
  89
  90 # System dependent: Modify the way the library is build
  91 if(${CMAKE_SYSTEM} MATCHES Darwin)
  92     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
  93 endif(${CMAKE_SYSTEM} MATCHES Darwin)
  94
  95 # Installation
  96 install(TARGETS ${MODULE}
  97         ARCHIVE DESTINATION lib
  98         LIBRARY DESTINATION lib)
  99 install(FILES ${HDRS} DESTINATION include)