check_openmanage

   1 #!/usr/bin/perl
   2 #
   3 # Nagios plugin
   4 #
   5 # Monitor Dell server hardware status using Dell OpenManage Server
   6 # Administrator, either locally via NRPE, or remotely via SNMP.
   7 #
   8 # $Id$
   9 #
  10 # Copyright (C) 2010 Trond H. Amundsen
  11 #
  12 # This program is free software: you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation, either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # This program is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 # General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  24 #
  25
  26 require 5.006;  # Perl v5.6.0 or newer is required
  27 use strict;
  28 use warnings;
  29 use POSIX qw(isatty ceil);
  30 use Getopt::Long qw(:config no_ignore_case);
  31
  32 # Global (package) variables used throughout the code
  33 use vars qw( $NAME $VERSION $AUTHOR $CONTACT $E_OK $E_WARNING $E_CRITICAL
  34              $E_UNKNOWN $FW_LOCK $USAGE $HELP $LICENSE
  35              $snmp_session $snmp_error $omreport $globalstatus $global
  36              $linebreak $omopt_chassis $omopt_system $blade
  37              $exit_code $snmp $original_sigwarn
  38              %check %opt %perfdata %reverse_exitcode %status2nagios
  39              %snmp_status %snmp_probestatus %probestatus2nagios %sysinfo
  40              %blacklist %nagios_alert_count %count
  41              @perl_warnings @controllers @enclosures
  42              @report_storage @report_chassis @report_other
  43           );
  44
  45 #---------------------------------------------------------------------
  46 # Initialization and global variables
  47 #---------------------------------------------------------------------
  48
  49 # Small subroutine to collect any perl warnings during execution
  50 sub collect_perl_warning {
  51   push @perl_warnings, [@_];
  52 }
  53
  54 # Set the WARN signal to use our collect subroutine above
  55 $original_sigwarn = $SIG{__WARN__};
  56 $SIG{__WARN__} = \&collect_perl_warning;
  57
  58 # Version and similar info
  59 $NAME    = 'check_openmanage';
  60 $VERSION = '3.5.4-beta6';
  61 $AUTHOR  = 'Trond H. Amundsen';
  62 $CONTACT = 't.h.amundsen@usit.uio.no';
  63
  64 # Exit codes
  65 $E_OK       = 0;
  66 $E_WARNING  = 1;
  67 $E_CRITICAL = 2;
  68 $E_UNKNOWN  = 3;
  69
  70 # Firmware update lock file [FIXME: location on Windows?]
  71 $FW_LOCK = '/var/lock/.spsetup';  # default on Linux
  72
  73 # Usage text
  74 $USAGE = <<"END_USAGE";
  75 Usage: $NAME [OPTION]...
  76 END_USAGE
  77
  78 # Help text
  79 $HELP = <<'END_HELP';
  80
  81 GENERAL OPTIONS:
  82
  83    -p, --perfdata      Output performance data
  84    -t, --timeout       Plugin timeout in seconds
  85    -c, --critical      Customise temperature critical limits
  86    -w, --warning       Customise temperature warning limits
  87    -d, --debug         Debug output, reports everything
  88    -h, --help          Display this help text
  89    -V, --version       Display version info
  90
  91 SNMP OPTIONS:
  92
  93    -H, --hostname      Hostname or IP of the server (needed for SNMP)
  94    -C, --community     SNMP community string
  95    -P, --protocol      SNMP protocol version
  96    --port              SNMP port number
  97
  98 OUTPUT OPTIONS:
  99
 100    -i, --info          Prefix any alerts with the service tag
 101    -e, --extinfo       Append system info to alerts
 102    -s, --state         Prefix alerts with alert state
 103    --short-state       Prefix alerts with alert state (abbreviated)
 104    -o, --okinfo        Verbosity when check result is OK
 105    --htmlinfo          HTML output with clickable links
 106
 107 CHECK CONTROL AND BLACKLISTING:
 108
 109    -a, --all           Check everything, even log content
 110    -b, --blacklist     Blacklist missing and/or failed components
 111    --only              Only check a certain component or alert type
 112    --check             Fine-tune which components are checked
 113
 114 For more information and advanced options, see the manual page or URL:
 115   http://folk.uio.no/trondham/software/check_openmanage.html
 116 END_HELP
 117
 118 # Version and license text
 119 $LICENSE = <<"END_LICENSE";
 120 $NAME $VERSION
 121 Copyright (C) 2010 $AUTHOR
 122 License GPLv3+: GNU GPL version 3 or later <http://gnu.org/licenses/gpl.html>
 123 This is free software: you are free to change and redistribute it.
 124 There is NO WARRANTY, to the extent permitted by law.
 125
 126 Written by $AUTHOR <$CONTACT>
 127 END_LICENSE
 128
 129 # Options with default values
 130 %opt = ( 'blacklist'         => [],
 131          'check'             => [],
 132          'critical'          => [],
 133          'warning'           => [],
 134          'timeout'           => 30,  # default timeout is 30 seconds
 135          'debug'             => 0,
 136          'help'              => 0,
 137          'perfdata'          => undef,
 138          'info'              => 0,
 139          'extinfo'           => 0,
 140          'htmlinfo'          => undef,
 141          'postmsg'           => undef,
 142          'state'             => 0,
 143          'short-state'       => 0,
 144          'okinfo'            => 0,   # default "ok" output level
 145          'linebreak'         => undef,
 146          'version'           => 0,
 147          'all'               => 0,
 148          'only'              => undef,
 149          'omreport'          => undef,
 150          'port'              => 161, # default SNMP port
 151          'hostname'          => undef,
 152          'community'         => 'public',  # SMNP v1 or v2c
 153          'protocol'          => 2,
 154          'username'          => undef, # SMNP v3
 155          'authpassword'      => undef, # SMNP v3
 156          'authkey'           => undef, # SMNP v3
 157          'authprotocol'      => undef, # SMNP v3
 158          'privpassword'      => undef, # SMNP v3
 159          'privkey'           => undef, # SMNP v3
 160          'privprotocol'      => undef, # SMNP v3
 161        );
 162
 163 # Get options
 164 GetOptions('b|blacklist=s'      => \@{ $opt{blacklist} },
 165            'check=s'            => \@{ $opt{check} },
 166            'c|critical=s'       => \@{ $opt{critical} },
 167            'w|warning=s'        => \@{ $opt{warning} },
 168            't|timeout=i'        => \$opt{timeout},
 169            'd|debug'            => \$opt{debug},
 170            'h|help'             => \$opt{help},
 171            'V|version'          => \$opt{version},
 172            'p|perfdata:s'       => \$opt{perfdata},
 173            'i|info'             => \$opt{info},
 174            'e|extinfo'          => \$opt{extinfo},
 175            'htmlinfo:s'         => \$opt{htmlinfo},
 176            'postmsg=s'          => \$opt{postmsg},
 177            's|state'            => \$opt{state},
 178            'short-state'        => \$opt{shortstate},
 179            'o|ok-info=i'        => \$opt{okinfo},
 180            'l|linebreak=s'      => \$opt{linebreak},
 181            'a|all'              => \$opt{all},
 182            'only=s'             => \$opt{only},
 183            'omreport=s'         => \$opt{omreport},
 184            'port=i'             => \$opt{port},
 185            'H|hostname=s'       => \$opt{hostname},
 186            'C|community=s'      => \$opt{community},
 187            'P|protocol=i'       => \$opt{protocol},
 188            'U|username=s'       => \$opt{username},
 189            'authpassword=s'     => \$opt{authpassword},
 190            'authkey=s'          => \$opt{authkey},
 191            'authprotocol=s'     => \$opt{authprotocol},
 192            'privpassword=s'     => \$opt{privpassword},
 193            'privkey=s'          => \$opt{privkey},
 194            'privprotocol=s'     => \$opt{privprotocol},
 195           ) or do { print $USAGE; exit $E_UNKNOWN };
 196
 197 # If user requested help
 198 if ($opt{help}) {
 199     print $USAGE, $HELP;
 200     exit $E_OK;
 201 }
 202
 203 # If user requested version info
 204 if ($opt{version}) {
 205     print $LICENSE;
 206     exit $E_OK;
 207 }
 208
 209 # Setting timeout
 210 $SIG{ALRM} = sub {
 211     print "PLUGIN TIMEOUT: $NAME timed out after $opt{timeout} seconds\n";
 212     exit $E_UNKNOWN;
 213 };
 214 alarm $opt{timeout};
 215
 216 # If we're using SNMP
 217 $snmp = defined $opt{hostname} ? 1 : 0;
 218
 219 # SNMP session variables
 220 $snmp_session = undef;
 221 $snmp_error   = undef;
 222
 223 # The omreport command
 224 $omreport = undef;
 225
 226 # Check flags, override available with the --check option
 227 %check = ( 'storage'     => 1,   # check storage subsystem
 228            'memory'      => 1,   # check memory (dimms)
 229            'fans'        => 1,   # check fan status
 230            'power'       => 1,   # check power supplies
 231            'temp'        => 1,   # check temperature
 232            'cpu'         => 1,   # check processors
 233            'voltage'     => 1,   # check voltage
 234            'batteries'   => 1,   # check battery probes
 235            'amperage'    => 1,   # check power consumption
 236            'intrusion'   => 1,   # check intrusion detection
 237            'alertlog'    => 0,   # check the alert log
 238            'esmlog'      => 0,   # check the ESM log (hardware log)
 239            'esmhealth'   => 1,   # check the ESM log overall health
 240          );
 241
 242 # Default line break
 243 $linebreak = isatty(*STDOUT) ? "\n" : '<br/>';
 244
 245 # Line break from option
 246 if (defined $opt{linebreak}) {
 247     if ($opt{linebreak} eq 'REG') {
 248         $linebreak = "\n";
 249     }
 250     elsif ($opt{linebreak} eq 'HTML') {
 251         $linebreak = '<br/>';
 252     }
 253     else {
 254         $linebreak = $opt{linebreak};
 255     }
 256 }
 257
 258 # Exit with status=UNKNOWN if there is firmware upgrade in progress
 259 if (!$snmp && -f $FW_LOCK) {
 260     print "MONITORING DISABLED - Firmware update in progress ($FW_LOCK exists)\n";
 261     exit $E_UNKNOWN;
 262 }
 263
 264 # List of controllers and enclosures
 265 @controllers = ();  # controllers
 266 @enclosures  = ();  # enclosures
 267
 268 # Messages
 269 @report_storage = ();  # messages with associated nagios level (storage)
 270 @report_chassis = ();  # messages with associated nagios level (chassis)
 271 @report_other   = ();  # messages with associated nagios level (other)
 272
 273 # Counters for everything
 274 %count
 275   = (
 276      'pdisk'  => 0, # number of physical disks
 277      'vdisk'  => 0, # number of logical drives (virtual disks)
 278      'temp'   => 0, # number of temperature probes
 279      'volt'   => 0, # number of voltage probes
 280      'amp'    => 0, # number of amperage probes
 281      'intr'   => 0, # number of intrusion probes
 282      'dimm'   => 0, # number of memory modules
 283      'fan'    => 0, # number of fan probes
 284      'cpu'    => 0, # number of CPUs
 285      'bat'    => 0, # number of batteries
 286      'power'  => 0, # number of power supplies
 287      'esm'    => {
 288                   'Critical'     => 0, # critical entries in ESM log
 289                   'Non-Critical' => 0, # warning entries in ESM log
 290                   'Ok'           => 0, # ok entries in ESM log
 291                  },
 292      'alert'  => {
 293                   'Critical'     => 0, # critical entries in alert log
 294                   'Non-Critical' => 0, # warning entries in alert log
 295                   'Ok'           => 0, # ok entries in alert log
 296                  },
 297     );
 298
 299 # Performance data
 300 %perfdata = ();
 301
 302 # Global health status
 303 $global         = 1;      # default is to check global status
 304 $globalstatus   = $E_OK;  # default global health status is "OK"
 305
 306 # Nagios error levels reversed
 307 %reverse_exitcode
 308   = (
 309      $E_OK       => 'OK',
 310      $E_WARNING  => 'WARNING',
 311      $E_CRITICAL => 'CRITICAL',
 312      $E_UNKNOWN  => 'UNKNOWN',
 313     );
 314
 315 # OpenManage (omreport) and SNMP error levels
 316 %status2nagios
 317   = (
 318      'Unknown'         => $E_CRITICAL,
 319      'Critical'        => $E_CRITICAL,
 320      'Non-Critical'    => $E_WARNING,
 321      'Ok'              => $E_OK,
 322      'Non-Recoverable' => $E_CRITICAL,
 323      'Other'           => $E_CRITICAL,
 324     );
 325
 326 # Status via SNMP
 327 %snmp_status
 328   = (
 329      1 => 'Other',
 330      2 => 'Unknown',
 331      3 => 'Ok',
 332      4 => 'Non-Critical',
 333      5 => 'Critical',
 334      6 => 'Non-Recoverable',
 335     );
 336
 337 # Probe Status via SNMP
 338 %snmp_probestatus
 339   = (
 340      1  => 'Other',               # probe status is not one of the following:
 341      2  => 'Unknown',             # probe status is unknown (not known or monitored)
 342      3  => 'Ok',                  # probe is reporting a value within the thresholds
 343      4  => 'nonCriticalUpper',    # probe has crossed upper noncritical threshold
 344      5  => 'criticalUpper',       # probe has crossed upper critical threshold
 345      6  => 'nonRecoverableUpper', # probe has crossed upper non-recoverable threshold
 346      7  => 'nonCriticalLower',    # probe has crossed lower noncritical threshold
 347      8  => 'criticalLower',       # probe has crossed lower critical threshold
 348      9  => 'nonRecoverableLower', # probe has crossed lower non-recoverable threshold
 349      10 => 'failed',              # probe is not functional
 350     );
 351
 352 # Probe status translated to Nagios alarm levels
 353 %probestatus2nagios
 354   = (
 355      'Other'               => $E_CRITICAL,
 356      'Unknown'             => $E_CRITICAL,
 357      'Ok'                  => $E_OK,
 358      'nonCriticalUpper'    => $E_WARNING,
 359      'criticalUpper'       => $E_CRITICAL,
 360      'nonRecoverableUpper' => $E_CRITICAL,
 361      'nonCriticalLower'    => $E_WARNING,
 362      'criticalLower'       => $E_CRITICAL,
 363      'nonRecoverableLower' => $E_CRITICAL,
 364      'failed'              => $E_CRITICAL,
 365     );
 366
 367 # System information gathered
 368 %sysinfo
 369   = (
 370      'bios'     => 'N/A',  # BIOS version
 371      'biosdate' => 'N/A',  # BIOS release date
 372      'serial'   => 'N/A',  # serial number (service tag)
 373      'model'    => 'N/A',  # system model
 374      'osname'   => 'N/A',  # OS name
 375      'osver'    => 'N/A',  # OS version
 376      'om'       => 'N/A',  # OMSA version
 377      'bmc'      => 0,      # HAS baseboard management controller (BMC)
 378      'rac'      => 0,      # HAS remote access controller (RAC)
 379      'rac_name' => 'N/A',  # remote access controller (RAC)
 380      'bmc_fw'   => 'N/A',  # BMC firmware
 381      'rac_fw'   => 'N/A',  # RAC firmware
 382     );
 383
 384 # Adjust which checks to perform
 385 adjust_checks() if defined $opt{check};
 386
 387 # Blacklisted components
 388 %blacklist = defined $opt{blacklist} ? %{ get_blacklist() } : ();
 389
 390 # If blacklisting is in effect, don't check global health status
 391 if (scalar keys %blacklist > 0) {
 392     $global = 0;
 393 }
 394
 395 # Take into account new hardware and blades
 396 $omopt_chassis = 'chassis';  # default "chassis" option to omreport
 397 $omopt_system  = 'system';   # default "system" option to omreport
 398 $blade         = 0;          # if this is a blade system
 399
 400 # Some initializations and checking before we begin
 401 if ($snmp) {
 402     snmp_initialize();    # initialize SNMP
 403     snmp_check();         # check that SNMP works
 404     snmp_detect_blade();  # detect blade via SNMP
 405 }
 406 else {
 407     # Find the omreport binary
 408     find_omreport();
 409     # Check help output from omreport, see which options are available.
 410     # Also detecting blade via omreport.
 411     check_omreport_options();
 412 }
 413
 414
 415 #---------------------------------------------------------------------
 416 # Helper functions
 417 #---------------------------------------------------------------------
 418
 419 #
 420 # Store a message in one of the message arrays
 421 #
 422 sub report {
 423     my ($type, $msg, $exval, $id) = @_;
 424     defined $id or $id = q{};
 425
 426     my %type2array
 427       = (
 428          'storage' => \@report_storage,
 429          'chassis' => \@report_chassis,
 430          'other'   => \@report_other,
 431         );
 432
 433     return push @{ $type2array{$type} }, [ $msg, $exval, $id ];
 434 }
 435
 436
 437 #
 438 # Run command, put resulting output lines in an array and return a
 439 # pointer to that array
 440 #
 441 sub run_command {
 442     my $command = shift;
 443
 444     open my $CMD, '-|', $command
 445       or do { report('other', "Couldn't run command '$command': $!", $E_UNKNOWN)
 446                 and return [] };
 447     my @lines = <$CMD>;
 448     close $CMD
 449       or do { report('other', "Couldn't close filehandle for command '$command': $!", $E_UNKNOWN)
 450                 and return \@lines };
 451     return \@lines;
 452 }
 453
 454 #
 455 # Run command, put resulting output in a string variable and return it
 456 #
 457 sub slurp_command {
 458     my $command = shift;
 459
 460     open my $CMD, '-|', $command
 461       or do { report('other', "Couldn't run command '$command': $!", $E_UNKNOWN) and return };
 462     my $rawtext = do { local $/ = undef; <$CMD> }; # slurping
 463     close $CMD;
 464
 465     # NOTE: We don't check the return value of close() since omreport
 466     # does something weird sometimes.
 467
 468     return $rawtext;
 469 }
 470
 471 #
 472 # Initialize SNMP
 473 #
 474 sub snmp_initialize {
 475     # Legal SNMP v3 protocols
 476     my $snmp_v3_privprotocol = qr{\A des|aes|aes128|3des|3desde \z}xms;
 477     my $snmp_v3_authprotocol = qr{\A md5|sha \z}xms;
 478
 479     # Parameters to Net::SNMP->session()
 480     my %param
 481       = (
 482          '-port'     => $opt{port},
 483          '-hostname' => $opt{hostname},
 484          '-version'  => $opt{protocol},
 485         );
 486
 487     # Parameters for SNMP v3
 488     if ($opt{protocol} == 3) {
 489
 490         # Username is mandatory
 491         if (defined $opt{username}) {
 492             $param{'-username'} = $opt{username};
 493         }
 494         else {
 495             print "SNMP ERROR: With SNMPv3 the username must be specified\n";
 496             exit $E_UNKNOWN;
 497         }
 498
 499         # Authpassword is optional
 500         if (defined $opt{authpassword}) {
 501             $param{'-authpassword'} = $opt{authpassword};
 502         }
 503
 504         # Authkey is optional
 505         if (defined $opt{authkey}) {
 506             $param{'-authkey'} = $opt{authkey};
 507         }
 508
 509         # Privpassword is optional
 510         if (defined $opt{privpassword}) {
 511             $param{'-privpassword'} = $opt{privpassword};
 512         }
 513
 514         # Privkey is optional
 515         if (defined $opt{privkey}) {
 516             $param{'-privkey'} = $opt{privkey};
 517         }
 518
 519         # Privprotocol is optional
 520         if (defined $opt{privprotocol}) {
 521             if ($opt{privprotocol} =~ m/$snmp_v3_privprotocol/xms) {
 522                 $param{'-privprotocol'} = $opt{privprotocol};
 523             }
 524             else {
 525                 print "SNMP ERROR: Unknown privprotocol '$opt{privprotocol}', "
 526                   . "must be one of [des|aes|aes128|3des|3desde]\n";
 527                 exit $E_UNKNOWN;
 528             }
 529         }
 530
 531         # Authprotocol is optional
 532         if (defined $opt{authprotocol}) {
 533             if ($opt{authprotocol} =~ m/$snmp_v3_authprotocol/xms) {
 534                 $param{'-authprotocol'} = $opt{authprotocol};
 535             }
 536             else {
 537                 print "SNMP ERROR: Unknown authprotocol '$opt{authprotocol}', "
 538                   . "must be one of [md5|sha]\n";
 539                 exit $E_UNKNOWN;
 540             }
 541         }
 542     }
 543     # Parameters for SNMP v2c or v1
 544     elsif ($opt{protocol} == 2 or $opt{protocol} == 1) {
 545         $param{'-community'} = $opt{community};
 546     }
 547     else {
 548         print "SNMP ERROR: Unknown SNMP version '$opt{protocol}'\n";
 549         exit $E_UNKNOWN;
 550     }
 551
 552     # Try to initialize the SNMP session
 553     if ( eval { require Net::SNMP; 1 } ) {
 554         ($snmp_session, $snmp_error) = Net::SNMP->session( %param );
 555         if (!defined $snmp_session) {
 556             printf "SNMP: %s\n", $snmp_error;
 557             exit $E_UNKNOWN;
 558         }
 559     }
 560     else {
 561         print "You need perl module Net::SNMP to run $NAME in SNMP mode\n";
 562         exit $E_UNKNOWN;
 563     }
 564     return;
 565 }
 566
 567 #
 568 # Checking if SNMP works by probing for "chassisModelName", which all
 569 # servers should have
 570 #
 571 sub snmp_check {
 572     my $chassisModelName = '1.3.6.1.4.1.674.10892.1.300.10.1.9.1';
 573     my $result = $snmp_session->get_request(-varbindlist => [$chassisModelName]);
 574
 575     # Typically if remote host isn't responding
 576     if (!defined $result) {
 577         printf "SNMP CRITICAL: %s\n", $snmp_session->error;
 578         exit $E_CRITICAL;
 579     }
 580
 581     # If OpenManage isn't installed or is not working
 582     if ($result->{$chassisModelName} =~ m{\A noSuch (Instance|Object) \z}xms) {
 583         print "ERROR: (SNMP) OpenManage is not installed or is not working correctly\n";
 584         exit $E_UNKNOWN;
 585     }
 586     return;
 587 }
 588
 589 #
 590 # Detecting blade via SNMP
 591 #
 592 sub snmp_detect_blade {
 593     my $DellBaseBoardType = '1.3.6.1.4.1.674.10892.1.300.80.1.7.1.1';
 594     my $result = $snmp_session->get_request(-varbindlist => [$DellBaseBoardType]);
 595
 596     # Identify blade. Older models (4th and 5th gen models) and/or old
 597     # OMSA (4.x) don't have this OID. If we get "noSuchInstance" or
 598     # similar, we assume that this isn't a blade
 599     if ($result->{$DellBaseBoardType} eq '3') {
 600         $blade = 1;
 601     }
 602     return;
 603 }
 604
 605 #
 606 # Locate the omreport binary
 607 #
 608 sub find_omreport {
 609     # If user has specified path to omreport
 610     if (defined $opt{omreport} and -x $opt{omreport}) {
 611         $omreport = qq{"$opt{omreport}"};
 612         return;
 613     }
 614
 615     # Possible full paths for omreport
 616     my @omreport_paths
 617       = (
 618          '/usr/bin/omreport',                            # default on Linux
 619          '/opt/dell/srvadmin/bin/omreport',              # default on Linux with OMSA 6.2.0
 620          '/opt/dell/srvadmin/oma/bin/omreport.sh',       # alternate on Linux
 621          '/opt/dell/srvadmin/oma/bin/omreport',          # alternate on Linux
 622          'C:\Program Files (x86)\Dell\SysMgt\oma\bin\omreport.exe', # default on Windows x64
 623          'C:\Program Files\Dell\SysMgt\oma\bin\omreport.exe',       # default on Windows x32
 624          'c:\progra~1\dell\sysmgt\oma\bin\omreport.exe', # 8bit legacy default on Windows x32
 625          'c:\progra~2\dell\sysmgt\oma\bin\omreport.exe', # 8bit legacy default on Windows x64
 626         );
 627
 628     # Find the one to use
 629   OMREPORT_PATH:
 630     foreach my $bin (@omreport_paths) {
 631         if (-x $bin) {
 632             $omreport = qq{"$bin"};
 633             last OMREPORT_PATH;
 634         }
 635     }
 636
 637     # Exit with status=UNKNOWN if OM is not installed, or we don't
 638     # have permission to execute the binary
 639     if (!defined $omreport) {
 640         print "ERROR: Dell OpenManage Server Administrator (OMSA) is not installed\n";
 641         exit $E_UNKNOWN;
 642     }
 643     return;
 644 }
 645
 646 #
 647 # Checks output from 'omreport -?' and searches for arguments to
 648 # omreport, to accommodate deprecated options "chassis" and "system"
 649 # (on newer hardware), as well as blade servers.
 650 #
 651 sub check_omreport_options {
 652     foreach (@{ run_command("$omreport -? 2>&1") }) {
 653        if (m/\A servermodule /xms) {
 654            # If "servermodule" argument to omreport exists, use it
 655            # instead of argument "system"
 656            $omopt_system = 'servermodule';
 657        }
 658        elsif (m/\A mainsystem /xms) {
 659            # If "mainsystem" argument to omreport exists, use it
 660            # instead of argument "chassis"
 661            $omopt_chassis = 'mainsystem';
 662        }
 663        elsif (m/\A modularenclosure /xms) {
 664            # If "modularenclusure" argument to omreport exists, assume
 665            # that this is a blade
 666            $blade = 1;
 667        }
 668     }
 669     return;
 670 }
 671
 672 #
 673 # Read the blacklist option and return a hash containing the
 674 # blacklisted components
 675 #
 676 sub get_blacklist {
 677     my @bl = ();
 678     my %blacklist = ();
 679
 680     if (scalar @{ $opt{blacklist} } >= 0) {
 681         foreach my $black (@{ $opt{blacklist} }) {
 682             my $tmp = q{};
 683             if (-f $black) {
 684                 open my $BL, '<', $black
 685                   or do { report('other', "Couldn't open blacklist file $black: $!", $E_UNKNOWN)
 686                             and return {} };
 687                 $tmp = <$BL>;
 688                 close $BL;
 689                 chomp $tmp;
 690             }
 691             else {
 692                 $tmp = $black;
 693             }
 694             push @bl, $tmp;
 695         }
 696     }
 697
 698     return {} if $#bl < 0;
 699
 700     # Parse blacklist string, put in hash
 701     foreach my $black (@bl) {
 702         my @comps = split m{/}xms, $black;
 703         foreach my $c (@comps) {
 704             next if $c !~ m/=/xms;
 705             my ($key, $val) = split /=/xms, $c;
 706             my @vals = split /,/xms, $val;
 707             $blacklist{$key} = \@vals;
 708         }
 709     }
 710
 711     return \%blacklist;
 712 }
 713
 714 #
 715 # Read the check option and adjust the hash %check, which is a rough
 716 # list of components to be checked
 717 #
 718 sub adjust_checks {
 719     my @cl = ();
 720
 721     # Adjust checking based on the '--all' option
 722     if ($opt{all}) {
 723         # Check option usage
 724         if (defined $opt{only} and $opt{only} !~ m{\A critical|warning \z}xms) {
 725             print qq{ERROR: Wrong simultaneous usage of the "--all" and "--only" options\n};
 726             exit $E_UNKNOWN;
 727         }
 728         if (scalar @{ $opt{check} } > 0) {
 729             print qq{ERROR: Wrong simultaneous usage of the "--all" and "--check" options\n};
 730             exit $E_UNKNOWN;
 731         }
 732
 733         # set the check hash to check everything
 734         map { $_ = 1 } values %check;
 735
 736         return;
 737     }
 738
 739     # Adjust checking based on the '--only' option
 740     if (defined $opt{only} and $opt{only} !~ m{\A critical|warning \z}xms) {
 741         # Check option usage
 742         if (scalar @{ $opt{check} } > 0) {
 743             print qq{ERROR: Wrong simultaneous usage of the "--only" and "--check" options\n};
 744             exit $E_UNKNOWN;
 745         }
 746         if (! exists $check{$opt{only}} && $opt{only} ne 'chassis') {
 747             print qq{ERROR: "$opt{only}" is not a known keyword for the "--only" option\n};
 748             exit $E_UNKNOWN;
 749         }
 750
 751         # reset the check hash
 752         map { $_ = 0 } values %check;
 753
 754         # adjust the check hash
 755         if ($opt{only} eq 'chassis') {
 756             map { $check{$_} = 1 } qw(memory fans power temp cpu voltage
 757                                       batteries amperage intrusion esmhealth);
 758         }
 759         else {
 760             $check{$opt{only}} = 1;
 761         }
 762
 763         return;
 764     }
 765
 766     # Adjust checking based on the '--check' option
 767     if (scalar @{ $opt{check} } >= 0) {
 768         foreach my $check (@{ $opt{check} }) {
 769             my $tmp = q{};
 770             if (-f $check) {
 771                 open my $CL, '<', $check
 772                   or do { report('other', "Couldn't open check file $check: $!", $E_UNKNOWN) and return };
 773                 $tmp = <$CL>;
 774                 close $CL;
 775             }
 776             else {
 777                 $tmp = $check;
 778             }
 779             push @cl, $tmp;
 780         }
 781     }
 782
 783     return if $#cl < 0;
 784
 785     # Parse checklist string, put in hash
 786     foreach my $check (@cl) {
 787         my @checks = split /,/xms, $check;
 788         foreach my $c (@checks) {
 789             next if $c !~ m/=/xms;
 790             my ($key, $val) = split /=/xms, $c;
 791             $check{$key} = $val;
 792         }
 793     }
 794
 795     # Check if we should check global health status
 796   CHECK_KEY:
 797     foreach (keys %check) {
 798         next CHECK_KEY if $_ eq 'esmlog';   # not part of global status
 799         next CHECK_KEY if $_ eq 'alertlog'; # not part of global status
 800
 801         if ($check{$_} == 0) { # found something with checking turned off
 802             $global = 0;
 803             last CHECK_KEY;
 804         }
 805     }
 806
 807     return;
 808 }
 809
 810 #
 811 # Runs omreport and returns an array of anonymous hashes containing
 812 # the output.
 813 # Takes one argument: string containing parameters to omreport
 814 #
 815 sub run_omreport {
 816     my $command = shift;
 817     my @output  = ();
 818     my @keys    = ();
 819
 820     # Errors that are OK. Some low-end poweredge (and blades) models
 821     # don't have RAID controllers, intrusion detection sensor, or
 822     # redundant/instrumented power supplies etc.
 823     my $ok_errors
 824       = qr{
 825             Intrusion\sinformation\sis\snot\sfound\sfor\sthis\ssystem  # No intrusion probe
 826           | No\sinstrumented\spower\ssupplies\sfound\son\sthis\ssystem # No instrumented PS (blades/low-end)
 827           | No\scontrollers\sfound                                     # No RAID controller
 828           | No\sbattery\sprobes\sfound\son\sthis\ssystem               # No battery probes
 829           | Invalid\scommand:\spwrmonitoring                           # Older OMSAs lack this command(?)
 830 #          | Current\sprobes\snot\sfound                                # No power monitoring capability
 831         }xms;
 832
 833     # Errors that are OK on blade servers
 834     my $ok_blade_errors
 835       = qr{
 836               No\sfan\sprobes\sfound\son\sthis\ssystem   # No fan probes
 837       }xms;
 838
 839     # Run omreport and fetch output
 840     my $rawtext = slurp_command("$omreport $command -fmt ssv 2>&1");
 841     return [] if !defined $rawtext;
 842
 843     # Workaround for Openmanage BUG introduced in OMSA 5.5.0
 844     $rawtext =~ s{\n;}{;}gxms if $command eq 'storage controller';
 845
 846     # Openmanage sometimes puts a linebreak between "Error" and the
 847     # actual error text
 848     $rawtext =~ s{^Error\s*\n}{Error: }xms;
 849
 850     # Parse output, store in array
 851     for ((split m{\n}xms, $rawtext)) {
 852         if (m{\AError}xms) {
 853             next if m{$ok_errors}xms;
 854             next if ($blade and m{$ok_blade_errors}xms);
 855             report('other', "Problem running 'omreport $command': $_", $E_UNKNOWN);
 856         }
 857
 858         next if !m/(.*?;){2}/xms;  # ignore lines with less than 3 fields
 859         my @vals = split /;/xms;
 860         if ($vals[0] =~ m/\A (Index|ID|Severity|Processor|Current\sSpeed) \z/xms) {
 861             @keys = @vals;
 862         }
 863         else {
 864             my $i = 0;
 865             push @output, { map { $_ => $vals[$i++] } @keys };
 866         }
 867
 868     }
 869
 870     # Finally, return the collected information
 871     return \@output;
 872 }
 873
 874
 875 #
 876 # Checks if a component is blacklisted. Returns 1 if the component is
 877 # blacklisted, 0 otherwise. Takes two arguments:
 878 #   arg1: component name
 879 #   arg2: component id or index
 880 #
 881 sub blacklisted {
 882     my $name = shift;  # component name
 883     my $id   = shift;  # component id
 884     my $ret  = 0;      # return value
 885
 886     if (defined $blacklist{$name}) {
 887         foreach my $comp (@{ $blacklist{$name} }) {
 888             if (defined $id and ($comp eq $id or uc($comp) eq 'ALL')) {
 889                 $ret = 1;
 890             }
 891         }
 892     }
 893
 894     return $ret;
 895 }
 896
 897 # Converts the NexusID from SNMP to our version
 898 sub convert_nexus {
 899     my $nexus = shift;
 900     $nexus =~ s{\A \\}{}xms;
 901     $nexus =~ s{\\}{:}gxms;
 902     return $nexus;
 903 }
 904
 905 # Sets custom temperature thresholds based on user supplied options
 906 sub custom_temperature_thresholds {
 907     my $type   = shift; # type of threshold, either w (warning) or c (critical)
 908     my %thres  = ();    # will contain the thresholds
 909     my @limits = ();    # holds the input
 910
 911     my @opt =  $type eq 'w' ? @{ $opt{warning} } : @{ $opt{critical} };
 912
 913     if (scalar @opt >= 0) {
 914         foreach my $t (@opt) {
 915             my $tmp = q{};
 916             if (-f $t) {
 917                 open my $F, '<', $t
 918                   or do { report('other', "Couldn't open temperature threshold file $t: $!",
 919                                  $E_UNKNOWN) and return {} };
 920                 $tmp = <$F>;
 921                 close $F;
 922             }
 923             else {
 924                 $tmp = $t;
 925             }
 926             push @limits, $tmp;
 927         }
 928     }
 929
 930     # Parse checklist string, put in hash
 931     foreach my $th (@limits) {
 932         my @tmp = split m{,}xms, $th;
 933         foreach my $t (@tmp) {
 934             next if $t !~ m{=}xms;
 935             my ($key, $val) = split m{=}xms, $t;
 936             if ($val =~ m{/}xms) {
 937                 my ($max, $min) = split m{/}xms, $val;
 938                 $thres{$key}{max} = $max;
 939                 $thres{$key}{min} = $min;
 940             }
 941             else {
 942                 $thres{$key}{max} = $val;
 943             }
 944         }
 945     }
 946
 947     return \%thres;
 948 }
 949
 950
 951 # Gets the output from SNMP result according to the OIDs checked
 952 sub get_snmp_output {
 953     my ($result,$oidref) = @_;
 954     my @output = ();
 955
 956     foreach my $oid (keys %{ $result }) {
 957         my @dummy = split /\./xms, $oid;
 958         my $id = pop @dummy;
 959         --$id;
 960         my $foo = join q{.}, @dummy;
 961         if (exists $oidref->{$foo}) {
 962             $output[$id]{$oidref->{$foo}} = $result->{$oid};
 963         }
 964     }
 965     return \@output;
 966 }
 967
 968
 969 # Map the controller or other item in-place
 970 sub map_item {
 971     my ($key, $val, $list)  = @_;
 972
 973     foreach my $lst (@{ $list }) {
 974         if (!exists $lst->{$key}) {
 975             $lst->{$key} = $val;
 976         }
 977     }
 978     return;
 979 }
 980
 981 # Return the URL for official Dell documentation for a specific
 982 # PowerEdge server
 983 sub documentation_url {
 984     my $model = shift;
 985
 986     # create model short form, e.g. "r710"
 987     $model =~ s{\A PowerEdge \s (.+?) \z}{lc($1)}exms;
 988
 989     # special case for blades (e.g. M600, M710), they have common
 990     # documentation
 991     $model =~ s{\A m\d+ \z}{m}xms;
 992
 993     return 'http://support.dell.com/support/edocs/systems/pe' . $model . '/';
 994 }
 995
 996 # Return the URL for warranty information for a server with a given
 997 # serial number (servicetag)
 998 sub warranty_url {
 999     my $tag = shift;
1000
1001     # Dell support sites for different parts of the world
1002     my %supportsite
1003       = (
1004          'emea' => 'http://support.euro.dell.com/support/topics/topic.aspx/emea/shared/support/my_systems_info/',
1005          'ap'   => 'http://supportapj.dell.com/support/topics/topic.aspx/ap/shared/support/my_systems_info/en/details?',
1006          'glob' => 'http://support.dell.com/support/topics/global.aspx/support/my_systems_info/details?',
1007         );
1008
1009     # warranty URLs for different country codes
1010     my %url
1011       = (
1012          # EMEA
1013          'at' => $supportsite{emea} . 'de/details?c=at&l=de&ServiceTag=',  # Austria
1014          'be' => $supportsite{emea} . 'nl/details?c=be&l=nl&ServiceTag=',  # Belgium
1015          'cz' => $supportsite{emea} . 'cs/details?c=cz&l=cs&ServiceTag=',  # Czech Republic
1016          'de' => $supportsite{emea} . 'de/details?c=de&l=de&ServiceTag=',  # Germany
1017          'dk' => $supportsite{emea} . 'da/details?c=dk&l=da&ServiceTag=',  # Denmark
1018          'es' => $supportsite{emea} . 'es/details?c=es&l=es&ServiceTag=',  # Spain
1019          'fi' => $supportsite{emea} . 'fi/details?c=fi&l=fi&ServiceTag=',  # Finland
1020          'fr' => $supportsite{emea} . 'fr/details?c=fr&l=fr&ServiceTag=',  # France
1021          'gr' => $supportsite{emea} . 'en/details?c=gr&l=el&ServiceTag=',  # Greece
1022          'it' => $supportsite{emea} . 'it/details?c=it&l=it&ServiceTag=',  # Italy
1023          'il' => $supportsite{emea} . 'en/details?c=il&l=en&ServiceTag=',  # Israel
1024          'me' => $supportsite{emea} . 'en/details?c=me&l=en&ServiceTag=',  # Middle East
1025          'no' => $supportsite{emea} . 'no/details?c=no&l=no&ServiceTag=',  # Norway
1026          'nl' => $supportsite{emea} . 'nl/details?c=nl&l=nl&ServiceTag=',  # The Netherlands
1027          'pl' => $supportsite{emea} . 'pl/details?c=pl&l=pl&ServiceTag=',  # Poland
1028          'pt' => $supportsite{emea} . 'en/details?c=pt&l=pt&ServiceTag=',  # Portugal
1029          'ru' => $supportsite{emea} . 'ru/details?c=ru&l=ru&ServiceTag=',  # Russia
1030          'se' => $supportsite{emea} . 'sv/details?c=se&l=sv&ServiceTag=',  # Sweden
1031          'uk' => $supportsite{emea} . 'en/details?c=uk&l=en&ServiceTag=',  # United Kingdom
1032          'za' => $supportsite{emea} . 'en/details?c=za&l=en&ServiceTag=',  # South Africa
1033          # America
1034          'br' => $supportsite{glob} . 'c=br&l=pt&ServiceTag=',  # Brazil
1035          'ca' => $supportsite{glob} . 'c=ca&l=en&ServiceTag=',  # Canada
1036          'mx' => $supportsite{glob} . 'c=mx&l=es&ServiceTag=',  # Mexico
1037          'us' => $supportsite{glob} . 'c=us&l=en&ServiceTag=',  # USA
1038          # Asia/Pacific
1039          'au' => $supportsite{ap} . 'c=au&l=en&ServiceTag=',  # Australia
1040          'cn' => $supportsite{ap} . 'c=cn&l=zh&ServiceTag=',  # China
1041          'in' => $supportsite{ap} . 'c=in&l=en&ServiceTag=',  # India
1042          # default fallback
1043          'XX' => $supportsite{glob} . 'ServiceTag=',  # default
1044         );
1045
1046     if (exists $url{$opt{htmlinfo}}) {
1047         return $url{$opt{htmlinfo}} . $tag;
1048     }
1049     else {
1050         return $url{XX} . $tag;
1051     }
1052 }
1053
1054
1055
1056 #---------------------------------------------------------------------
1057 # Check functions
1058 #---------------------------------------------------------------------
1059
1060 #-----------------------------------------
1061 # Check global health status
1062 #-----------------------------------------
1063 sub check_global {
1064     my $health = $E_OK;
1065
1066     if ($snmp) {
1067         #
1068         # Checks global status, i.e. both storage and chassis
1069         #
1070         my $systemStateGlobalSystemStatus = '1.3.6.1.4.1.674.10892.1.200.10.1.2.1';
1071         my $result = $snmp_session->get_request(-varbindlist => [$systemStateGlobalSystemStatus]);
1072         if (!defined $result) {
1073             printf "SNMP ERROR [global]: %s\n", $snmp_error;
1074             exit $E_UNKNOWN;
1075         }
1076         $health = $status2nagios{$snmp_status{$result->{$systemStateGlobalSystemStatus}}};
1077     }
1078     else {
1079         #
1080         # NB! This does not check storage, only chassis...
1081         #
1082         foreach (@{ run_command("$omreport $omopt_system -fmt ssv") }) {
1083             next if !m/;/xms;
1084             next if m/\A SEVERITY;COMPONENT/xms;
1085             if (m/\A (.+?);Main\sSystem(\sChassis)? /xms) {
1086                 $health = $status2nagios{$1};
1087                 last;
1088             }
1089         }
1090     }
1091
1092     # Return the status
1093     return $health;
1094 }
1095
1096
1097 #-----------------------------------------
1098 # STORAGE: Check controllers
1099 #-----------------------------------------
1100 sub check_controllers {
1101     my $id       = undef;
1102     my $nexus    = undef;
1103     my $name     = undef;
1104     my $state    = undef;
1105     my $status   = undef;
1106     my $minfw    = undef;
1107     my $mindr    = undef;
1108     my $firmware = undef;
1109     my $driver   = undef;
1110     my $minstdr  = undef;  # Minimum required Storport driver version (whats this?)
1111     my $stdr     = undef;  # Storport driver version (whats this?)
1112     my @output   = ();
1113
1114     if ($snmp) {
1115         my %ctrl_oid
1116           = (
1117              '1.3.6.1.4.1.674.10893.1.20.130.1.1.1'  => 'controllerNumber',
1118              '1.3.6.1.4.1.674.10893.1.20.130.1.1.2'  => 'controllerName',
1119              '1.3.6.1.4.1.674.10893.1.20.130.1.1.5'  => 'controllerState',
1120              '1.3.6.1.4.1.674.10893.1.20.130.1.1.8'  => 'controllerFWVersion',
1121              '1.3.6.1.4.1.674.10893.1.20.130.1.1.38' => 'controllerComponentStatus',
1122              '1.3.6.1.4.1.674.10893.1.20.130.1.1.39' => 'controllerNexusID',
1123              '1.3.6.1.4.1.674.10893.1.20.130.1.1.41' => 'controllerDriverVersion',
1124              '1.3.6.1.4.1.674.10893.1.20.130.1.1.44' => 'controllerMinFWVersion',
1125              '1.3.6.1.4.1.674.10893.1.20.130.1.1.45' => 'controllerMinDriverVersion',
1126              '1.3.6.1.4.1.674.10893.1.20.130.1.1.55' => 'FIXME_StorportDriverVersion',
1127              '1.3.6.1.4.1.674.10893.1.20.130.1.1.56' => 'FIXME_StorportMinDriverVersion',
1128             );
1129
1130         # We use get_table() here for the odd case where a server has
1131         # two or more controllers, and where some OIDs are missing on
1132         # one of the controllers.
1133         my $controllerTable = '1.3.6.1.4.1.674.10893.1.20.130.1';
1134         my $result = $snmp_session->get_table(-baseoid => $controllerTable);
1135
1136         # No controllers is OK
1137         return if !defined $result;
1138
1139         @output = @{ get_snmp_output($result, \%ctrl_oid) };
1140     }
1141     else {
1142         @output = @{ run_omreport('storage controller') };
1143     }
1144
1145     my %ctrl_state
1146       = (
1147          0 => 'Unknown',
1148          1 => 'Ready',
1149          2 => 'Failed',
1150          3 => 'Online',
1151          4 => 'Offline',
1152          6 => 'Degraded',
1153         );
1154
1155   CTRL:
1156     foreach my $out (@output) {
1157         if ($snmp) {
1158             $id       = $out->{controllerNumber} - 1;
1159             $name     = $out->{controllerName};
1160             $state    = $ctrl_state{$out->{controllerState}};
1161             $status   = $snmp_status{$out->{controllerComponentStatus}};
1162             $minfw    = exists $out->{controllerMinFWVersion}
1163               ? $out->{controllerMinFWVersion} : undef;
1164             $mindr    = exists $out->{controllerMinDriverVersion}
1165               ? $out->{controllerMinDriverVersion} : undef;
1166             $firmware = exists $out->{controllerFWVersion}
1167               ? $out->{controllerFWVersion} : 'N/A';
1168             $driver   = exists $out->{controllerDriverVersion}
1169               ? $out->{controllerDriverVersion} : 'N/A';
1170             $minstdr  = exists $out->{'FIXME_StorportMinDriverVersion'}
1171               ? $out->{FIXME_StorportMinDriverVersion} : undef;
1172             $stdr     = exists $out->{FIXME_StorportDriverVersion}
1173               ? $out->{FIXME_StorportDriverVersion} : 'N/A';
1174             $nexus    = convert_nexus($out->{controllerNexusID});
1175         }
1176         else {
1177             $id       = $out->{ID};
1178             $name     = $out->{Name};
1179             $state    = $out->{State};
1180             $status   = $out->{Status};
1181             $minfw    = $out->{'Minimum Required Firmware Version'} ne 'Not Applicable'
1182               ? $out->{'Minimum Required Firmware Version'} : undef;
1183             $mindr    = $out->{'Minimum Required Driver Version'} ne 'Not Applicable'
1184               ? $out->{'Minimum Required Driver Version'} : undef;
1185             $firmware = $out->{'Firmware Version'} ne 'Not Applicable'
1186               ? $out->{'Firmware Version'} : 'N/A';
1187             $driver   = $out->{'Driver Version'} ne 'Not Applicable'
1188               ? $out->{'Driver Version'} : 'N/A';
1189             $minstdr  = (exists $out->{'Minimum Required Storport Driver Version'}
1190                          and $out->{'Minimum Required Storport Driver Version'} ne 'Not Applicable')
1191               ? $out->{'Minimum Required Storport Driver Version'} : undef;
1192             $stdr     = (exists $out->{'Storport Driver Version'}
1193                          and $out->{'Storport Driver Version'} ne 'Not Applicable')
1194               ? $out->{'Storport Driver Version'} : 'N/A';
1195             $nexus    = $id;
1196         }
1197
1198         $name =~ s{\s+\z}{}xms; # remove trailing whitespace
1199         push @controllers, $id;
1200
1201         # Collecting some storage info
1202         $sysinfo{'controller'}{$id}{'id'}       = $nexus;
1203         $sysinfo{'controller'}{$id}{'name'}     = $name;
1204         $sysinfo{'controller'}{$id}{'driver'}   = $driver;
1205         $sysinfo{'controller'}{$id}{'firmware'} = $firmware;
1206
1207         next CTRL if blacklisted('ctrl', $nexus);
1208
1209         # Special case: old firmware
1210         if (!blacklisted('ctrl_fw', $id) && defined $minfw) {
1211             chomp $firmware;
1212             my $msg = sprintf q{Controller %d [%s]: Firmware '%s' is out of date},
1213               $id, $name, $firmware;
1214             report('storage', $msg, $E_WARNING, $nexus);
1215         }
1216         # Special case: old driver
1217         if (!blacklisted('ctrl_driver', $id) && defined $mindr) {
1218             chomp $driver;
1219             my $msg = sprintf q{Controller %d [%s]: Driver '%s' is out of date},
1220               $id, $name, $driver;
1221             report('storage', $msg, $E_WARNING, $nexus);
1222         }
1223         # Special case: old storport driver
1224         if (!blacklisted('ctrl_stdr', $id) && defined $minstdr) {
1225             chomp $stdr;
1226             my $msg = sprintf q{Controller %d [%s]: Storport driver '%s' is out of date},
1227               $id, $name, $stdr;
1228             report('storage', $msg, $E_WARNING, $nexus);
1229         }
1230         # Ok
1231         if ($status eq 'Ok' or ($status eq 'Non-Critical'
1232                                 and (defined $minfw or defined $mindr or defined $minstdr))) {
1233             my $msg = sprintf 'Controller %d [%s] is %s',
1234               $id, $name, $state;
1235             report('storage', $msg, $E_OK, $nexus);
1236         }
1237         # Default
1238         else {
1239             my $msg = sprintf 'Controller %d [%s] needs attention: %s',
1240               $id, $name, $state;
1241             report('storage', $msg, $status2nagios{$status}, $nexus);
1242         }
1243     }
1244     return;
1245 }
1246
1247
1248 #-----------------------------------------
1249 # STORAGE: Check physical drives
1250 #-----------------------------------------
1251 sub check_physical_disks {
1252     return if $#controllers == -1;
1253
1254     my $id       = undef;
1255     my $nexus    = undef;
1256     my $name     = undef;
1257     my $state    = undef;
1258     my $status   = undef;
1259     my $fpred    = undef;
1260     my $progr    = undef;
1261     my $ctrl     = undef;
1262     my $vendor   = undef;  # disk vendor
1263     my $product  = undef;  # product ID
1264     my $capacity = undef;  # disk length (size) in bytes
1265     my @output  = ();
1266
1267     if ($snmp) {
1268         my %pdisk_oid
1269           = (
1270              '1.3.6.1.4.1.674.10893.1.20.130.4.1.1'  => 'arrayDiskNumber',
1271              '1.3.6.1.4.1.674.10893.1.20.130.4.1.2'  => 'arrayDiskName',
1272              '1.3.6.1.4.1.674.10893.1.20.130.4.1.3'  => 'arrayDiskVendor',
1273              '1.3.6.1.4.1.674.10893.1.20.130.4.1.4'  => 'arrayDiskState',
1274              '1.3.6.1.4.1.674.10893.1.20.130.4.1.6'  => 'arrayDiskProductID',
1275              '1.3.6.1.4.1.674.10893.1.20.130.4.1.9'  => 'arrayDiskEnclosureID',
1276              '1.3.6.1.4.1.674.10893.1.20.130.4.1.10' => 'arrayDiskChannel',
1277              '1.3.6.1.4.1.674.10893.1.20.130.4.1.11' => 'arrayDiskLengthInMB',
1278              '1.3.6.1.4.1.674.10893.1.20.130.4.1.15' => 'arrayDiskTargetID',
1279              '1.3.6.1.4.1.674.10893.1.20.130.4.1.16' => 'arrayDiskLunID',
1280              '1.3.6.1.4.1.674.10893.1.20.130.4.1.24' => 'arrayDiskComponentStatus',
1281              '1.3.6.1.4.1.674.10893.1.20.130.4.1.26' => 'arrayDiskNexusID',
1282              '1.3.6.1.4.1.674.10893.1.20.130.4.1.31' => 'arrayDiskSmartAlertIndication',
1283              '1.3.6.1.4.1.674.10893.1.20.130.5.1.5'  => 'arrayDiskEnclosureConnectionEnclosureNumber',
1284              '1.3.6.1.4.1.674.10893.1.20.130.5.1.7'  => 'arrayDiskEnclosureConnectionControllerNumber',
1285             );
1286         my $result = $snmp_session->get_entries(-columns => [keys %pdisk_oid]);
1287
1288         if (!defined $result) {
1289             printf "SNMP ERROR [storage / pdisk]: %s.\n", $snmp_session->error;
1290             $snmp_session->close;
1291             exit $E_UNKNOWN;
1292         }
1293
1294         @output = @{ get_snmp_output($result, \%pdisk_oid) };
1295     }
1296     else {
1297         foreach my $c (@controllers) {
1298             push @output, @{ run_omreport("storage pdisk controller=$c") };
1299             map_item('ctrl', $c, \@output);
1300         }
1301     }
1302
1303     my %pdisk_state
1304       = (
1305          0  => 'Unknown',
1306          1  => 'Ready',
1307          2  => 'Failed',
1308          3  => 'Online',
1309          4  => 'Offline',
1310          6  => 'Degraded',
1311          7  => 'Recovering',
1312          11 => 'Removed',
1313          15 => 'Resynching',
1314          24 => 'Rebuilding',
1315          25 => 'No Media',
1316          26 => 'Formatting',
1317          28 => 'Diagnostics',
1318          34 => 'Predictive failure',
1319          35 => 'Initializing',
1320          39 => 'Foreign',
1321          40 => 'Clear',
1322          41 => 'Unsupported',
1323          53 => 'Incompatible',
1324         );
1325
1326     # Check physical disks on each of the controllers
1327   PDISK:
1328     foreach my $out (@output) {
1329         if ($snmp) {
1330             $name   = $out->{arrayDiskName};
1331             if ($name =~ m{.*\d+:\d+:\d+\z}xms) {
1332                 $id = join q{:}, ($out->{arrayDiskChannel}, $out->{arrayDiskEnclosureID},
1333                                  $out->{arrayDiskTargetID});
1334             }
1335             else {
1336                 $id = join q{:}, ($out->{arrayDiskChannel}, $out->{arrayDiskTargetID});
1337             }
1338             $state    = $pdisk_state{$out->{arrayDiskState}};
1339             $status   = $snmp_status{$out->{arrayDiskComponentStatus}};
1340             $fpred    = $out->{arrayDiskSmartAlertIndication} == 2 ? 1 : 0;
1341             $progr    = q{};
1342             $ctrl     = exists $out->{arrayDiskEnclosureConnectionControllerNumber}
1343               ? $out->{arrayDiskEnclosureConnectionControllerNumber} - 1
1344                 : -1;
1345             $nexus    = convert_nexus($out->{arrayDiskNexusID});
1346             $vendor   = $out->{arrayDiskVendor};
1347             $product  = $out->{arrayDiskProductID};
1348             $capacity = $out->{arrayDiskLengthInMB} * 1024**2;
1349         }
1350         else {
1351             $id       = $out->{'ID'};
1352             $name     = $out->{'Name'};
1353             $state    = $out->{'State'};
1354             $status   = $out->{'Status'};
1355             $fpred    = lc($out->{'Failure Predicted'}) eq 'yes' ? 1 : 0;
1356             $progr    = ' [' . $out->{'Progress'} . ']';
1357             $ctrl     = $out->{'ctrl'};
1358             $nexus    = join q{:}, $out->{ctrl}, $id;
1359             $vendor   = $out->{'Vendor ID'};
1360             $product  = $out->{'Product ID'};
1361             $capacity = $out->{'Capacity'};
1362             $capacity =~ s{\A .*? \((\d+) \s bytes\) \z}{$1}xms;
1363         }
1364
1365         next PDISK if blacklisted('pdisk', $nexus);
1366         $count{pdisk}++;
1367
1368         $vendor  =~ s{\s+\z}{}xms; # remove trailing whitespace
1369         $product =~ s{\s+\z}{}xms; # remove trailing whitespace
1370
1371         # Calculate human readable capacity
1372         $capacity = ceil($capacity / 1000**3) >= 1000
1373           ? sprintf '%.1fTB', ($capacity / 1000**4)
1374             : sprintf '%.0fGB', ($capacity / 1000**3);
1375         $capacity = '450GB' if $capacity eq '449GB';  # quick fix for 450GB disks
1376         $capacity = '300GB' if $capacity eq '299GB';  # quick fix for 300GB disks
1377         $capacity = '146GB' if $capacity eq '147GB';  # quick fix for 146GB disks
1378
1379         # Capitalize only the first letter of the vendor name
1380         $vendor = (substr $vendor, 0, 1) . lc (substr $vendor, 1, length $vendor);
1381
1382         # Remove unnecessary trademark rubbish from vendor name
1383         $vendor =~ s{\(tm\)\z}{}xms;
1384
1385         # Special case: Failure predicted
1386         if ($status eq 'Non-Critical' and $fpred) {
1387             my $msg = sprintf '%s [%s %s, %s] on ctrl %d needs attention: Failure Predicted',
1388               $name, $vendor, $product, $capacity, $ctrl;
1389             report('storage', $msg, $E_WARNING, $nexus);
1390         }
1391         # Special case: Rebuilding
1392         elsif ($state eq 'Rebuilding') {
1393             my $msg = sprintf '%s [%s] on ctrl %d is %s%s',
1394               $name, $capacity, $ctrl, $state, $progr;
1395             report('storage', $msg, $E_WARNING, $nexus);
1396         }
1397         # Default
1398         elsif ($status ne 'Ok') {
1399             my $msg =  sprintf '%s [%s %s, %s] on ctrl %d needs attention: %s',
1400               $name, $vendor, $product, $capacity, $ctrl, $state;
1401             report('storage', $msg, $status2nagios{$status}, $nexus);
1402         }
1403         # Ok
1404         else {
1405             my $msg = sprintf '%s [%s] on ctrl %d is %s',
1406               $name, $capacity, $ctrl, $state;
1407             report('storage', $msg, $E_OK, $nexus);
1408         }
1409     }
1410     return;
1411 }
1412
1413
1414 #-----------------------------------------
1415 # STORAGE: Check logical drives
1416 #-----------------------------------------
1417 sub check_virtual_disks {
1418     return if $#controllers == -1;
1419
1420     my $id     = undef;
1421     my $name   = undef;
1422     my $nexus  = undef;
1423     my $dev    = undef;
1424     my $state  = undef;
1425     my $status = undef;
1426     my $layout = undef;
1427     my $size   = undef;
1428     my $progr  = undef;
1429     my $ctrl   = undef;
1430     my @output = ();
1431
1432     if ($snmp) {
1433         my %vdisk_oid
1434           = (
1435              '1.3.6.1.4.1.674.10893.1.20.140.1.1.3'  => 'virtualDiskDeviceName',
1436              '1.3.6.1.4.1.674.10893.1.20.140.1.1.4'  => 'virtualDiskState',
1437              '1.3.6.1.4.1.674.10893.1.20.140.1.1.6'  => 'virtualDiskLengthInMB',
1438              '1.3.6.1.4.1.674.10893.1.20.140.1.1.13' => 'virtualDiskLayout',
1439              '1.3.6.1.4.1.674.10893.1.20.140.1.1.17' => 'virtualDiskTargetID',
1440              '1.3.6.1.4.1.674.10893.1.20.140.1.1.20' => 'virtualDiskComponentStatus',
1441              '1.3.6.1.4.1.674.10893.1.20.140.1.1.21' => 'virtualDiskNexusID',
1442             );
1443         my $result = $snmp_session->get_entries(-columns => [keys %vdisk_oid]);
1444
1445         # No logical drives is OK
1446         return if !defined $result;
1447
1448         @output = @{ get_snmp_output($result, \%vdisk_oid) };
1449     }
1450     else {
1451         foreach my $c (@controllers) {
1452             push @output, @{ run_omreport("storage vdisk controller=$c") };
1453             map_item('ctrl', $c, \@output);
1454         }
1455     }
1456
1457     my %vdisk_state
1458       = (
1459          0  => 'Unknown',
1460          1  => 'Ready',
1461          2  => 'Failed',
1462          3  => 'Online',
1463          4  => 'Offline',
1464          6  => 'Degraded',
1465          15 => 'Resynching',
1466          16 => 'Regenerating',
1467          24 => 'Rebuilding',
1468          26 => 'Formatting',
1469          32 => 'Reconstructing',
1470          35 => 'Initializing',
1471          36 => 'Background Initialization',
1472          38 => 'Resynching Paused',
1473          52 => 'Permanently Degraded',
1474          54 => 'Degraded Redundancy',
1475         );
1476
1477     my %vdisk_layout
1478       = (
1479          1  => 'Concatenated',
1480          2  => 'RAID-0',
1481          3  => 'RAID-1',
1482          7  => 'RAID-5',
1483          8  => 'RAID-6',
1484          10 => 'RAID-10',
1485          12 => 'RAID-50',
1486          19 => 'Concatenated RAID 1',
1487          24 => 'RAID-60',
1488         );
1489
1490     # Check virtual disks on each of the controllers
1491   VDISK:
1492     foreach my $out (@output) {
1493         if ($snmp) {
1494             $id     = $out->{virtualDiskTargetID};
1495             $dev    = $out->{virtualDiskDeviceName};
1496             $state  = $vdisk_state{$out->{virtualDiskState}};
1497             $status = $snmp_status{$out->{virtualDiskComponentStatus}};
1498             $layout = $vdisk_layout{$out->{virtualDiskLayout}};
1499             $size   = sprintf '%.2f GB', $out->{virtualDiskLengthInMB} / 1024;
1500             $progr  = q{};  # can't get this from SNMP(?)
1501             $nexus  = convert_nexus($out->{virtualDiskNexusID});
1502             $ctrl   = $nexus;  # We use the nexus id to get the controller id
1503             $ctrl   =~ s{\A (\d+):\d+ \z}{$1}xms;
1504         }
1505         else {
1506             $id     = $out->{ID};
1507             $dev    = $out->{'Device Name'};
1508             $state  = $out->{State};
1509             $status = $out->{Status};
1510             $layout = $out->{Layout};
1511             $size   = $out->{Size};
1512             $progr  = ' [' . $out->{Progress} . ']';
1513             $size   =~ s{\A (.*GB).* \z}{$1}xms;
1514             $nexus  = join q{:}, $out->{ctrl}, $id;
1515             $ctrl   = $out->{ctrl};
1516         }
1517
1518         next VDISK if blacklisted('vdisk', $nexus);
1519         $count{vdisk}++;
1520
1521         # The device name is undefined sometimes
1522         $dev = q{} if !defined $dev;
1523
1524         # Special case: Regenerating
1525         if ($state eq 'Regenerating') {
1526             my $msg = sprintf q{Logical drive %d '%s' [%s, %s] on ctrl %d is %s%s},
1527               $id, $dev, $layout, $size, $ctrl, $state, $progr;
1528             report('storage', $msg, $E_WARNING, $nexus);
1529         }
1530         # Default
1531         elsif ($status ne 'Ok') {
1532             my $msg = sprintf q{Logical drive %d '%s' [%s, %s] on ctrl %d needs attention: %s},
1533               $id, $dev, $layout, $size, $ctrl, $state;
1534             report('storage', $msg, $status2nagios{$status}, $nexus);
1535         }
1536         # Ok
1537         else {
1538             my $msg = sprintf q{Logical drive %d '%s' [%s, %s] on ctrl %d is %s},
1539               $id, $dev, $layout, $size, $ctrl, $state;
1540             report('storage', $msg, $E_OK, $nexus);
1541         }
1542     }
1543     return;
1544 }
1545
1546
1547 #-----------------------------------------
1548 # STORAGE: Check cache batteries
1549 #-----------------------------------------
1550 sub check_cache_battery {
1551     return if $#controllers == -1;
1552
1553     my $id     = undef;
1554     my $nexus  = undef;
1555     my $state  = undef;
1556     my $status = undef;
1557     my $ctrl   = undef;
1558     my $learn  = undef; # learn state
1559     my $pred   = undef; # battery's ability to be charged
1560     my @output = ();
1561
1562     if ($snmp) {
1563         my %bat_oid
1564           = (
1565              '1.3.6.1.4.1.674.10893.1.20.130.15.1.4'  => 'batteryState',
1566              '1.3.6.1.4.1.674.10893.1.20.130.15.1.6'  => 'batteryComponentStatus',
1567              '1.3.6.1.4.1.674.10893.1.20.130.15.1.9'  => 'batteryNexusID',
1568              '1.3.6.1.4.1.674.10893.1.20.130.15.1.10' => 'batteryPredictedCapacity',
1569              '1.3.6.1.4.1.674.10893.1.20.130.15.1.12' => 'batteryLearnState',
1570              '1.3.6.1.4.1.674.10893.1.20.130.16.1.5'  => 'batteryConnectionControllerNumber',
1571             );
1572         my $result = $snmp_session->get_entries(-columns => [keys %bat_oid]);
1573
1574         # No cache battery is OK
1575         return if !defined $result;
1576
1577         @output = @{ get_snmp_output($result, \%bat_oid) };
1578     }
1579     else {
1580         foreach my $c (@controllers) {
1581             push @output, @{ run_omreport("storage battery controller=$c") };
1582             map_item('ctrl', $c, \@output);
1583         }
1584     }
1585
1586     my %bat_state
1587       = (
1588          0  => 'Unknown',
1589          1  => 'Ready',
1590          2  => 'Failed',
1591          6  => 'Degraded',
1592          7  => 'Reconditioning',
1593          9  => 'High',
1594          10 => 'Power Low',
1595          12 => 'Charging',
1596          21 => 'Missing',
1597          36 => 'Learning',
1598         );
1599
1600     # Specifies the learn state activity of the battery
1601     my %bat_learn_state
1602       = (
1603          1  => 'Failed',
1604          2  => 'Active',
1605          4  => 'Timed out',
1606          8  => 'Requested',
1607          16 => 'Idle',
1608         );
1609
1610     # This property displays the battery's ability to be charged
1611     my %bat_pred_cap
1612       = (
1613          1 => 'Failed',  # The battery cannot be charged and needs to be replaced
1614          2 => 'Ready',   # The battery can be charged to full capacity
1615          4 => 'Unknown', # The battery is completing a Learn cycle. The charge capacity of the
1616                          # battery cannot be determined until the Learn cycle is complete
1617         );
1618
1619     # Check battery on each of the controllers
1620   BATTERY:
1621     foreach my $out (@output) {
1622         if ($snmp) {
1623             $state  = $bat_state{$out->{batteryState}};
1624             $status = $snmp_status{$out->{batteryComponentStatus}};
1625             $learn  = exists $out->{batteryLearnState}
1626               ? $bat_learn_state{$out->{batteryLearnState}} : undef;
1627             $pred   = exists $out->{batteryPredictedCapacity}
1628               ? $bat_pred_cap{$out->{batteryPredictedCapacity}} : undef;
1629             $ctrl   = $out->{batteryConnectionControllerNumber} - 1;
1630             $nexus  = convert_nexus($out->{batteryNexusID});
1631             $id     = $nexus;
1632             $id     =~ s{\A \d+:(\d+) \z}{$1}xms;
1633         }
1634         else {
1635             $id     = $out->{'ID'};
1636             $state  = $out->{'State'};
1637             $status = $out->{'Status'};
1638             $learn  = $out->{'Learn State'};
1639             $pred   = $out->{'Predicted Capacity Status'};
1640             $ctrl   = $out->{'ctrl'};
1641             $nexus  = join q{:}, $out->{ctrl}, $id;
1642         }
1643
1644         next BATTERY if blacklisted('bat', $nexus);
1645
1646         # Special case: Charging
1647         if ($state eq 'Charging') {
1648             if ($pred eq 'Failed') {
1649                 my $msg = sprintf 'Cache battery %d in controller %d is %s (%s) [replace battery]',
1650                   $id, $ctrl, $state, $pred;
1651                 report('storage', $msg, $E_CRITICAL, $nexus);
1652             }
1653             else {
1654                 next BATTERY if blacklisted('bat_charge', $nexus);
1655                 my $msg = sprintf 'Cache battery %d in controller %d is %s (%s) [probably harmless]',
1656                   $id, $ctrl, $state, $pred;
1657                 report('storage', $msg, $E_WARNING, $nexus);
1658             }
1659         }
1660         # Special case: Learning (battery learns its capacity)
1661         elsif ($state eq 'Learning') {
1662             if ($learn eq 'Failed') {
1663                 my $msg = sprintf 'Cache battery %d in controller %d is %s (%s)',
1664                   $id, $ctrl, $state, $learn;
1665                 report('storage', $msg, $E_CRITICAL, $nexus);
1666             }
1667             else {
1668                 next BATTERY if blacklisted('bat_charge', $nexus);
1669                 my $msg = sprintf 'Cache battery %d in controller %d is %s (%s) [probably harmless]',
1670                   $id, $ctrl, $state, $learn;
1671                 report('storage', $msg, $E_WARNING, $nexus);
1672             }
1673         }
1674         # Special case: Power Low (first part of recharge cycle)
1675         elsif ($state eq 'Power Low') {
1676             next BATTERY if blacklisted('bat_charge', $nexus);
1677             my $msg = sprintf 'Cache battery %d in controller %d is %s [probably harmless]',
1678               $id, $ctrl, $state;
1679             report('storage', $msg, $E_WARNING, $nexus);
1680         }
1681         # Special case: Degraded and Non-Critical (usually part of recharge cycle)
1682         elsif ($state eq 'Degraded' && $status eq 'Non-Critical') {
1683             next BATTERY if blacklisted('bat_charge', $nexus);
1684             my $msg = sprintf 'Cache battery %d in controller %d is %s (%s) [probably harmless]',
1685               $id, $ctrl, $state, $status;
1686             report('storage', $msg, $E_WARNING, $nexus);
1687         }
1688         # Default
1689         elsif ($status ne 'Ok') {
1690             my $msg = sprintf 'Cache battery %d in controller %d needs attention: %s (%s)',
1691               $id, $ctrl, $state, $status;
1692             report('storage', $msg, $status2nagios{$status}, $nexus);
1693         }
1694         # Ok
1695         else {
1696             my $msg = sprintf 'Cache battery %d in controller %d is %s',
1697               $id, $ctrl, $state;
1698             report('storage', $msg, $E_OK, $nexus);
1699         }
1700     }
1701     return;
1702 }
1703
1704
1705 #-----------------------------------------
1706 # STORAGE: Check connectors (channels)
1707 #-----------------------------------------
1708 sub check_connectors {
1709     return if $#controllers == -1;
1710
1711     my $id     = undef;
1712     my $nexus  = undef;
1713     my $name   = undef;
1714     my $state  = undef;
1715     my $status = undef;
1716     my $type   = undef;
1717     my $ctrl   = undef;
1718     my @output = ();
1719
1720     if ($snmp) {
1721         my %conn_oid
1722           = (
1723              '1.3.6.1.4.1.674.10893.1.20.130.2.1.1'  => 'channelNumber',
1724              '1.3.6.1.4.1.674.10893.1.20.130.2.1.2'  => 'channelName',
1725              '1.3.6.1.4.1.674.10893.1.20.130.2.1.3'  => 'channelState',
1726              '1.3.6.1.4.1.674.10893.1.20.130.2.1.8'  => 'channelComponentStatus',
1727              '1.3.6.1.4.1.674.10893.1.20.130.2.1.9'  => 'channelNexusID',
1728              '1.3.6.1.4.1.674.10893.1.20.130.2.1.11' => 'channelBusType',
1729             );
1730         my $result = $snmp_session->get_entries(-columns => [keys %conn_oid]);
1731
1732         if (!defined $result) {
1733             printf "SNMP ERROR [storage / channel]: %s.\n", $snmp_session->error;
1734             $snmp_session->close;
1735             exit $E_UNKNOWN;
1736         }
1737
1738         @output = @{ get_snmp_output($result, \%conn_oid) };
1739     }
1740     else {
1741         foreach my $c (@controllers) {
1742             push @output, @{ run_omreport("storage connector controller=$c") };
1743             map_item('ctrl', $c, \@output);
1744         }
1745     }
1746
1747     my %conn_state
1748       = (
1749          0 => 'Unknown',
1750          1 => 'Ready',
1751          2 => 'Failed',
1752          3 => 'Online',
1753          4 => 'Offline',
1754          6 => 'Degraded',
1755         );
1756
1757     my %conn_bustype
1758       = (
1759          1 => 'SCSI',
1760          2 => 'IDE',
1761          3 => 'Fibre Channel',
1762          4 => 'SSA',
1763          6 => 'USB',
1764          7 => 'SATA',
1765          8 => 'SAS',
1766         );
1767
1768     # Check connectors on each of the controllers
1769   CHANNEL:
1770     foreach my $out (@output) {
1771         if ($snmp) {
1772             $id     = $out->{channelNumber} - 1;
1773             $name   = $out->{channelName};
1774             $state  = $conn_state{$out->{channelState}};
1775             $status = $snmp_status{$out->{channelComponentStatus}};
1776             $type   = $conn_bustype{$out->{channelBusType}};
1777             $nexus  = convert_nexus($out->{channelNexusID});
1778             $ctrl   = $nexus;
1779             $ctrl   =~ s{(\d+):\d+}{$1}xms;
1780         }
1781         else {
1782             $id     = $out->{'ID'};
1783             $name   = $out->{'Name'};
1784             $state  = $out->{'State'};
1785             $status = $out->{'Status'};
1786             $type   = $out->{'Connector Type'};
1787             $ctrl   = $out->{ctrl};
1788             $nexus  = join q{:}, $out->{ctrl}, $id;
1789         }
1790
1791         next CHANNEL if blacklisted('conn', $nexus);
1792
1793         my $msg = sprintf '%s [%s] on controller %d is %s',
1794           $name, $type, $ctrl, $state;
1795         report('storage', $msg, $status2nagios{$status}, $nexus);
1796     }
1797     return;
1798 }
1799
1800
1801 #-----------------------------------------
1802 # STORAGE: Check enclosures
1803 #-----------------------------------------
1804 sub check_enclosures {
1805     my $id       = undef;
1806     my $nexus    = undef;
1807     my $name     = undef;
1808     my $state    = undef;
1809     my $status   = undef;
1810     my $firmware = undef;
1811     my $ctrl     = undef;
1812     my @output   = ();
1813
1814     if ($snmp) {
1815         my %encl_oid
1816           = (
1817              '1.3.6.1.4.1.674.10893.1.20.130.3.1.1'  => 'enclosureNumber',
1818              '1.3.6.1.4.1.674.10893.1.20.130.3.1.2'  => 'enclosureName',
1819              '1.3.6.1.4.1.674.10893.1.20.130.3.1.4'  => 'enclosureState',
1820              '1.3.6.1.4.1.674.10893.1.20.130.3.1.19' => 'enclosureChannelNumber',
1821              '1.3.6.1.4.1.674.10893.1.20.130.3.1.24' => 'enclosureComponentStatus',
1822              '1.3.6.1.4.1.674.10893.1.20.130.3.1.25' => 'enclosureNexusID',
1823              '1.3.6.1.4.1.674.10893.1.20.130.3.1.26' => 'enclosureFirmwareVersion',
1824             );
1825         my $result = $snmp_session->get_entries(-columns => [keys %encl_oid]);
1826
1827         # No enclosures is OK
1828         return if !defined $result;
1829
1830         @output = @{ get_snmp_output($result, \%encl_oid) };
1831     }
1832     else {
1833         foreach my $c (@controllers) {
1834             push @output, @{ run_omreport("storage enclosure controller=$c") };
1835             map_item('ctrl', $c, \@output);
1836         }
1837     }
1838
1839     my %encl_state
1840       = (
1841          0 => 'Unknown',
1842          1 => 'Ready',
1843          2 => 'Failed',
1844          3 => 'Online',
1845          4 => 'Offline',
1846          6 => 'Degraded',
1847         );
1848
1849   ENCLOSURE:
1850     foreach my $out (@output) {
1851         if ($snmp) {
1852             $id       = $out->{'enclosureNumber'} - 1;
1853             $name     = $out->{'enclosureName'};
1854             $state    = $encl_state{$out->{'enclosureState'}};
1855             $status   = $snmp_status{$out->{'enclosureComponentStatus'}};
1856             $firmware = exists $out->{enclosureFirmwareVersion}
1857               ? $out->{enclosureFirmwareVersion} : 'N/A';
1858             $nexus    = convert_nexus($out->{enclosureNexusID});
1859             $ctrl     = $nexus;
1860             $ctrl     =~ s{\A (\d+):.* \z}{$1}xms;
1861         }
1862         else {
1863             $id       = $out->{ID};
1864             $name     = $out->{Name};
1865             $state    = $out->{State};
1866             $status   = $out->{Status};
1867             $firmware = $out->{'Firmware Version'} ne 'Not Applicable'
1868               ? $out->{'Firmware Version'} : 'N/A';
1869             $nexus    = join q{:}, $out->{ctrl}, $id;
1870             $ctrl     = $out->{ctrl};
1871         }
1872
1873         $name     =~ s{\s+\z}{}xms; # remove trailing whitespace
1874         $firmware =~ s{\s+\z}{}xms; # remove trailing whitespace
1875
1876         # store enclosure data for future use
1877         push @enclosures, { 'id'    => $id,
1878                             'ctrl'  => $out->{ctrl},
1879                             'name'  => $name };
1880
1881         # Collecting some storage info
1882         $sysinfo{'enclosure'}{$nexus}{'id'}       = $nexus;
1883         $sysinfo{'enclosure'}{$nexus}{'name'}     = $name;
1884         $sysinfo{'enclosure'}{$nexus}{'firmware'} = $firmware;
1885
1886         next ENCLOSURE if blacklisted('encl', $nexus);
1887
1888         my $msg = sprintf 'Enclosure %s [%s] on controller %d is %s',
1889           $nexus, $name, $ctrl, $state;
1890         report('storage', $msg, $status2nagios{$status}, $nexus);
1891     }
1892     return;
1893 }
1894
1895
1896 #-----------------------------------------
1897 # STORAGE: Check enclosure fans
1898 #-----------------------------------------
1899 sub check_enclosure_fans {
1900     return if $#controllers == -1;
1901
1902     my $id        = undef;
1903     my $nexus     = undef;
1904     my $name      = undef;
1905     my $state     = undef;
1906     my $status    = undef;
1907     my $speed     = undef;
1908     my $encl_id   = undef;
1909     my $encl_name = undef;
1910     my @output    = ();
1911
1912     if ($snmp) {
1913         my %fan_oid
1914           = (
1915              '1.3.6.1.4.1.674.10893.1.20.130.7.1.1'  => 'fanNumber',
1916              '1.3.6.1.4.1.674.10893.1.20.130.7.1.2'  => 'fanName',
1917              '1.3.6.1.4.1.674.10893.1.20.130.7.1.4'  => 'fanState',
1918              '1.3.6.1.4.1.674.10893.1.20.130.7.1.11' => 'fanProbeCurrValue',
1919              '1.3.6.1.4.1.674.10893.1.20.130.7.1.15' => 'fanComponentStatus',
1920              '1.3.6.1.4.1.674.10893.1.20.130.7.1.16' => 'fanNexusID',
1921              '1.3.6.1.4.1.674.10893.1.20.130.8.1.4'  => 'fanConnectionEnclosureName',
1922              '1.3.6.1.4.1.674.10893.1.20.130.8.1.5'  => 'fanConnectionEnclosureNumber',
1923             );
1924
1925         my $result = $snmp_session->get_entries(-columns => [keys %fan_oid]);
1926
1927         # No enclosure fans is OK
1928         return if !defined $result;
1929
1930         @output = @{ get_snmp_output($result, \%fan_oid) };
1931     }
1932     else {
1933         foreach my $enc (@enclosures) {
1934             push @output, @{ run_omreport("storage enclosure controller=$enc->{ctrl} enclosure=$enc->{id} info=fans") };
1935             map_item('ctrl', $enc->{ctrl}, \@output);
1936             map_item('encl_id', $enc->{id}, \@output);
1937             map_item('encl_name', $enc->{name}, \@output);
1938         }
1939     }
1940
1941     my %fan_state
1942       = (
1943          0  => 'Unknown',
1944          1  => 'Ready',
1945          2  => 'Failed',
1946          3  => 'Online',
1947          4  => 'Offline',
1948          6  => 'Degraded',
1949          21 => 'Missing',
1950         );
1951
1952     # Check fans on each of the enclosures
1953   FAN:
1954     foreach my $out (@output) {
1955         if ($snmp) {
1956             $id        = $out->{fanNumber} - 1;
1957             $name      = $out->{fanName};
1958             $state     = $fan_state{$out->{fanState}};
1959             $status    = $snmp_status{$out->{fanComponentStatus}};
1960             $speed     = $out->{fanProbeCurrValue};
1961             $encl_id   = $out->{fanConnectionEnclosureNumber} - 1;
1962             $encl_name = $out->{fanConnectionEnclosureName};
1963             $nexus     = convert_nexus($out->{fanNexusID});
1964         }
1965         else {
1966             $id        = $out->{'ID'};
1967             $name      = $out->{'Name'};
1968             $state     = $out->{'State'};
1969             $status    = $out->{'Status'};
1970             $speed     = $out->{'Speed'};
1971             $encl_id   = join q{:}, $out->{ctrl}, $out->{'encl_id'};
1972             $encl_name = $out->{encl_name};
1973             $nexus     = join q{:}, $out->{ctrl}, $out->{'encl_id'}, $id;
1974         }
1975
1976         next FAN if blacklisted('encl_fan', $nexus);
1977
1978         # Default
1979         if ($status ne 'Ok') {
1980             my $msg = sprintf '%s in enclosure %s [%s] needs attention: %s',
1981               $name, $encl_id, $encl_name, $state;
1982             report('storage', $msg, $status2nagios{$status}, $nexus);
1983         }
1984         # Ok
1985         else {
1986             my $msg = sprintf '%s in enclosure %s [%s] is %s (speed=%s)',
1987               $name, $encl_id, $encl_name, $state, $speed;
1988             report('storage', $msg, $E_OK, $nexus);
1989         }
1990     }
1991     return;
1992 }
1993
1994
1995 #-----------------------------------------
1996 # STORAGE: Check enclosure power supplies
1997 #-----------------------------------------
1998 sub check_enclosure_pwr {
1999     return if $#controllers == -1;
2000
2001     my $id        = undef;
2002     my $nexus     = undef;
2003     my $name      = undef;
2004     my $state     = undef;
2005     my $status    = undef;
2006     my $encl_id   = undef;
2007     my $encl_name = undef;
2008     my @output    = ();
2009
2010     if ($snmp) {
2011         my %ps_oid
2012           = (
2013              '1.3.6.1.4.1.674.10893.1.20.130.9.1.1'  => 'powerSupplyNumber',
2014              '1.3.6.1.4.1.674.10893.1.20.130.9.1.2'  => 'powerSupplyName',
2015              '1.3.6.1.4.1.674.10893.1.20.130.9.1.4'  => 'powerSupplyState',
2016              '1.3.6.1.4.1.674.10893.1.20.130.9.1.9'  => 'powerSupplyComponentStatus',
2017              '1.3.6.1.4.1.674.10893.1.20.130.9.1.10' => 'powerSupplyNexusID',
2018              '1.3.6.1.4.1.674.10893.1.20.130.10.1.4' => 'powerSupplyConnectionEnclosureName',
2019              '1.3.6.1.4.1.674.10893.1.20.130.10.1.5' => 'powerSupplyConnectionEnclosureNumber',
2020             );
2021         my $result = $snmp_session->get_entries(-columns => [keys %ps_oid]);
2022
2023         # No enclosure power supplies is OK
2024         return if !defined $result;
2025
2026         @output = @{ get_snmp_output($result, \%ps_oid) };
2027     }
2028     else {
2029         foreach my $enc (@enclosures) {
2030             push @output, @{ run_omreport("storage enclosure controller=$enc->{ctrl} enclosure=$enc->{id} info=pwrsupplies") };
2031             map_item('ctrl', $enc->{ctrl}, \@output);
2032             map_item('encl_id', $enc->{id}, \@output);
2033             map_item('encl_name', $enc->{name}, \@output);
2034         }
2035     }
2036
2037     my %ps_state
2038       = (
2039          0  => 'Unknown',
2040          1  => 'Ready',
2041          2  => 'Failed',
2042          5  => 'Not Installed',
2043          6  => 'Degraded',
2044          11 => 'Removed',
2045          21 => 'Missing',
2046         );
2047
2048     # Check power supplies on each of the enclosures
2049   PS:
2050     foreach my $out (@output) {
2051         if ($snmp) {
2052             $id        = $out->{powerSupplyNumber};
2053             $name      = $out->{powerSupplyName};
2054             $state     = $ps_state{$out->{powerSupplyState}};
2055             $status    = $snmp_status{$out->{powerSupplyComponentStatus}};
2056             $encl_id   = $out->{powerSupplyConnectionEnclosureNumber} - 1;
2057             $encl_name = $out->{powerSupplyConnectionEnclosureName};
2058             $nexus     = convert_nexus($out->{powerSupplyNexusID});
2059         }
2060         else {
2061             $id        = $out->{'ID'};
2062             $name      = $out->{'Name'};
2063             $state     = $out->{'State'};
2064             $status    = $out->{'Status'};
2065             $encl_id   = join q{:}, $out->{ctrl}, $out->{'encl_id'};
2066             $encl_name = $out->{encl_name};
2067             $nexus     = join q{:}, $out->{ctrl}, $out->{'encl_id'}, $id;
2068         }
2069
2070         next PS if blacklisted('encl_ps', $nexus);
2071
2072         # Default
2073         if ($status ne 'Ok') {
2074             my $msg = sprintf '%s in enclosure %s [%s] needs attention: %s',
2075               $name, $encl_id, $encl_name, $state;
2076             report('storage', $msg, $status2nagios{$status}, $nexus);
2077         }
2078         # Ok
2079         else {
2080             my $msg = sprintf '%s in enclosure %s [%s] is %s',
2081               $name, $encl_id, $encl_name, $state;
2082             report('storage', $msg, $E_OK, $nexus);
2083         }
2084     }
2085     return;
2086 }
2087
2088
2089 #-----------------------------------------
2090 # STORAGE: Check enclosure temperatures
2091 #-----------------------------------------
2092 sub check_enclosure_temp {
2093     return if $#controllers == -1;
2094
2095     my $id        = undef;
2096     my $nexus     = undef;
2097     my $name      = undef;
2098     my $state     = undef;
2099     my $status    = undef;
2100     my $reading   = undef;
2101     my $unit      = undef;
2102     my $max_warn  = undef;
2103     my $max_crit  = undef;
2104     my $encl_id   = undef;
2105     my $encl_name = undef;
2106     my @output    = ();
2107
2108     if ($snmp) {
2109         my %temp_oid
2110           = (
2111              '1.3.6.1.4.1.674.10893.1.20.130.11.1.1'  => 'temperatureProbeNumber',
2112              '1.3.6.1.4.1.674.10893.1.20.130.11.1.2'  => 'temperatureProbeName',
2113              '1.3.6.1.4.1.674.10893.1.20.130.11.1.4'  => 'temperatureProbeState',
2114              '1.3.6.1.4.1.674.10893.1.20.130.11.1.6'  => 'temperatureProbeUnit',
2115              '1.3.6.1.4.1.674.10893.1.20.130.11.1.9'  => 'temperatureProbeMaxWarning',
2116              '1.3.6.1.4.1.674.10893.1.20.130.11.1.10' => 'temperatureProbeMaxCritical',
2117              '1.3.6.1.4.1.674.10893.1.20.130.11.1.11' => 'temperatureProbeCurValue',
2118              '1.3.6.1.4.1.674.10893.1.20.130.11.1.13' => 'temperatureProbeComponentStatus',
2119              '1.3.6.1.4.1.674.10893.1.20.130.11.1.14' => 'temperatureProbeNexusID',
2120              '1.3.6.1.4.1.674.10893.1.20.130.12.1.4'  => 'temperatureConnectionEnclosureName',
2121              '1.3.6.1.4.1.674.10893.1.20.130.12.1.5'  => 'temperatureConnectionEnclosureNumber',
2122             );
2123         my $result = $snmp_session->get_entries(-columns => [keys %temp_oid]);
2124
2125         # No enclosure temperature probes is OK
2126         return if !defined $result;
2127
2128         @output = @{ get_snmp_output($result, \%temp_oid) };
2129     }
2130     else {
2131         foreach my $enc (@enclosures) {
2132             push @output, @{ run_omreport("storage enclosure controller=$enc->{ctrl} enclosure=$enc->{id} info=temps") };
2133             map_item('ctrl', $enc->{ctrl}, \@output);
2134             map_item('encl_id', $enc->{id}, \@output);
2135             map_item('encl_name', $enc->{name}, \@output);
2136         }
2137     }
2138
2139     my %temp_state
2140       = (
2141          0  => 'Unknown',
2142          1  => 'Ready',
2143          2  => 'Failed',
2144          4  => 'Offline',
2145          6  => 'Degraded',
2146          9  => 'Inactive',
2147          21 => 'Missing',
2148         );
2149
2150     # Check temperature probes on each of the enclosures
2151   TEMP:
2152     foreach my $out (@output) {
2153         if ($snmp) {
2154             $id        = $out->{temperatureProbeNumber} - 1;
2155             $name      = $out->{temperatureProbeName};
2156             $state     = $temp_state{$out->{temperatureProbeState}};
2157             $status    = $snmp_status{$out->{temperatureProbeComponentStatus}};
2158             $unit      = $out->{temperatureProbeUnit};
2159             $reading   = $out->{temperatureProbeCurValue};
2160             $max_warn  = $out->{temperatureProbeMaxWarning};
2161             $max_crit  = $out->{temperatureProbeMaxCritical};
2162             $encl_id   = $out->{temperatureConnectionEnclosureNumber} - 1;
2163             $encl_name = $out->{temperatureConnectionEnclosureName};
2164             $nexus     = convert_nexus($out->{temperatureProbeNexusID});
2165         }
2166         else {
2167             $id        = $out->{'ID'};
2168             $name      = $out->{'Name'};
2169             $state     = $out->{'State'};
2170             $status    = $out->{'Status'};
2171             $unit      = 'FIXME';
2172             $reading   = $out->{'Reading'}; $reading =~ s{\s*C}{}xms;
2173             $max_warn  = $out->{'Maximum Warning Threshold'}; $max_warn =~ s{\s*C}{}xms;
2174             $max_crit  = $out->{'Maximum Failure Threshold'}; $max_crit =~ s{\s*C}{}xms;
2175             $encl_id   = join q{:}, $out->{ctrl}, $out->{'encl_id'};
2176             $encl_name = $out->{encl_name};
2177             $nexus     = join q{:}, $out->{ctrl}, $out->{'encl_id'}, $id;
2178         }
2179
2180         next TEMP if blacklisted('encl_temp', $nexus);
2181
2182         # Default
2183         if ($status ne 'Ok') {
2184             my $msg = sprintf '%s in enclosure %s [%s] is %s C at %s (%s max)',
2185               $name, $encl_id, $encl_name, $state, $reading, $max_crit;
2186             report('storage', $msg, $status2nagios{$status}, $nexus);
2187         }
2188         # Ok
2189         else {
2190             my $msg = sprintf '%s in enclosure %s [%s]: %s C (%s max)',
2191               $name, $encl_id, $encl_name, $reading, $max_crit;
2192             report('storage', $msg, $E_OK, $nexus);
2193         }
2194
2195         # Collect performance data
2196         if (defined $opt{perfdata}) {
2197             $name =~ s{\A Temperature\sProbe\s(\d+) \z}{temp_$1}gxms;
2198             my $pkey = "enclosure_${encl_id}_${name}";
2199             my $pval = join q{;}, "${reading}C", $max_warn, $max_crit;
2200             $perfdata{$pkey} = $pval;
2201         }
2202     }
2203     return;
2204 }
2205
2206
2207 #-----------------------------------------
2208 # STORAGE: Check enclosure management modules (EMM)
2209 #-----------------------------------------
2210 sub check_enclosure_emms {
2211     return if $#controllers == -1;
2212
2213     my $id        = undef;
2214     my $nexus     = undef;
2215     my $name      = undef;
2216     my $state     = undef;
2217     my $status    = undef;
2218     my $encl_id   = undef;
2219     my $encl_name = undef;
2220     my @output    = ();
2221
2222     if ($snmp) {
2223         my %emms_oid
2224           = (
2225              '1.3.6.1.4.1.674.10893.1.20.130.13.1.1'  => 'enclosureManagementModuleNumber',
2226              '1.3.6.1.4.1.674.10893.1.20.130.13.1.2'  => 'enclosureManagementModuleName',
2227              '1.3.6.1.4.1.674.10893.1.20.130.13.1.4'  => 'enclosureManagementModuleState',
2228              '1.3.6.1.4.1.674.10893.1.20.130.13.1.11' => 'enclosureManagementModuleComponentStatus',
2229              '1.3.6.1.4.1.674.10893.1.20.130.13.1.12' => 'enclosureManagementModuleNexusID',
2230              '1.3.6.1.4.1.674.10893.1.20.130.14.1.4'  => 'enclosureManagementModuleConnectionEnclosureName',
2231              '1.3.6.1.4.1.674.10893.1.20.130.14.1.5'  => 'enclosureManagementModuleConnectionEnclosureNumber',
2232             );
2233         my $result = $snmp_session->get_entries(-columns => [keys %emms_oid]);
2234
2235         # No enclosure EMMs is OK
2236         return if !defined $result;
2237
2238         @output = @{ get_snmp_output($result, \%emms_oid) };
2239     }
2240     else {
2241         foreach my $enc (@enclosures) {
2242             push @output, @{ run_omreport("storage enclosure controller=$enc->{ctrl} enclosure=$enc->{id} info=emms") };
2243             map_item('ctrl', $enc->{ctrl}, \@output);
2244             map_item('encl_id', $enc->{id}, \@output);
2245             map_item('encl_name', $enc->{name}, \@output);
2246         }
2247     }
2248
2249     my %emms_state
2250       = (
2251          0  => 'Unknown',
2252          1  => 'Ready',
2253          2  => 'Failed',
2254          3  => 'Online',
2255          4  => 'Offline',
2256          5  => 'Not Installed',
2257          6  => 'Degraded',
2258          21 => 'Missing',
2259         );
2260
2261     # Check temperature probes on each of the enclosures
2262   EMM:
2263     foreach my $out (@output) {
2264         if ($snmp) {
2265             $id        = $out->{enclosureManagementModuleNumber} - 1;
2266             $name      = $out->{enclosureManagementModuleName};
2267             $state     = $emms_state{$out->{enclosureManagementModuleState}};
2268             $status    = $snmp_status{$out->{enclosureManagementModuleComponentStatus}};
2269             $encl_id   = $out->{enclosureManagementModuleConnectionEnclosureNumber} - 1;
2270             $encl_name = $out->{enclosureManagementModuleConnectionEnclosureName};
2271             $nexus     = convert_nexus($out->{enclosureManagementModuleNexusID});
2272         }
2273         else {
2274             $id        = $out->{'ID'};
2275             $name      = $out->{'Name'};
2276             $state     = $out->{'State'};
2277             $status    = $out->{'Status'};
2278             $encl_id   = join q{:}, $out->{ctrl}, $out->{'encl_id'};
2279             $encl_name = $out->{encl_name};
2280             $nexus     = join q{:}, $out->{ctrl}, $out->{'encl_id'}, $id;
2281         }
2282
2283         next EMM if blacklisted('encl_emm', $nexus);
2284
2285         # Default
2286         if ($status ne 'Ok') {
2287             my $msg = sprintf '%s in enclosure %s [%s] needs attention: %s',
2288               $name, $encl_id, $encl_name, $state;
2289             report('storage', $msg, $status2nagios{$status}, $nexus);
2290         }
2291         # Ok
2292         else {
2293             my $msg = sprintf '%s in enclosure %s [%s] is %s',
2294               $name, $encl_id, $encl_name, $state;
2295             report('storage', $msg, $E_OK, $nexus);
2296         }
2297     }
2298     return;
2299 }
2300
2301
2302 #-----------------------------------------
2303 # CHASSIS: Check memory modules
2304 #-----------------------------------------
2305 sub check_memory {
2306     my $index    = undef;
2307     my $status   = undef;
2308     my $location = undef;
2309     my $size     = undef;
2310     my $modes    = undef;
2311     my @failures = ();
2312     my @output   = ();
2313
2314     if ($snmp) {
2315         my %dimm_oid
2316           = (
2317              '1.3.6.1.4.1.674.10892.1.1100.50.1.2.1'  => 'memoryDeviceIndex',
2318              '1.3.6.1.4.1.674.10892.1.1100.50.1.5.1'  => 'memoryDeviceStatus',
2319              '1.3.6.1.4.1.674.10892.1.1100.50.1.8.1'  => 'memoryDeviceLocationName',
2320              '1.3.6.1.4.1.674.10892.1.1100.50.1.14.1' => 'memoryDeviceSize',
2321              '1.3.6.1.4.1.674.10892.1.1100.50.1.20.1' => 'memoryDeviceFailureModes',
2322             );
2323         my $result = $snmp_session->get_entries(-columns => [keys %dimm_oid]);
2324
2325         if (!defined $result) {
2326             printf "SNMP ERROR [memory]: %s.\n", $snmp_session->error;
2327             $snmp_session->close;
2328             exit $E_UNKNOWN;
2329         }
2330
2331         @output = @{ get_snmp_output($result, \%dimm_oid) };
2332     }
2333     else {
2334         @output = @{ run_omreport("$omopt_chassis memory") };
2335     }
2336
2337     # Note: These values are bit masks, so combination values are
2338     # possible. If value is 0 (zero), memory device has no faults.
2339     my %failure_mode
2340       = (
2341          1  => 'ECC single bit correction warning rate exceeded',
2342          2  => 'ECC single bit correction failure rate exceeded',
2343          4  => 'ECC multibit fault encountered',
2344          8  => 'ECC single bit correction logging disabled',
2345          16 => 'device disabled because of spare activation',
2346         );
2347
2348   DIMM:
2349     foreach my $out (@output) {
2350         @failures = ();  # Initialize
2351         if ($snmp) {
2352             $index    = $out->{memoryDeviceIndex};
2353             $status   = $snmp_status{$out->{memoryDeviceStatus}};
2354             $location = $out->{memoryDeviceLocationName};
2355             $size     = sprintf '%d MB', $out->{memoryDeviceSize}/1024;
2356             $modes    = $out->{memoryDeviceFailureModes};
2357             if ($modes > 0) {
2358                 foreach my $mask (sort keys %failure_mode) {
2359                     if (($modes & $mask) != 0) { push @failures, $failure_mode{$mask}; }
2360                 }
2361             }
2362         }
2363         else {
2364             $index    = $out->{'Type'} eq '[Not Occupied]' ? undef : $out->{'Index'};
2365             $status   = $out->{'Status'};
2366             $location = $out->{'Connector Name'};
2367             $size     = $out->{'Size'};
2368             if (defined $size) {
2369                 $size =~ s{\s\s}{ }gxms;
2370             }
2371             # Run 'omreport chassis memory index=X' to get the failures
2372             if ($status ne 'Ok' && defined $index) {
2373                 foreach (@{ run_command("$omreport $omopt_chassis memory index=$index -fmt ssv") }) {
2374                     if (m/\A Failures; (.+?) \z/xms) {
2375                         chop(my $fail = $1);
2376                         push @failures, split m{\.}xms, $fail;
2377                     }
2378                 }
2379             }
2380         }
2381         $location =~ s{\A \s*(.*?)\s* \z}{$1}xms;
2382
2383         next DIMM if blacklisted('dimm', $index);
2384
2385         # Ignore empty memory slots
2386         next DIMM if !defined $index;
2387         $count{dimm}++;
2388
2389         if ($status ne 'Ok') {
2390             my $msg = undef;
2391             if (scalar @failures == 0) {
2392                 $msg = sprintf 'Memory module %d [%s, %s] needs attention (%s)',
2393                   $index, $location, $size, $status;
2394             }
2395             else {
2396                 $msg = sprintf 'Memory module %d [%s, %s] needs attention: %s',
2397                   $index, $location, $size, (join q{, }, @failures);
2398             }
2399
2400             report('chassis', $msg, $status2nagios{$status}, $index);
2401         }
2402         # Ok
2403         else {
2404             my $msg = sprintf 'Memory module %d [%s, %s] is %s',
2405               $index, $location, $size, $status;
2406             report('chassis', $msg, $E_OK, $index);
2407         }
2408     }
2409     return;
2410 }
2411
2412
2413 #-----------------------------------------
2414 # CHASSIS: Check fans
2415 #-----------------------------------------
2416 sub check_fans {
2417     my $index    = undef;
2418     my $status   = undef;
2419     my $reading  = undef;
2420     my $location = undef;
2421     my $max_crit = undef;
2422     my $max_warn = undef;
2423     my @output   = ();
2424
2425     if ($snmp) {
2426         my %cool_oid
2427           = (
2428              '1.3.6.1.4.1.674.10892.1.700.12.1.2.1'  => 'coolingDeviceIndex',
2429              '1.3.6.1.4.1.674.10892.1.700.12.1.5.1'  => 'coolingDeviceStatus',
2430              '1.3.6.1.4.1.674.10892.1.700.12.1.6.1'  => 'coolingDeviceReading',
2431              '1.3.6.1.4.1.674.10892.1.700.12.1.8.1'  => 'coolingDeviceLocationName',
2432              '1.3.6.1.4.1.674.10892.1.700.12.1.10.1' => 'coolingDeviceUpperCriticalThreshold',
2433              '1.3.6.1.4.1.674.10892.1.700.12.1.11.1' => 'coolingDeviceUpperNonCriticalThreshold',
2434             );
2435         my $result = $snmp_session->get_entries(-columns => [keys %cool_oid]);
2436
2437         if ($blade && !defined $result) {
2438             return 0;
2439         }
2440         elsif (!$blade && !defined $result) {
2441             printf "SNMP ERROR [cooling]: %s.\n", $snmp_session->error;
2442             $snmp_session->close;
2443             exit $E_UNKNOWN;
2444         }
2445
2446         @output = @{ get_snmp_output($result, \%cool_oid) };
2447     }
2448     else {
2449         @output = @{ run_omreport("$omopt_chassis fans") };
2450     }
2451
2452   FAN:
2453     foreach my $out (@output) {
2454         if ($snmp) {
2455             $index    = $out->{coolingDeviceIndex};
2456             $status   = $snmp_probestatus{$out->{coolingDeviceStatus}};
2457             $reading  = $out->{coolingDeviceReading};
2458             $location = $out->{coolingDeviceLocationName};
2459             $max_crit = exists $out->{coolingDeviceUpperCriticalThreshold}
2460               ? $out->{coolingDeviceUpperCriticalThreshold} : 0;
2461             $max_warn = exists $out->{coolingDeviceUpperNonCriticalThreshold}
2462               ? $out->{coolingDeviceUpperNonCriticalThreshold} : 0;
2463         }
2464         else {
2465             $index    = $out->{'Index'};
2466             $status   = $out->{'Status'};
2467             $reading  = $out->{'Reading'};
2468             $location = $out->{'Probe Name'};
2469             $max_crit = $out->{'Maximum Failure Threshold'} ne '[N/A]'
2470               ? $out->{'Maximum Failure Threshold'} : 0;
2471             $max_warn = $out->{'Maximum Warning Threshold'} ne '[N/A]'
2472               ? $out->{'Maximum Warning Threshold'} : 0;
2473             $reading  =~ s{\A (\d+).* \z}{$1}xms;
2474             $max_warn =~ s{\A (\d+).* \z}{$1}xms;
2475             $max_crit =~ s{\A (\d+).* \z}{$1}xms;
2476         }
2477
2478         next FAN if blacklisted('fan', $index);
2479         $count{fan}++;
2480
2481         if ($status ne 'Ok') {
2482             my $msg = sprintf 'Chassis fan %d [%s] needs attention: %s',
2483               $index, $location, $status;
2484             my $err = $snmp ? $probestatus2nagios{$status} : $status2nagios{$status};
2485             report('chassis', $msg, $err, $index);
2486         }
2487         else {
2488             my $msg = sprintf 'Chassis fan %d [%s]: %s',
2489               $index, $location, $reading;
2490             report('chassis', $msg, $E_OK, $index);
2491         }
2492
2493         # Collect performance data
2494         if (defined $opt{perfdata}) {
2495             my $pname = lc $location;
2496             $pname =~ s{\s}{_}gxms;
2497             $pname =~ s{proc_}{cpu#}xms;
2498             my $pkey = join q{_}, 'fan', $index, $pname;
2499             my $pval = join q{;}, "${reading}RPM", $max_warn, $max_crit;
2500             $perfdata{$pkey} = $pval;
2501         }
2502     }
2503     return;
2504 }
2505
2506
2507 #-----------------------------------------
2508 # CHASSIS: Check power supplies
2509 #-----------------------------------------
2510 sub check_powersupplies {
2511     my $index    = undef;
2512     my $status   = undef;
2513     my $type     = undef;
2514     my $err_type = undef;
2515     my $state    = undef;
2516     my @states   = ();
2517     my @output   = ();
2518
2519     if ($snmp) {
2520         my %ps_oid
2521           = (
2522              '1.3.6.1.4.1.674.10892.1.600.12.1.2.1'  => 'powerSupplyIndex',
2523              '1.3.6.1.4.1.674.10892.1.600.12.1.5.1'  => 'powerSupplyStatus',
2524              '1.3.6.1.4.1.674.10892.1.600.12.1.7.1'  => 'powerSupplyType',
2525              '1.3.6.1.4.1.674.10892.1.600.12.1.11.1' => 'powerSupplySensorState',
2526              '1.3.6.1.4.1.674.10892.1.600.12.1.12.1' => 'powerSupplyConfigurationErrorType',
2527             );
2528         my $result = $snmp_session->get_entries(-columns => [keys %ps_oid]);
2529
2530         # No instrumented PSU is OK (blades, low-end servers)
2531         return 0 if !defined $result;
2532
2533         @output = @{ get_snmp_output($result, \%ps_oid) };
2534     }
2535     else {
2536         @output = @{ run_omreport("$omopt_chassis pwrsupplies") };
2537     }
2538
2539     my %ps_type
2540       = (
2541          1  => 'Other',
2542          2  => 'Unknown',
2543          3  => 'Linear',
2544          4  => 'Switching',
2545          5  => 'Battery',
2546          6  => 'Uninterruptible Power Supply',
2547          7  => 'Converter',
2548          8  => 'Regulator',
2549          9  => 'AC',
2550          10 => 'DC',
2551          11 => 'VRM',
2552         );
2553
2554     my %ps_state
2555       = (
2556          1  => 'Presence detected',
2557          2  => 'Failure detected',
2558          4  => 'Predictive Failure',
2559          8  => 'AC lost',
2560          16 => 'AC lost or out-of-range',
2561          32 => 'AC out-of-range but present',
2562          64 => 'Configuration error',
2563         );
2564
2565     my %ps_config_error_type
2566       = (
2567          1 => 'Vendor mismatch',
2568          2 => 'Revision mismatch',
2569          3 => 'Processor missing',
2570         );
2571
2572   PS:
2573     foreach my $out (@output) {
2574         if ($snmp) {
2575             @states = ();  # contains states for the PS
2576
2577             $index    = $out->{powerSupplyIndex} - 1;
2578             $status   = $snmp_status{$out->{powerSupplyStatus}};
2579             $type     = $ps_type{$out->{powerSupplyType}};
2580             $err_type = defined $out->{powerSupplyConfigurationErrorType}
2581               ? $ps_config_error_type{$out->{powerSupplyConfigurationErrorType}} : undef;
2582
2583             # get the combined state from the StatusReading OID
2584             foreach my $mask (sort keys %ps_state) {
2585                 if (($out->{powerSupplySensorState} & $mask) != 0) {
2586                     push @states, $ps_state{$mask};
2587                 }
2588             }
2589
2590             # If configuration error, also include the error type
2591             if (defined $err_type) {
2592                 push @states, $err_type;
2593             }
2594
2595             # Finally, construct the state string
2596             $state = join q{, }, @states;
2597         }
2598         else {
2599             $index  = $out->{'Index'};
2600             $status = $out->{'Status'};
2601             $type   = $out->{'Type'};
2602             $state  = $out->{'Online Status'};
2603         }
2604
2605         next PS if blacklisted('ps', $index);
2606         $count{power}++;
2607
2608         if ($status ne 'Ok') {
2609             my $msg = sprintf 'Power Supply %d [%s] needs attention: %s',
2610               $index, $type, $state;
2611             report('chassis', $msg, $status2nagios{$status}, $index);
2612         }
2613         else {
2614             my $msg = sprintf 'Power Supply %d [%s]: %s',
2615               $index, $type, $state;
2616             report('chassis', $msg, $E_OK, $index);
2617         }
2618     }
2619     return;
2620 }
2621
2622
2623 #-----------------------------------------
2624 # CHASSIS: Check temperatures
2625 #-----------------------------------------
2626 sub check_temperatures {
2627     my $index    = undef;
2628     my $status   = undef;
2629     my $reading  = undef;
2630     my $location = undef;
2631     my $max_crit = undef;
2632     my $max_warn = undef;
2633     my $min_warn = undef;
2634     my $min_crit = undef;
2635     my $type     = undef;
2636     my $discrete = undef;
2637     my @output = ();
2638
2639     # Getting custom temperature thresholds (user option)
2640     my %warn_threshold = %{ custom_temperature_thresholds('w') };
2641     my %crit_threshold = %{ custom_temperature_thresholds('c') };
2642
2643     if ($snmp) {
2644         my %temp_oid
2645           = (
2646              '1.3.6.1.4.1.674.10892.1.700.20.1.2.1'  => 'temperatureProbeIndex',
2647              '1.3.6.1.4.1.674.10892.1.700.20.1.5.1'  => 'temperatureProbeStatus',
2648              '1.3.6.1.4.1.674.10892.1.700.20.1.6.1'  => 'temperatureProbeReading',
2649              '1.3.6.1.4.1.674.10892.1.700.20.1.7.1'  => 'temperatureProbeType',
2650              '1.3.6.1.4.1.674.10892.1.700.20.1.8.1'  => 'temperatureProbeLocationName',
2651              '1.3.6.1.4.1.674.10892.1.700.20.1.10.1' => 'temperatureProbeUpperCriticalThreshold',
2652              '1.3.6.1.4.1.674.10892.1.700.20.1.11.1' => 'temperatureProbeUpperNonCriticalThreshold',
2653              '1.3.6.1.4.1.674.10892.1.700.20.1.12.1' => 'temperatureProbeLowerNonCriticalThreshold',
2654              '1.3.6.1.4.1.674.10892.1.700.20.1.13.1' => 'temperatureProbeLowerCriticalThreshold',
2655              '1.3.6.1.4.1.674.10892.1.700.20.1.16.1' => 'temperatureProbeDiscreteReading',
2656             );
2657         # this didn't work well for some reason
2658         #my $result = $snmp_session->get_entries(-columns => [keys %temp_oid]);
2659
2660         # Getting values using the table
2661         my $temperatureProbeTable = '1.3.6.1.4.1.674.10892.1.700.20';
2662         my $result = $snmp_session->get_table(-baseoid => $temperatureProbeTable);
2663
2664         if (!defined $result) {
2665             printf "SNMP ERROR [temperatures]: %s.\n", $snmp_session->error;
2666             $snmp_session->close;
2667             exit $E_UNKNOWN;
2668         }
2669
2670         @output = @{ get_snmp_output($result, \%temp_oid) };
2671     }
2672     else {
2673         @output = @{ run_omreport("$omopt_chassis temps") };
2674     }
2675
2676     my %probe_type
2677       = (
2678          1  => 'Other',      # type is other than following values
2679          2  => 'Unknown',    # type is unknown
2680          3  => 'AmbientESM', # type is Ambient Embedded Systems Management temperature probe
2681          16 => 'Discrete',   # type is temperature probe with discrete reading
2682         );
2683
2684   TEMP:
2685     foreach my $out (@output) {
2686         if ($snmp) {
2687             $index    = $out->{temperatureProbeIndex} - 1;
2688             $status   = $snmp_probestatus{$out->{temperatureProbeStatus}};
2689             $reading  = $out->{temperatureProbeReading} / 10;
2690             $location = $out->{temperatureProbeLocationName};
2691             $max_crit = $out->{temperatureProbeUpperCriticalThreshold} / 10;
2692             $max_warn = $out->{temperatureProbeUpperNonCriticalThreshold} / 10;
2693             $min_crit = exists $out->{temperatureProbeLowerCriticalThreshold}
2694               ? $out->{temperatureProbeLowerCriticalThreshold} / 10 : '[N/A]';
2695             $min_warn = exists $out->{temperatureProbeLowerNonCriticalThreshold}
2696               ? $out->{temperatureProbeLowerNonCriticalThreshold} / 10 : '[N/A]';
2697             $type     = $probe_type{$out->{temperatureProbeType}};
2698             $discrete = exists $out->{temperatureProbeDiscreteReading}
2699               ? $out->{temperatureProbeDiscreteReading} : undef;
2700         }
2701         else {
2702             $index    = $out->{'Index'};
2703             $status   = $out->{'Status'};
2704             $reading  = $out->{'Reading'}; $reading =~ s{\.0\s+C}{}xms;
2705             $location = $out->{'Probe Name'};
2706             $max_crit = $out->{'Maximum Failure Threshold'}; $max_crit =~ s{\.0\s+C}{}xms;
2707             $max_warn = $out->{'Maximum Warning Threshold'}; $max_warn =~ s{\.0\s+C}{}xms;
2708             $min_crit = $out->{'Minimum Failure Threshold'}; $min_crit =~ s{\.0\s+C}{}xms;
2709             $min_warn = $out->{'Minimum Warning Threshold'}; $min_warn =~ s{\.0\s+C}{}xms;
2710             $type     = $reading =~ m{\A\d+\z}xms ? 'AmbientESM' : 'Discrete';
2711             $discrete = $reading;
2712         }
2713
2714         next TEMP if blacklisted('temp', $index);
2715         $count{temp}++;
2716
2717         if ($type eq 'Discrete') {
2718             my $msg = sprintf 'Temperature probe %d (%s): is %s',
2719               $index, $location, $discrete;
2720             my $err = $snmp ? $probestatus2nagios{$status} : $status2nagios{$status};
2721             report('chassis', $msg, $err, $index);
2722         }
2723         else {
2724             # First check according to custom thresholds
2725             if (exists $crit_threshold{$index}{max} and $reading > $crit_threshold{$index}{max}) {
2726                 # Custom critical MAX
2727                 my $msg = sprintf 'Temperature Probe %d [%s] reads %d C (custom max=%d)',
2728                   $index, $location, $reading, $crit_threshold{$index}{max};
2729                 report('chassis', $msg, $E_CRITICAL, $index);
2730             }
2731             elsif (exists $warn_threshold{$index}{max} and $reading > $warn_threshold{$index}{max}) {
2732                 # Custom warning MAX
2733                 my $msg = sprintf 'Temperature Probe %d [%s] reads %d C (custom max=%d)',
2734                   $index, $location, $reading, $warn_threshold{$index}{max};
2735                 report('chassis', $msg, $E_WARNING, $index);
2736             }
2737             elsif (exists $crit_threshold{$index}{min} and $reading < $crit_threshold{$index}{min}) {
2738                 # Custom critical MIN
2739                 my $msg = sprintf 'Temperature Probe %d [%s] reads %d C (custom min=%d)',
2740                   $index, $location, $reading, $crit_threshold{$index}{min};
2741                 report('chassis', $msg, $E_CRITICAL, $index);
2742             }
2743             elsif (exists $warn_threshold{$index}{min} and $reading < $warn_threshold{$index}{min}) {
2744                 # Custom warning MIN
2745                 my $msg = sprintf 'Temperature Probe %d [%s] reads %d C (custom min=%d)',
2746                   $index, $location, $reading, $warn_threshold{$index}{min};
2747                 report('chassis', $msg, $E_WARNING, $index);
2748             }
2749             elsif ($status ne 'Ok' and $max_crit ne '[N/A]' and $reading > $max_crit) {
2750                 my $msg = sprintf 'Temperature Probe %d [%s] is critically high at %d C',
2751                   $index, $location, $reading;
2752                 my $err = $snmp ? $probestatus2nagios{$status} : $status2nagios{$status};
2753                 report('chassis', $msg, $err, $index);
2754             }
2755             elsif ($status ne 'Ok' and $max_warn ne '[N/A]' and $reading > $max_warn) {
2756                 my $msg = sprintf 'Temperature Probe %d [%s] is too high at %d C',
2757                   $index, $location, $reading;
2758                 my $err = $snmp ? $probestatus2nagios{$status} : $status2nagios{$status};
2759                 report('chassis', $msg, $err, $index);
2760             }
2761             elsif ($status ne 'Ok' and $min_crit ne '[N/A]' and $reading < $min_crit) {
2762                 my $msg = sprintf 'Temperature Probe %d [%s] is critically low at %d C',
2763                   $index, $location, $reading;
2764                 my $err = $snmp ? $probestatus2nagios{$status} : $status2nagios{$status};
2765                 report('chassis', $msg, $err, $index);
2766             }
2767             elsif ($status ne 'Ok' and $min_warn ne '[N/A]' and $reading < $min_warn) {
2768                 my $msg = sprintf 'Temperature Probe %d [%s] is too low at %d C',
2769                   $index, $location, $reading;
2770                 my $err = $snmp ? $probestatus2nagios{$status} : $status2nagios{$status};
2771                 report('chassis', $msg, $err, $index);
2772             }
2773             # Ok
2774             else {
2775                 my $msg = sprintf 'Temperature Probe %d [%s] reads %d C',
2776                   $index, $location, $reading;
2777                 if ($min_warn eq '[N/A]' and $min_crit eq '[N/A]') {
2778                     $msg .= sprintf ' (max=%s/%s)', $max_warn, $max_crit;
2779                 }
2780                 else {
2781                     $msg .= sprintf ' (min=%s/%s, max=%s/%s)',
2782                       $min_warn, $min_crit, $max_warn, $max_crit;
2783                 }
2784                 my $err = $snmp ? $probestatus2nagios{$status} : $status2nagios{$status};
2785                 report('chassis', $msg, $err, $index);
2786             }
2787
2788             # Collect performance data
2789             if (defined $opt{perfdata}) {
2790                 my $pname = lc $location;
2791                 $pname =~ s{\s}{_}gxms;
2792                 $pname =~ s{_temp\z}{}xms;
2793                 $pname =~ s{proc_}{cpu#}xms;
2794                 my $pkey = join q{_}, 'temp', $index, $pname;
2795                 my $pval = join q{;}, "${reading}C", $max_warn, $max_crit;
2796                 $perfdata{$pkey} = $pval;
2797             }
2798         }
2799     }
2800     return;
2801 }
2802
2803
2804 #-----------------------------------------
2805 # CHASSIS: Check processors
2806 #-----------------------------------------
2807 sub check_processors {
2808     my $index   = undef;
2809     my $status  = undef;
2810     my $state   = undef;
2811     my $brand   = undef;
2812     my $family  = undef;
2813     my $man     = undef;
2814     my $speed   = undef;
2815     my @output = ();
2816
2817     if ($snmp) {
2818
2819         # NOTE: For some reason, older models don't have the
2820         # "Processor Device Status" OIDs. We check both the newer
2821         # (preferred) OIDs and the old ones.
2822
2823         my %cpu_oid
2824           = (
2825              '1.3.6.1.4.1.674.10892.1.1100.30.1.2.1'  => 'processorDeviceIndex',
2826              '1.3.6.1.4.1.674.10892.1.1100.30.1.5.1'  => 'processorDeviceStatus',
2827              '1.3.6.1.4.1.674.10892.1.1100.30.1.8.1'  => 'processorDeviceManufacturerName',
2828              '1.3.6.1.4.1.674.10892.1.1100.30.1.9.1'  => 'processorDeviceStatusState',
2829              '1.3.6.1.4.1.674.10892.1.1100.30.1.10.1' => 'processorDeviceFamily',
2830              '1.3.6.1.4.1.674.10892.1.1100.30.1.12.1' => 'processorDeviceCurrentSpeed',
2831              '1.3.6.1.4.1.674.10892.1.1100.30.1.23.1' => 'processorDeviceBrandName',
2832              '1.3.6.1.4.1.674.10892.1.1100.32.1.2.1'  => 'processorDeviceStatusIndex',
2833              '1.3.6.1.4.1.674.10892.1.1100.32.1.5.1'  => 'processorDeviceStatusStatus',
2834              '1.3.6.1.4.1.674.10892.1.1100.32.1.6.1'  => 'processorDeviceStatusReading',
2835             );
2836
2837         my $result = $snmp_session->get_entries(-columns => [keys %cpu_oid]);
2838
2839         if (!defined $result) {
2840             printf "SNMP ERROR [processors]: %s.\n", $snmp_session->error;
2841             $snmp_session->close;
2842             exit $E_UNKNOWN;
2843         }
2844
2845         @output = @{ get_snmp_output($result, \%cpu_oid) };
2846     }
2847     else {
2848         @output = @{ run_omreport("$omopt_chassis processors") };
2849     }
2850
2851     my %cpu_state
2852       = (
2853          1 => 'Other',         # other than following values
2854          2 => 'Unknown',       # unknown
2855          3 => 'Enabled',       # enabled
2856          4 => 'User Disabled', # disabled by user via BIOS setup
2857          5 => 'BIOS Disabled', # disabled by BIOS (POST error)
2858          6 => 'Idle',          # idle
2859         );
2860
2861     my %cpu_reading
2862       = (
2863          1    => 'Internal Error',      # Internal Error
2864          2    => 'Thermal Trip',        # Thermal Trip
2865          32   => 'Configuration Error', # Configuration Error
2866          128  => 'Present',             # Processor Present
2867          256  => 'Disabled',            # Processor Disabled
2868          512  => 'Terminator Present',  # Terminator Present
2869          1024 => 'Throttled',           # Processor Throttled
2870         );
2871
2872     # Mapping between family numbers from SNMP and actual CPU family
2873     my %cpu_family
2874       = (
2875          1   => 'Other',                2   => 'Unknown',              3   => '8086',
2876          4   => '80286',                5   => '386',                  6   => '486',
2877          7   => '8087',                 8   => '80287',                9   => '80387',
2878          10  => '80487',                11  => 'Pentium',              12  => 'Pentium Pro',
2879          13  => 'Pentium II',           14  => 'Pentium with MMX',     15  => 'Celeron',
2880          16  => 'Pentium II Xeon',      17  => 'Pentium III',          18  => 'Pentium III Xeon',
2881          19  => 'Pentium III',          20  => 'Itanium',              21  => 'Xeon',
2882          22  => 'Pentium 4',            23  => 'Xeon MP',              24  => 'Itanium 2',
2883          25  => 'K5',                   26  => 'K6',                   27  => 'K6-2',
2884          28  => 'K6-3',                 29  => 'Athlon',               30  => 'AMD2900',
2885          31  => 'K6-2+',                32  => 'Power PC',             33  => 'Power PC 601',
2886          34  => 'Power PC 603',         35  => 'Power PC 603+',        36  => 'Power PC 604',
2887          37  => 'Power PC 620',         38  => 'Power PC x704',        39  => 'Power PC 750',
2888          48  => 'Alpha',                49  => 'Alpha 21064',          50  => 'Alpha 21066',
2889          51  => 'Alpha 21164',          52  => 'Alpha 21164PC',        53  => 'Alpha 21164a',
2890          54  => 'Alpha 21264',          55  => 'Alpha 21364',          64  => 'MIPS',
2891          65  => 'MIPS R4000',           66  => 'MIPS R4200',           67  => 'MIPS R4400',
2892          68  => 'MIPS R4600',           69  => 'MIPS R10000',          80  => 'SPARC',
2893          81  => 'SuperSPARC',           82  => 'microSPARC II',        83  => 'microSPARC IIep',
2894          84  => 'UltraSPARC',           85  => 'UltraSPARC II',        86  => 'UltraSPARC IIi',
2895          87  => 'UltraSPARC III',       88  => 'UltraSPARC IIIi',      96  => '68040',
2896          97  => '68xxx',                98  => '68000',                99  => '68010',
2897          100 => '68020',                101 => '68030',                112 => 'Hobbit',
2898          120 => 'Crusoe TM5000',        121 => 'Crusoe TM3000',        122 => 'Efficeon TM8000',
2899          128 => 'Weitek',               131 => 'Athlon 64',            132 => 'Opteron',
2900          133 => 'Sempron',              134 => 'Turion 64 Mobile',     135 => 'Dual-Core Opteron',
2901          136 => 'Athlon 64 X2 DC',      137 => 'Turion 64 X2 M',       138 => 'Quad-Core Opteron',
2902          139 => '3rd gen Opteron',      144 => 'PA-RISC',              145 => 'PA-RISC 8500',
2903          146 => 'PA-RISC 8000',         147 => 'PA-RISC 7300LC',       148 => 'PA-RISC 7200',
2904          149 => 'PA-RISC 7100LC',       150 => 'PA-RISC 7100',         160 => 'V30',
2905          171 => 'Dual-Core Xeon 5200',  172 => 'Dual-Core Xeon 7200',  173 => 'Quad-Core Xeon 7300',
2906          174 => 'Quad-Core Xeon 7400',  175 => 'Multi-Core Xeon 7400', 176 => 'M1',
2907          177 => 'M2',                   180 => 'AS400',                182 => 'Athlon XP',
2908          183 => 'Athlon MP',            184 => 'Duron',                185 => 'Pentium M',
2909          186 => 'Celeron D',            187 => 'Pentium D',            188 => 'Pentium Extreme',
2910          189 => 'Core Solo',            190 => 'Core2',                191 => 'Core2 Duo',
2911          198 => 'Core i7',              199 => 'Dual-Core Celeron',    200 => 'IBM390',
2912          201 => 'G4',                   202 => 'G5',                   203 => 'ESA/390 G6',
2913          204 => 'z/Architectur',        210 => 'C7-M',                 211 => 'C7-D',
2914          212 => 'C7',                   213 => 'Eden',                 214 => 'Multi-Core Xeon',
2915          215 => 'Dual-Core Xeon 3xxx',  216 => 'Quad-Core Xeon 3xxx',  218 => 'Dual-Core Xeon 5xxx',
2916          219 => 'Quad-Core Xeon 5xxx',  221 => 'Dual-Core Xeon 7xxx',  222 => 'Quad-Core Xeon 7xxx',
2917          223 => 'Multi-Core Xeon 7xxx', 250 => 'i860',                 251 => 'i960',
2918         );
2919
2920   CPU:
2921     foreach my $out (@output) {
2922         if ($snmp) {
2923             $index  = exists $out->{processorDeviceStatusIndex}
2924               ? $out->{processorDeviceStatusIndex} - 1
2925                 : $out->{processorDeviceIndex} - 1;
2926             $status = exists $out->{processorDeviceStatusStatus}
2927               ? $snmp_status{$out->{processorDeviceStatusStatus}}
2928                 : $snmp_status{$out->{processorDeviceStatus}};
2929             if (exists $out->{processorDeviceStatusReading}) {
2930                 my @states  = ();  # contains states for the CPU
2931
2932                 # get the combined state from the StatusReading OID
2933                 foreach my $mask (sort keys %cpu_reading) {
2934                     if (($out->{processorDeviceStatusReading} & $mask) != 0) {
2935                         push @states, $cpu_reading{$mask};
2936                     }
2937                 }
2938
2939                 # Finally, create the state string
2940                 $state = join q{, }, @states;
2941             }
2942             else {
2943                 $state  = $cpu_state{$out->{processorDeviceStatusState}};
2944             }
2945             $man    = $out->{processorDeviceManufacturerName};
2946             $family = (exists $out->{processorDeviceFamily}
2947                        and exists $cpu_family{$out->{processorDeviceFamily}})
2948               ? $cpu_family{$out->{processorDeviceFamily}} : undef;
2949             $speed  = $out->{processorDeviceCurrentSpeed};
2950             $brand  = $out->{processorDeviceBrandName};
2951         }
2952         else {
2953             $index  = $out->{'Index'};
2954             $status = $out->{'Status'};
2955             $state  = $out->{'State'};
2956             $brand  = exists $out->{'Processor Brand'} ? $out->{'Processor Brand'} : undef;
2957             $family = exists $out->{'Processor Family'} ? $out->{'Processor Family'} : undef;
2958             $man    = exists $out->{'Processor Manufacturer'} ? $out->{'Processor Manufacturer'} : undef;
2959             $speed  = exists $out->{'Current Speed'} ? $out->{'Current Speed'} : undef;
2960         }
2961
2962         next CPU if blacklisted('cpu', $index);
2963
2964         # Ignore unoccupied CPU slots (omreport)
2965         next CPU if (defined $out->{'Processor Manufacturer'}
2966                      and $out->{'Processor Manufacturer'} eq '[Not Occupied]')
2967           or (defined $out->{'Processor Brand'} and $out->{'Processor Brand'} eq '[Not Occupied]');
2968
2969         # Ignore unoccupied CPU slots (snmp)
2970         if ($snmp and exists $out->{processorDeviceStatusReading}
2971             and $out->{processorDeviceStatusReading} == 0) {
2972             next CPU;
2973         }
2974
2975         $count{cpu}++;
2976
2977         if (defined $brand) {
2978             $brand =~ s{\s\s+}{ }gxms;
2979             $brand =~ s{\((R|tm)\)}{}gxms;
2980             $brand =~ s{\s(CPU|Processor)}{}xms;
2981             $brand =~ s{\s\@}{}xms;
2982         }
2983         elsif (defined $family and defined $man and defined $speed) {
2984             $speed =~ s{\A (\d+) .*}{$1}xms;
2985             $brand = sprintf '%s %s %.2fGHz', $man, $family, $speed / 1000;
2986         }
2987         else {
2988             $brand = "unknown";
2989         }
2990
2991         # Default
2992         if ($status ne 'Ok') {
2993             my $msg = sprintf 'Processor %d [%s] needs attention: %s',
2994               $index, $brand, $state;
2995             report('chassis', $msg, $status2nagios{$status}, $index);
2996         }
2997         # Ok
2998         else {
2999             my $msg = sprintf 'Processor %d [%s] is %s',
3000               $index, $brand, $state;
3001             report('chassis', $msg, $E_OK, $index);
3002         }
3003     }
3004     return;
3005 }
3006
3007
3008 #-----------------------------------------
3009 # CHASSIS: Check voltage probes
3010 #-----------------------------------------
3011 sub check_volts {
3012     my $index    = undef;
3013     my $status   = undef;
3014     my $reading  = undef;
3015     my $location = undef;
3016     my @output = ();
3017
3018     if ($snmp) {
3019         my %volt_oid
3020           = (
3021              '1.3.6.1.4.1.674.10892.1.600.20.1.2.1'  => 'voltageProbeIndex',
3022              '1.3.6.1.4.1.674.10892.1.600.20.1.5.1'  => 'voltageProbeStatus',
3023              '1.3.6.1.4.1.674.10892.1.600.20.1.6.1'  => 'voltageProbeReading',
3024              '1.3.6.1.4.1.674.10892.1.600.20.1.8.1'  => 'voltageProbeLocationName',
3025              '1.3.6.1.4.1.674.10892.1.600.20.1.16.1' => 'voltageProbeDiscreteReading',
3026             );
3027
3028         my $voltageProbeTable = '1.3.6.1.4.1.674.10892.1.600.20.1';
3029         my $result = $snmp_session->get_table(-baseoid => $voltageProbeTable);
3030
3031         if (!defined $result) {
3032             printf "SNMP ERROR [voltage]: %s.\n", $snmp_session->error;
3033             $snmp_session->close;
3034             exit $E_UNKNOWN;
3035         }
3036
3037         @output = @{ get_snmp_output($result, \%volt_oid) };
3038     }
3039     else {
3040         @output = @{ run_omreport("$omopt_chassis volts") };
3041     }
3042
3043     my %volt_discrete_reading
3044       = (
3045          1 => 'Good',
3046          2 => 'Bad',
3047         );
3048
3049   VOLT:
3050     foreach my $out (@output) {
3051         if ($snmp) {
3052             $index    = $out->{voltageProbeIndex} - 1;
3053             $status   = $snmp_status{$out->{voltageProbeStatus}};
3054             $reading  = exists $out->{voltageProbeReading}
3055               ? sprintf('%.3f V', $out->{voltageProbeReading}/1000)
3056               : $volt_discrete_reading{$out->{voltageProbeDiscreteReading}};
3057             $location = $out->{voltageProbeLocationName};
3058         }
3059         else {
3060             $index    = $out->{'Index'};
3061             $status   = $out->{'Status'};
3062             $reading  = $out->{'Reading'};
3063             $location = $out->{'Probe Name'};
3064         }
3065
3066         next VOLT if blacklisted('volt', $index);
3067         $count{volt}++;
3068
3069         my $msg = sprintf 'Voltage sensor %d [%s] is %s',
3070           $index, $location, $reading;
3071         my $err = $snmp ? $probestatus2nagios{$status} : $status2nagios{$status};
3072         report('chassis', $msg, $err, $index);
3073     }
3074     return;
3075 }
3076
3077
3078 #-----------------------------------------
3079 # CHASSIS: Check batteries
3080 #-----------------------------------------
3081 sub check_batteries {
3082     my $index    = undef;
3083     my $status   = undef;
3084     my $reading  = undef;
3085     my $location = undef;
3086     my @output = ();
3087
3088     if ($snmp) {
3089         my %bat_oid
3090           = (
3091              '1.3.6.1.4.1.674.10892.1.600.50.1.2.1' => 'batteryIndex',
3092              '1.3.6.1.4.1.674.10892.1.600.50.1.5.1' => 'batteryStatus',
3093              '1.3.6.1.4.1.674.10892.1.600.50.1.6.1' => 'batteryReading',
3094              '1.3.6.1.4.1.674.10892.1.600.50.1.7.1' => 'batteryLocationName',
3095             );
3096         my $result = $snmp_session->get_entries(-columns => [keys %bat_oid]);
3097
3098         # No batteries is OK
3099         return 0 if !defined $result;
3100
3101         @output = @{ get_snmp_output($result, \%bat_oid) };
3102     }
3103     else {
3104         @output = @{ run_omreport("$omopt_chassis batteries") };
3105     }
3106
3107     my %bat_reading
3108       = (
3109          1 => 'Predictive Failure',
3110          2 => 'Failed',
3111          4 => 'Presence Detected',
3112         );
3113
3114   BATTERY:
3115     foreach my $out (@output) {
3116         if ($snmp) {
3117             $index    = $out->{batteryIndex} - 1;
3118             $status   = $snmp_status{$out->{batteryStatus}};
3119             $reading  = $bat_reading{$out->{batteryReading}};
3120             $location = $out->{batteryLocationName};
3121         }
3122         else {
3123             $index    = $out->{'Index'};
3124             $status   = $out->{'Status'};
3125             $reading  = $out->{'Reading'};
3126             $location = $out->{'Probe Name'};
3127         }
3128
3129         next BATTERY if blacklisted('bp', $index);
3130         $count{bat}++;
3131
3132         my $msg = sprintf 'Battery probe %d [%s] is %s',
3133           $index, $location, $reading;
3134         report('chassis', $msg, $status2nagios{$status}, $index);
3135     }
3136     return;
3137 }
3138
3139
3140 #-----------------------------------------
3141 # CHASSIS: Check amperage probes (power monitoring)
3142 #-----------------------------------------
3143 sub check_pwrmonitoring {
3144     my $index    = undef;
3145     my $status   = undef;
3146     my $reading  = undef;
3147     my $location = undef;
3148     my $max_crit = undef;
3149     my $max_warn = undef;
3150     my $unit     = undef;
3151     my @output = ();
3152
3153     if ($snmp) {
3154         my %amp_oid
3155           = (
3156              '1.3.6.1.4.1.674.10892.1.600.30.1.2.1'  => 'amperageProbeIndex',
3157              '1.3.6.1.4.1.674.10892.1.600.30.1.5.1'  => 'amperageProbeStatus',
3158              '1.3.6.1.4.1.674.10892.1.600.30.1.6.1'  => 'amperageProbeReading',
3159              '1.3.6.1.4.1.674.10892.1.600.30.1.7.1'  => 'amperageProbeType',
3160              '1.3.6.1.4.1.674.10892.1.600.30.1.8.1'  => 'amperageProbeLocationName',
3161              '1.3.6.1.4.1.674.10892.1.600.30.1.10.1' => 'amperageProbeUpperCriticalThreshold',
3162              '1.3.6.1.4.1.674.10892.1.600.30.1.11.1' => 'amperageProbeUpperNonCriticalThreshold',
3163              '1.3.6.1.4.1.674.10892.1.600.30.1.16.1' => 'amperageProbeDiscreteReading',
3164             );
3165         my $result = $snmp_session->get_entries(-columns => [keys %amp_oid]);
3166
3167         # No pwrmonitoring is OK
3168         return 0 if !defined $result;
3169
3170         @output = @{ get_snmp_output($result, \%amp_oid) };
3171     }
3172     else {
3173         @output = @{ run_omreport("$omopt_chassis pwrmonitoring") };
3174     }
3175
3176     my %amp_type   # Amperage probe types
3177       = (
3178          1  => 'amperageProbeTypeIsOther',            # other than following values
3179          2  => 'amperageProbeTypeIsUnknown',          # unknown
3180          3  => 'amperageProbeTypeIs1Point5Volt',      # 1.5 amperage probe
3181          4  => 'amperageProbeTypeIs3Point3volt',      # 3.3 amperage probe
3182          5  => 'amperageProbeTypeIs5Volt',            # 5 amperage probe
3183          6  => 'amperageProbeTypeIsMinus5Volt',       # -5 amperage probe
3184          7  => 'amperageProbeTypeIs12Volt',           # 12 amperage probe
3185          8  => 'amperageProbeTypeIsMinus12Volt',      # -12 amperage probe
3186          9  => 'amperageProbeTypeIsIO',               # I/O probe
3187          10 => 'amperageProbeTypeIsCore',             # Core probe
3188          11 => 'amperageProbeTypeIsFLEA',             # FLEA (standby) probe
3189          12 => 'amperageProbeTypeIsBattery',          # Battery probe
3190          13 => 'amperageProbeTypeIsTerminator',       # SCSI Termination probe
3191          14 => 'amperageProbeTypeIs2Point5Volt',      # 2.5 amperage probe
3192          15 => 'amperageProbeTypeIsGTL',              # GTL (ground termination logic) probe
3193          16 => 'amperageProbeTypeIsDiscrete',         # amperage probe with discrete reading
3194          23 => 'amperageProbeTypeIsPowerSupplyAmps',  # Power Supply probe with reading in Amps
3195          24 => 'amperageProbeTypeIsPowerSupplyWatts', # Power Supply probe with reading in Watts
3196          25 => 'amperageProbeTypeIsSystemAmps',       # System probe with reading in Amps
3197          26 => 'amperageProbeTypeIsSystemWatts',      # System probe with reading in Watts
3198         );
3199
3200     my %amp_discrete
3201       = (
3202          1 => 'Good',
3203          2 => 'Bad',
3204         );
3205
3206     my %amp_unit
3207       = (
3208          'amperageProbeTypeIsPowerSupplyAmps'  => 'hA',  # tenths of Amps
3209          'amperageProbeTypeIsSystemAmps'       => 'hA',  # tenths of Amps
3210          'amperageProbeTypeIsPowerSupplyWatts' => 'W',   # Watts
3211          'amperageProbeTypeIsSystemWatts'      => 'W',   # Watts
3212          'amperageProbeTypeIsDiscrete'         => q{},   # discrete reading, no unit
3213         );
3214
3215   AMP:
3216     foreach my $out (@output) {
3217         if ($snmp) {
3218             $index    = $out->{amperageProbeIndex} - 1;
3219             $status   = $snmp_status{$out->{amperageProbeStatus}};
3220             $reading  = $amp_type{$out->{amperageProbeType}} eq 'amperageProbeTypeIsDiscrete'
3221               ? $amp_discrete{$out->{amperageProbeDiscreteReading}}
3222                 : $out->{amperageProbeReading};
3223             $location = $out->{amperageProbeLocationName};
3224             $max_crit = exists $out->{amperageProbeUpperCriticalThreshold}
3225               ? $out->{amperageProbeUpperCriticalThreshold} : 0;
3226             $max_warn = exists $out->{amperageProbeUpperNonCriticalThreshold}
3227               ? $out->{amperageProbeUpperNonCriticalThreshold} : 0;
3228             $unit     = exists $amp_unit{$amp_type{$out->{amperageProbeType}}}
3229               ? $amp_unit{$amp_type{$out->{amperageProbeType}}} : 'mA';
3230             if ($unit eq 'hA') {
3231                 $reading  /= 10;
3232                 $max_crit /= 10;
3233                 $max_warn /= 10;
3234                 $unit      = 'A';
3235             }
3236         }
3237         else {
3238             $index    = $out->{'Index'};
3239             next AMP if (!defined $index || $index !~ m/^\d+$/x);
3240             $status   = $out->{'Status'};
3241             $reading  = $out->{'Reading'};
3242             $location = $out->{'Probe Name'};
3243             $max_crit = $out->{'Failure Threshold'} ne '[N/A]'
3244               ? $out->{'Failure Threshold'} : 0;
3245             $max_warn = $out->{'Warning Threshold'} ne '[N/A]'
3246               ? $out->{'Warning Threshold'} : 0;
3247             $reading  =~ s{\A (\d+.*?)\s+([a-zA-Z]+) \s*\z}{$1}xms;
3248             $unit     = $2;
3249             $max_warn =~ s{\A (\d+.*?)\s+[a-zA-Z]+ \s*\z}{$1}xms;
3250             $max_crit =~ s{\A (\d+.*?)\s+[a-zA-Z]+ \s*\z}{$1}xms;
3251         }
3252
3253         next AMP if blacklisted('amp', $index);
3254         next AMP if $index !~ m{\A \d+ \z}xms;
3255         $count{amp}++;
3256
3257         my $msg = sprintf 'Amperage probe %d [%s] reads %s %s',
3258           $index, $location, $reading, $unit, $status;
3259         report('chassis', $msg, $status2nagios{$status}, $index);
3260
3261         # Collect performance data
3262         if (defined $opt{perfdata}) {
3263             next AMP if $reading !~ m{\A \d+(\.\d+)? \z}xms; # discrete reading (not number)
3264             my $pname = lc $location;
3265             $pname =~ s{\s}{_}gxms;
3266             my $pkey = join q{_}, 'pwr_mon', $index, $pname;
3267             my $pval = join q{;}, "$reading$unit", $max_warn, $max_crit;
3268             $perfdata{$pkey} = $pval;
3269         }
3270     }
3271
3272     # Collect EXTRA performance data not found at first run. This is a
3273     # rather ugly hack
3274     if (defined $opt{perfdata} && !$snmp) {
3275         my $found = 0;
3276         my $index = 0;
3277         my %used  = ();
3278
3279         # find used indexes
3280         foreach (keys %perfdata) {
3281             if (m/\A pwr_mon_(\d+)/xms) {
3282                 $used{$1} = 1;
3283             }
3284         }
3285
3286       AMP2:
3287         foreach my $line (@{ run_command("$omreport $omopt_chassis pwrmonitoring -fmt ssv") }) {
3288             chop $line;
3289             if ($line eq 'Location;Reading') {
3290                 $found = 1;
3291                 next AMP2;
3292             }
3293             if ($line eq q{}) {
3294                 $found = 0;
3295                 next AMP2;
3296             }
3297             if ($found and $line =~ m/\A ([^;]+?) ; (\d*\.\d+) \s ([AW]) \z/xms) {
3298                 my $aname = lc $1;
3299                 my $aval = $2;
3300                 my $aunit = $3;
3301                 $aname =~ s{\s}{_}gxms;
3302
3303                 # don't use an existing index
3304                 while (exists $used{$index}) { ++$index; }
3305
3306                 $perfdata{"pwr_mon_${index}_${aname}"} = "$aval$aunit;0;0";
3307                 ++$index;
3308             }
3309         }
3310     }
3311
3312     return;
3313 }
3314
3315
3316 #-----------------------------------------
3317 # CHASSIS: Check intrusion
3318 #-----------------------------------------
3319 sub check_intrusion {
3320     my $index    = undef;
3321     my $status   = undef;
3322     my $reading  = undef;
3323     my @output = ();
3324
3325     if ($snmp) {
3326         my %int_oid
3327           = (
3328              '1.3.6.1.4.1.674.10892.1.300.70.1.2.1' => 'intrusionIndex',
3329              '1.3.6.1.4.1.674.10892.1.300.70.1.5.1' => 'intrusionStatus',
3330              '1.3.6.1.4.1.674.10892.1.300.70.1.6.1' => 'intrusionReading',
3331             );
3332         my $result = $snmp_session->get_entries(-columns => [keys %int_oid]);
3333
3334         # No intrusion is OK
3335         return 0 if !defined $result;
3336
3337         @output = @{ get_snmp_output($result, \%int_oid) };
3338     }
3339     else {
3340         @output = @{ run_omreport("$omopt_chassis intrusion") };
3341     }
3342
3343     my %int_reading
3344       = (
3345          1 => 'Not Breached',          # chassis not breached and no uncleared breaches
3346          2 => 'Breached',              # chassis currently breached
3347          3 => 'Breached Prior',        # chassis breached prior to boot and has not been cleared
3348          4 => 'Breach Sensor Failure', # intrusion sensor has failed
3349         );
3350
3351   INTRUSION:
3352     foreach my $out (@output) {
3353         if ($snmp) {
3354             $index    = $out->{intrusionIndex} - 1;
3355             $status   = $snmp_status{$out->{intrusionStatus}};
3356             $reading  = $int_reading{$out->{intrusionReading}};
3357         }
3358         else {
3359             $index    = $out->{'Index'};
3360             $status   = $out->{'Status'};
3361             $reading  = $out->{'State'};
3362         }
3363
3364         next INTRUSION if blacklisted('intr', $index);
3365         $count{intr}++;
3366
3367         if ($status ne 'Ok') {
3368             my $msg = sprintf 'Chassis intrusion %d detected: %s',
3369               $index, $reading;
3370             report('chassis', $msg, $E_WARNING, $index);
3371         }
3372         # Ok
3373         else {
3374             my $msg = sprintf 'Chassis intrusion %d detection: %s (%s)',
3375               $index, $status, $reading;
3376             report('chassis', $msg, $E_OK, $index);
3377         }
3378     }
3379     return;
3380 }
3381
3382
3383 #-----------------------------------------
3384 # CHASSIS: Check alert log
3385 #-----------------------------------------
3386 sub check_alertlog {
3387     return if $snmp; # Not supported with SNMP
3388
3389     my @output = @{ run_omreport("$omopt_system alertlog") };
3390     foreach my $out (@output) {
3391         ++$count{alert}{$out->{Severity}};
3392     }
3393
3394     # Create error messages and set exit value if appropriate
3395     my $err = 0;
3396     if ($count{alert}{'Critical'} > 0)        { $err = $E_CRITICAL; }
3397     elsif ($count{alert}{'Non-Critical'} > 0) { $err = $E_WARNING;  }
3398
3399     my $msg = sprintf 'Alert log content: %d critical, %d non-critical, %d ok',
3400       $count{alert}{'Critical'}, $count{alert}{'Non-Critical'}, $count{alert}{'Ok'};
3401     report('other', $msg, $err);
3402
3403     return;
3404 }
3405
3406 #-----------------------------------------
3407 # CHASSIS: Check ESM log overall health
3408 #-----------------------------------------
3409 sub check_esmlog_health {
3410     my $health = 'Ok';
3411
3412     if ($snmp) {
3413         my $systemStateEventLogStatus = '1.3.6.1.4.1.674.10892.1.200.10.1.41.1';
3414         my $result = $snmp_session->get_request(-varbindlist => [$systemStateEventLogStatus]);
3415         if (!defined $result) {
3416             my $msg = sprintf 'SNMP ERROR [esmhealth]: %s',
3417               $snmp_session->error;
3418             report('other', $msg, $E_UNKNOWN);
3419         }
3420         $health = $snmp_status{$result->{$systemStateEventLogStatus}};
3421     }
3422     else {
3423         foreach (@{ run_command("$omreport $omopt_system esmlog -fmt ssv") }) {
3424             if (m/\A Health;(.+) \z/xms) {
3425                 $health = $1;
3426                 chop $health;
3427                 last;
3428             }
3429         }
3430     }
3431
3432     # If the overall health of the ESM log is other than "Ok", the
3433     # fill grade of the log is more than 80% and the log should be
3434     # cleared
3435     if ($health eq 'Ok') {
3436         my $msg = sprintf 'ESM log health is Ok (less than 80%% full)';
3437         report('other', $msg, $E_OK);
3438     }
3439     elsif ($health eq 'Critical') {
3440         my $msg = sprintf 'ESM log is 100%% full';
3441         report('other', $msg, $status2nagios{$health});
3442     }
3443     else {
3444         my $msg = sprintf 'ESM log is more than 80%% full';
3445         report('other', $msg, $status2nagios{$health});
3446     }
3447
3448     return;
3449 }
3450
3451 #-----------------------------------------
3452 # CHASSIS: Check ESM log
3453 #-----------------------------------------
3454 sub check_esmlog {
3455     my @output = ();
3456
3457     if ($snmp) {
3458         my %esm_oid
3459           = (
3460              '1.3.6.1.4.1.674.10892.1.300.40.1.7.1'  => 'eventLogSeverityStatus',
3461             );
3462         my $result = $snmp_session->get_entries(-columns => [keys %esm_oid]);
3463
3464         # No entries is OK
3465         return if !defined $result;
3466
3467         @output = @{ get_snmp_output($result, \%esm_oid) };
3468         foreach my $out (@output) {
3469             ++$count{esm}{$snmp_status{$out->{eventLogSeverityStatus}}};
3470         }
3471     }
3472     else {
3473         @output = @{ run_omreport("$omopt_system esmlog") };
3474         foreach my $out (@output) {
3475             ++$count{esm}{$out->{Severity}};
3476         }
3477     }
3478
3479     # Create error messages and set exit value if appropriate
3480     my $err = 0;
3481     if ($count{esm}{'Critical'} > 0)        { $err = $E_CRITICAL; }
3482     elsif ($count{esm}{'Non-Critical'} > 0) { $err = $E_WARNING;  }
3483
3484     my $msg = sprintf 'ESM log content: %d critical, %d non-critical, %d ok',
3485       $count{esm}{'Critical'}, $count{esm}{'Non-Critical'}, $count{esm}{'Ok'};
3486     report('other', $msg, $err);
3487
3488     return;
3489 }
3490
3491 #
3492 # Handy function for checking all storage components
3493 #
3494 sub check_storage {
3495     check_controllers();
3496     check_physical_disks();
3497     check_virtual_disks();
3498     check_cache_battery();
3499     check_connectors();
3500     check_enclosures();
3501     check_enclosure_fans();
3502     check_enclosure_pwr();
3503     check_enclosure_temp();
3504     check_enclosure_emms();
3505     return;
3506 }
3507
3508
3509
3510 #---------------------------------------------------------------------
3511 # Info functions
3512 #---------------------------------------------------------------------
3513
3514 #
3515 # Fetch output from 'omreport chassis info', put in sysinfo hash
3516 #
3517 sub get_omreport_chassis_info {
3518     if (open my $INFO, '-|', "$omreport $omopt_chassis info -fmt ssv") {
3519         my @lines = <$INFO>;
3520         close $INFO;
3521         foreach (@lines) {
3522             next if !m/\A (Chassis\sModel|Chassis\sService\sTag|Model|Service\sTag)/xms;
3523             my ($key, $val) = split /;/xms;
3524             $key =~ s{\s+\z}{}xms; # remove trailing whitespace
3525             $val =~ s{\s+\z}{}xms; # remove trailing whitespace
3526             if ($key eq 'Chassis Model' or $key eq 'Model') {
3527                 $sysinfo{model}  = $val;
3528             }
3529             if ($key eq 'Chassis Service Tag' or $key eq 'Service Tag') {
3530                 $sysinfo{serial} = $val;
3531             }
3532         }
3533     }
3534     return;
3535 }
3536
3537 #
3538 # Fetch output from 'omreport chassis bios', put in sysinfo hash
3539 #
3540 sub get_omreport_chassis_bios {
3541     if (open my $BIOS, '-|', "$omreport $omopt_chassis bios -fmt ssv") {
3542         my @lines = <$BIOS>;
3543         close $BIOS;
3544         foreach (@lines) {
3545             next if !m/;/xms;
3546             my ($key, $val) = split /;/xms;
3547             $key =~ s{\s+\z}{}xms; # remove trailing whitespace
3548             $val =~ s{\s+\z}{}xms; # remove trailing whitespace
3549             $sysinfo{bios}     = $val if $key eq 'Version';
3550             $sysinfo{biosdate} = $val if $key eq 'Release Date';
3551         }
3552     }
3553     return;
3554 }
3555
3556 #
3557 # Fetch output from 'omreport system operatingsystem', put in sysinfo hash
3558 #
3559 sub get_omreport_system_operatingsystem {
3560     if (open my $VER, '-|', "$omreport $omopt_system operatingsystem -fmt ssv") {
3561         my @lines = <$VER>;
3562         close $VER;
3563         foreach (@lines) {
3564             next if !m/;/xms;
3565             my ($key, $val) = split /;/xms;
3566             $key =~ s{\s+\z}{}xms; # remove trailing whitespace
3567             $val =~ s{\s+\z}{}xms; # remove trailing whitespace
3568             if ($key eq 'Operating System') {
3569                 $sysinfo{osname} = $val;
3570             }
3571             elsif ($key eq 'Operating System Version') {
3572                 $sysinfo{osver}  = $val;
3573             }
3574         }
3575     }
3576     return;
3577 }
3578
3579 #
3580 # Fetch output from 'omreport about', put in sysinfo hash
3581 #
3582 sub get_omreport_about {
3583     if (open my $OM, '-|', "$omreport about -fmt ssv") {
3584         my @lines = <$OM>;
3585         close $OM;
3586         foreach (@lines) {
3587             if (m/\A Version;(.+) \z/xms) {
3588                 $sysinfo{om} = $1;
3589                 chomp $sysinfo{om};
3590             }
3591         }
3592     }
3593     return;
3594 }
3595
3596 #
3597 # Fetch chassis info via SNMP, put in sysinfo hash
3598 #
3599 sub get_snmp_chassis_info {
3600     my %chassis_oid
3601       = (
3602          '1.3.6.1.4.1.674.10892.1.300.10.1.9.1'  => 'chassisModelName',
3603          '1.3.6.1.4.1.674.10892.1.300.10.1.11.1' => 'chassisServiceTagName',
3604         );
3605
3606     my $chassisInformationTable = '1.3.6.1.4.1.674.10892.1.300.10.1';
3607     my $result = $snmp_session->get_table(-baseoid => $chassisInformationTable);
3608
3609     if (defined $result) {
3610         foreach my $oid (keys %{ $result }) {
3611             if (exists $chassis_oid{$oid} and $chassis_oid{$oid} eq 'chassisModelName') {
3612                 $sysinfo{model} = $result->{$oid};
3613                 $sysinfo{model} =~ s{\s+\z}{}xms; # remove trailing whitespace
3614             }
3615             elsif (exists $chassis_oid{$oid} and $chassis_oid{$oid} eq 'chassisServiceTagName') {
3616                 $sysinfo{serial} = $result->{$oid};
3617             }
3618         }
3619     }
3620     else {
3621         my $msg = sprintf 'SNMP ERROR getting chassis info: %s',
3622           $snmp_session->error;
3623         report('other', $msg, $E_UNKNOWN);
3624     }
3625     return;
3626 }
3627
3628 #
3629 # Fetch BIOS info via SNMP, put in sysinfo hash
3630 #
3631 sub get_snmp_chassis_bios {
3632     my %bios_oid
3633       = (
3634          '1.3.6.1.4.1.674.10892.1.300.50.1.7.1.1' => 'systemBIOSReleaseDateName',
3635          '1.3.6.1.4.1.674.10892.1.300.50.1.8.1.1' => 'systemBIOSVersionName',
3636         );
3637
3638     my $systemBIOSTable = '1.3.6.1.4.1.674.10892.1.300.50.1';
3639     my $result = $snmp_session->get_table(-baseoid => $systemBIOSTable);
3640
3641     if (defined $result) {
3642         foreach my $oid (keys %{ $result }) {
3643             if (exists $bios_oid{$oid} and $bios_oid{$oid} eq 'systemBIOSReleaseDateName') {
3644                 $sysinfo{biosdate} = $result->{$oid};
3645                 $sysinfo{biosdate} =~ s{\A (\d{4})(\d{2})(\d{2}).*}{$2/$3/$1}xms;
3646             }
3647             elsif (exists $bios_oid{$oid} and $bios_oid{$oid} eq 'systemBIOSVersionName') {
3648                 $sysinfo{bios} = $result->{$oid};
3649             }
3650         }
3651     }
3652     else {
3653         my $msg = sprintf 'SNMP ERROR getting BIOS info: %s',
3654           $snmp_session->error;
3655         report('other', $msg, $E_UNKNOWN);
3656     }
3657     return;
3658 }
3659
3660 #
3661 # Fetch OS info via SNMP, put in sysinfo hash
3662 #
3663 sub get_snmp_system_operatingsystem {
3664     my %os_oid
3665       = (
3666          '1.3.6.1.4.1.674.10892.1.400.10.1.6.1' => 'operatingSystemOperatingSystemName',
3667          '1.3.6.1.4.1.674.10892.1.400.10.1.7.1' => 'operatingSystemOperatingSystemVersionName',
3668         );
3669
3670     my $operatingSystemTable = '1.3.6.1.4.1.674.10892.1.400.10.1';
3671     my $result = $snmp_session->get_table(-baseoid => $operatingSystemTable);
3672
3673     if (defined $result) {
3674         foreach my $oid (keys %{ $result }) {
3675             if (exists $os_oid{$oid} and $os_oid{$oid} eq 'operatingSystemOperatingSystemName') {
3676                 $sysinfo{osname} = ($result->{$oid});
3677             }
3678             elsif (exists $os_oid{$oid} and $os_oid{$oid} eq 'operatingSystemOperatingSystemVersionName') {
3679                 $sysinfo{osver} = $result->{$oid};
3680             }
3681         }
3682     }
3683     else {
3684         my $msg = sprintf 'SNMP ERROR getting OS info: %s',
3685           $snmp_session->error;
3686         report('other', $msg, $E_UNKNOWN);
3687     }
3688     return;
3689 }
3690
3691 #
3692 # Fetch OMSA version via SNMP, put in sysinfo hash
3693 #
3694 sub get_snmp_about {
3695     my %omsa_oid
3696       = (
3697          '1.3.6.1.4.1.674.10892.1.100.10.0' => 'systemManagementSoftwareGlobalVersionName',
3698         );
3699     my $systemManagementSoftwareGroup = '1.3.6.1.4.1.674.10892.1.100';
3700     my $result = $snmp_session->get_table(-baseoid => $systemManagementSoftwareGroup);
3701     if (defined $result) {
3702         foreach my $oid (keys %{ $result }) {
3703             if (exists $omsa_oid{$oid} and $omsa_oid{$oid} eq 'systemManagementSoftwareGlobalVersionName') {
3704                 $sysinfo{om} = ($result->{$oid});
3705             }
3706         }
3707     }
3708     else {
3709         my $msg = sprintf 'SNMP ERROR getting OMSA info: %s',
3710           $snmp_session->error;
3711         report('other', $msg, $E_UNKNOWN);
3712     }
3713     return;
3714 }
3715
3716 #
3717 # Collects some information about the system
3718 #
3719 sub get_sysinfo
3720 {
3721     # Get system model and serial number
3722     $snmp ? get_snmp_chassis_info() : get_omreport_chassis_info();
3723
3724     # Get BIOS information. Only if needed
3725     if ( $opt{okinfo} >= 1
3726          or $opt{debug}
3727          or (defined $opt{postmsg} and $opt{postmsg} =~ m/[%][bd]/xms) ) {
3728         $snmp ? get_snmp_chassis_bios() : get_omreport_chassis_bios();
3729     }
3730
3731     # Get OMSA information. Only if needed
3732     if ($opt{okinfo} >= 3 or $opt{debug}) {
3733         $snmp ? get_snmp_about() : get_omreport_about();
3734     }
3735
3736     # Return now if debug
3737     return if $opt{debug};
3738
3739     # Get OS information. Only if needed
3740     if (defined $opt{postmsg} and $opt{postmsg} =~ m/[%][or]/xms) {
3741         $snmp ? get_snmp_system_operatingsystem() : get_omreport_system_operatingsystem();
3742     }
3743
3744     return;
3745 }
3746
3747
3748 # Helper function for running omreport when the results are strictly
3749 # name=value pairs.
3750 sub run_omreport_info {
3751     my $command = shift;
3752     my %output  = ();
3753     my @keys    = ();
3754
3755     # Run omreport and fetch output
3756     my $rawtext = slurp_command("$omreport $command -fmt ssv 2>&1");
3757
3758     # Parse output, store in array
3759     for ((split /\n/xms, $rawtext)) {
3760         if (m/\A Error/xms) {
3761             my $msg = "Problem running 'omreport $command': $_";
3762             report('other', $msg, $E_UNKNOWN);
3763         }
3764         next if !m/;/xms;  # ignore lines with less than two fields
3765         my @vals = split m/;/xms;
3766         $output{$vals[0]} = $vals[1];
3767     }
3768
3769     # Finally, return the collected information
3770     return \%output;
3771 }
3772
3773 # Get various firmware information (BMC, RAC)
3774 sub get_firmware_info {
3775     my @snmp_output = ();
3776     my %nrpe_output = ();
3777
3778     if ($snmp) {
3779         my %fw_oid
3780           = (
3781              '1.3.6.1.4.1.674.10892.1.300.60.1.7.1'  => 'firmwareType',
3782              '1.3.6.1.4.1.674.10892.1.300.60.1.8.1'  => 'firmwareTypeName',
3783              '1.3.6.1.4.1.674.10892.1.300.60.1.11.1' => 'firmwareVersionName',
3784             );
3785
3786         my $firmwareTable = '1.3.6.1.4.1.674.10892.1.300.60.1';
3787         my $result = $snmp_session->get_table(-baseoid => $firmwareTable);
3788
3789         # Some don't have this OID, this is ok
3790         if (!defined $result) {
3791             return;
3792         }
3793
3794         @snmp_output = @{ get_snmp_output($result, \%fw_oid) };
3795     }
3796     else {
3797         %nrpe_output = %{ run_omreport_info("$omopt_chassis info") };
3798     }
3799
3800     my %fw_type  # Firmware types
3801       = (
3802          1  => 'other',                              # other than following values
3803          2  => 'unknown',                            # unknown
3804          3  => 'systemBIOS',                         # System BIOS
3805          4  => 'embeddedSystemManagementController', # Embedded System Management Controller
3806          5  => 'powerSupplyParallelingBoard',        # Power Supply Paralleling Board
3807          6  => 'systemBackPlane',                    # System (Primary) Backplane
3808          7  => 'powerVault2XXSKernel',               # PowerVault 2XXS Kernel
3809          8  => 'powerVault2XXSApplication',          # PowerVault 2XXS Application
3810          9  => 'frontPanel',                         # Front Panel Controller
3811          10 => 'baseboardManagementController',      # Baseboard Management Controller
3812          11 => 'hotPlugPCI',                         # Hot Plug PCI Controller
3813          12 => 'sensorData',                         # Sensor Data Records
3814          13 => 'peripheralBay',                      # Peripheral Bay Backplane
3815          14 => 'secondaryBackPlane',                 # Secondary Backplane for ESM 2 systems
3816          15 => 'secondaryBackPlaneESM3And4',         # Secondary Backplane for ESM 3 and 4 systems
3817          16 => 'rac',                                # Remote Access Controller
3818          17 => 'imc'                                 # Integrated Management Controller
3819         );
3820
3821
3822     if ($snmp) {
3823         foreach my $out (@snmp_output) {
3824             if ($fw_type{$out->{firmwareType}} eq 'baseboardManagementController') {
3825                 $sysinfo{'bmc'} = 1;
3826                 $sysinfo{'bmc_fw'} = $out->{firmwareVersionName};
3827             }
3828             elsif ($fw_type{$out->{firmwareType}} =~ m{\A rac|imc \z}xms) {
3829                 my $name = $out->{firmwareTypeName}; $name =~ s/\s//gxms;
3830                 $sysinfo{'rac'} = 1;
3831                 $sysinfo{'rac_name'} = $name;
3832                 $sysinfo{'rac_fw'} = $out->{firmwareVersionName};
3833             }
3834         }
3835     }
3836     else {
3837         foreach my $key (keys %nrpe_output) {
3838             next if !defined $nrpe_output{$key};
3839             if ($key eq 'BMC Version' or $key eq 'Baseboard Management Controller Version') {
3840                 $sysinfo{'bmc'} = 1;
3841                 $sysinfo{'bmc_fw'} = $nrpe_output{$key};
3842             }
3843             elsif ($key =~ m{\A (i?DRAC)\s*(\d?)\s+Version}xms) {
3844                 my $name = "$1$2";
3845                 $sysinfo{'rac'} = 1;
3846                 $sysinfo{'rac_fw'} = $nrpe_output{$key};
3847                 $sysinfo{'rac_name'} = $name;
3848             }
3849         }
3850     }
3851
3852     return;
3853 }
3854
3855
3856
3857 #=====================================================================
3858 # Main program
3859 #=====================================================================
3860
3861 # Here we do the actual checking of components
3862 # Check global status if applicable
3863 if ($global) {
3864     $globalstatus = check_global();
3865 }
3866
3867 # Do multiple selected checks
3868 if ($check{storage})     { check_storage();       }
3869 if ($check{memory})      { check_memory();        }
3870 if ($check{fans})        { check_fans();          }
3871 if ($check{power})       { check_powersupplies(); }
3872 if ($check{temp})        { check_temperatures();  }
3873 if ($check{cpu})         { check_processors();    }
3874 if ($check{voltage})     { check_volts();         }
3875 if ($check{batteries})   { check_batteries();     }
3876 if ($check{amperage})    { check_pwrmonitoring(); }
3877 if ($check{intrusion})   { check_intrusion();     }
3878 if ($check{alertlog})    { check_alertlog();      }
3879 if ($check{esmlog})      { check_esmlog();        }
3880 if ($check{esmhealth})   { check_esmlog_health(); }
3881
3882
3883 #---------------------------------------------------------------------
3884 # Finish up
3885 #---------------------------------------------------------------------
3886
3887 # Counter variable
3888 %nagios_alert_count
3889   = (
3890      'OK'       => 0,
3891      'WARNING'  => 0,
3892      'CRITICAL' => 0,
3893      'UNKNOWN'  => 0,
3894     );
3895
3896 # Get system information
3897 get_sysinfo();
3898
3899 # Get firmware info if requested via option
3900 if ($opt{okinfo} >= 1) {
3901     get_firmware_info();
3902 }
3903
3904 # Close SNMP session
3905 if ($snmp) {
3906     $snmp_session->close;
3907 }
3908
3909 # Print messages
3910 if ($opt{debug}) {
3911     print "   System:      $sysinfo{model}\n";
3912     print "   ServiceTag:  $sysinfo{serial}";
3913     print q{ } x (25 - length $sysinfo{serial}), "OMSA version:    $sysinfo{om}\n";
3914     print "   BIOS/date:   $sysinfo{bios} $sysinfo{biosdate}";
3915     print q{ } x (25 - length "$sysinfo{bios} $sysinfo{biosdate}"), "Plugin version:  $VERSION\n";
3916     if ($#report_storage >= 0) {
3917         print "-----------------------------------------------------------------------------\n";
3918         print "   Storage Components                                                        \n";
3919         print "=============================================================================\n";
3920         print "  STATE  |    ID    |  MESSAGE TEXT                                          \n";
3921         print "---------+----------+--------------------------------------------------------\n";
3922         foreach (@report_storage) {
3923             my ($msg, $level, $nexus) = @{$_};
3924             print q{ } x (8 - length $reverse_exitcode{$level}) . "$reverse_exitcode{$level} | "
3925               . q{ } x (8 - length $nexus) . "$nexus | $msg\n";
3926             $nagios_alert_count{$reverse_exitcode{$level}}++;
3927         }
3928     }
3929     if ($#report_chassis >= 0) {
3930         print "-----------------------------------------------------------------------------\n";
3931         print "   Chassis Components                                                        \n";
3932         print "=============================================================================\n";
3933         print "  STATE  |  ID  |  MESSAGE TEXT                                              \n";
3934         print "---------+------+------------------------------------------------------------\n";
3935         foreach (@report_chassis) {
3936             my ($msg, $level, $nexus) = @{$_};
3937             print q{ } x (8 - length $reverse_exitcode{$level}) . "$reverse_exitcode{$level} | "
3938               . q{ } x (4 - length $nexus) . "$nexus | $msg\n";
3939             $nagios_alert_count{$reverse_exitcode{$level}}++;
3940         }
3941     }
3942     if ($#report_other >= 0) {
3943         print "-----------------------------------------------------------------------------\n";
3944         print "   Other messages                                                            \n";
3945         print "=============================================================================\n";
3946         print "  STATE  |  MESSAGE TEXT                                                     \n";
3947         print "---------+-------------------------------------------------------------------\n";
3948         foreach (@report_other) {
3949             my ($msg, $level, $nexus) = @{$_};
3950             print q{ } x (8 - length $reverse_exitcode{$level}) . "$reverse_exitcode{$level} | $msg\n";
3951             $nagios_alert_count{$reverse_exitcode{$level}}++;
3952         }
3953     }
3954 }
3955 else {
3956     my $c = 0;  # counter to determine linebreaks
3957
3958     # Run through each message, sorted by severity level
3959   ALERT:
3960     foreach (sort {$a->[1] < $b->[1]} (@report_storage, @report_chassis, @report_other)) {
3961         my ($msg, $level, $nexus) = @{ $_ };
3962         next ALERT if $level == $E_OK;
3963
3964         if (defined $opt{only}) {
3965             # If user wants only critical alerts
3966             next ALERT if ($opt{only} eq 'critical' and $level == $E_WARNING);
3967
3968             # If user wants only warning alerts
3969             next ALERT if ($opt{only} eq 'warning' and $level == $E_CRITICAL);
3970         }
3971
3972         # Prefix with service tag if specified with option '-i|--info'
3973         if ($opt{info}) {
3974             if (defined $opt{htmlinfo}) {
3975                 $msg = '[<a href="' . warranty_url($sysinfo{serial})
3976                   . "\">$sysinfo{serial}</a>] " . $msg;
3977             }
3978             else {
3979                 $msg = "[$sysinfo{serial}] " . $msg;
3980             }
3981         }
3982
3983         # Prefix with nagios level if specified with option '--state'
3984         $msg = $reverse_exitcode{$level} . ": $msg" if $opt{state};
3985
3986         # Prefix with one-letter nagios level if specified with option '--short-state'
3987         $msg = (substr $reverse_exitcode{$level}, 0, 1) . ": $msg" if $opt{shortstate};
3988
3989         ($c++ == 0) ? print $msg : print $linebreak, $msg;
3990
3991         $nagios_alert_count{$reverse_exitcode{$level}}++;
3992     }
3993 }
3994
3995 # Determine our exit code
3996 $exit_code = $E_OK;
3997 $exit_code = $E_UNKNOWN  if $nagios_alert_count{'UNKNOWN'} > 0;
3998 $exit_code = $E_WARNING  if $nagios_alert_count{'WARNING'} > 0;
3999 $exit_code = $E_CRITICAL if $nagios_alert_count{'CRITICAL'} > 0;
4000
4001 # Global status via SNMP.. extra safety check
4002 if ($globalstatus != $E_OK && $exit_code == $E_OK && !defined $opt{only}) {
4003     print "OOPS! Something is wrong with this server, but I don't know what. ";
4004     print "The global system health status is $reverse_exitcode{$globalstatus}, ";
4005     print "but every component check is OK. This may be a bug in the Nagios plugin, ";
4006     print "please file a bug report.\n";
4007     exit $E_UNKNOWN;
4008 }
4009
4010 # Print OK message
4011 if ($exit_code == $E_OK && defined $opt{only} && $opt{only} !~ m{\A critical|warning|chassis \z}xms && !$opt{debug}) {
4012     my %okmsg
4013       = ( 'storage'     => "STORAGE OK - $count{pdisk} physical drives, $count{vdisk} logical drives",
4014           'fans'        => $count{fan} == 0 && $blade ? 'OK - blade system with no fan probes' : "FANS OK - $count{fan} fan probes checked",
4015           'temp'        => "TEMPERATURES OK - $count{temp} temperature probes checked",
4016           'memory'      => "MEMORY OK - $count{dimm} memory modules checked",
4017           'power'       => $count{power} == 0 ? 'OK - no instrumented power supplies found' : "POWER OK - $count{power} power supplies checked",
4018           'cpu'         => "PROCESSORS OK - $count{cpu} processors checked",
4019           'voltage'     => "VOLTAGE OK - $count{volt} voltage probes checked",
4020           'batteries'   => $count{bat} == 0 ? 'OK - no batteries found' : "BATTERIES OK - $count{bat} batteries checked",
4021           'amperage'    => $count{amp} == 0 ? 'OK - no power monitoring probes found' : "AMPERAGE OK - $count{amp} amperage (power monitoring) probes checked",
4022           'intrusion'   => $count{intr} == 0 ? 'OK - no intrusion detection probes found' : "INTRUSION OK - $count{intr} intrusion detection probes checked",
4023           'alertlog'    => $snmp ? 'OK - not supported via snmp' : "OK - Alert Log content: $count{alert}{Ok} ok, $count{alert}{'Non-Critical'} warning and $count{alert}{Critical} critical",
4024           'esmlog'      => "OK - ESM Log content: $count{esm}{Ok} ok, $count{esm}{'Non-Critical'} warning and $count{esm}{Critical} critical",
4025           'esmhealth'   => "ESM LOG OK - less than 80% used",
4026         );
4027
4028     print $okmsg{$opt{only}};
4029 }
4030 elsif ($exit_code == $E_OK && !$opt{debug}) {
4031     if (defined $opt{htmlinfo}) {
4032         printf q{OK - System: '<a href="%s">%s</a>', SN: '<a href="%s">%s</a>', hardware working fine},
4033           documentation_url($sysinfo{model}), $sysinfo{model},
4034             warranty_url($sysinfo{serial}), $sysinfo{serial};
4035     }
4036     else {
4037         printf q{OK - System: '%s', SN: '%s', hardware working fine},
4038           $sysinfo{model}, $sysinfo{serial};
4039     }
4040
4041     if ($check{storage}) {
4042         printf ', %d logical drives, %d physical drives',
4043           $count{vdisk}, $count{pdisk};
4044     }
4045     else {
4046         print ', not checking storage';
4047     }
4048
4049     if ($opt{okinfo} >= 1) {
4050         print $linebreak;
4051         printf q{----- BIOS='%s %s'}, $sysinfo{bios}, $sysinfo{biosdate};
4052
4053         if ($sysinfo{rac}) {
4054             printf q{, %s='%s'}, $sysinfo{rac_name}, $sysinfo{rac_fw};
4055         }
4056         if ($sysinfo{bmc}) {
4057             printf q{, BMC='%s'}, $sysinfo{bmc_fw};
4058         }
4059     }
4060
4061     if ($opt{okinfo} >= 2) {
4062         if ($check{storage}) {
4063             my @storageprint = ();
4064             foreach my $id (sort keys %{ $sysinfo{controller} }) {
4065                 chomp $sysinfo{controller}{$id}{driver};
4066                 push @storageprint, sprintf q{----- CTRL %s (%s): FW='%s', DR='%s'},
4067                   $sysinfo{controller}{$id}{id}, $sysinfo{controller}{$id}{name},
4068                     $sysinfo{controller}{$id}{firmware}, $sysinfo{controller}{$id}{driver};
4069             }
4070             foreach my $id (sort keys %{ $sysinfo{enclosure} }) {
4071                 push @storageprint, sprintf q{----- ENCL %s (%s): FW='%s'},
4072                   $sysinfo{enclosure}{$id}->{id}, $sysinfo{enclosure}{$id}->{name},
4073                     $sysinfo{enclosure}{$id}->{firmware};
4074             }
4075
4076             # print stuff
4077             foreach my $line (@storageprint) {
4078                 print $linebreak, $line;
4079             }
4080         }
4081     }
4082
4083     if ($opt{okinfo} >= 3) {
4084         print "$linebreak----- OpenManage Server Administrator (OMSA) version: '$sysinfo{om}'";
4085     }
4086
4087 }
4088 else {
4089     if ($opt{extinfo}) {
4090         print $linebreak;
4091         if (defined $opt{htmlinfo}) {
4092             printf '------ SYSTEM: <a href="%s">%s</a>, SN: <a href="%s">%s</a>',
4093               documentation_url($sysinfo{model}), $sysinfo{model},
4094                 warranty_url($sysinfo{serial}), $sysinfo{serial};
4095         }
4096         else {
4097             printf '------ SYSTEM: %s, SN: %s',
4098               $sysinfo{model}, $sysinfo{serial};
4099         }
4100     }
4101     if (defined $opt{postmsg}) {
4102         my $post = undef;
4103         if (-f $opt{postmsg}) {
4104             open my $POST, '<', $opt{postmsg}
4105               or ( print $linebreak
4106                    and print "ERROR: Couldn't open post message file $opt{postmsg}: $!\n"
4107                    and exit $E_UNKNOWN );
4108             $post = <$POST>;
4109             close $POST;
4110             chomp $post;
4111         }
4112         else {
4113             $post = $opt{postmsg};
4114         }
4115         if (defined $post) {
4116             print $linebreak;
4117             $post =~ s{[%]s}{$sysinfo{serial}}gxms;
4118             $post =~ s{[%]m}{$sysinfo{model}}gxms;
4119             $post =~ s{[%]b}{$sysinfo{bios}}gxms;
4120             $post =~ s{[%]d}{$sysinfo{biosdate}}gxms;
4121             $post =~ s{[%]o}{$sysinfo{osname}}gxms;
4122             $post =~ s{[%]r}{$sysinfo{osver}}gxms;
4123             $post =~ s{[%]p}{$count{pdisk}}gxms;
4124             $post =~ s{[%]l}{$count{vdisk}}gxms;
4125             $post =~ s{[%]n}{$linebreak}gxms;
4126             $post =~ s{[%]{2}}{%}gxms;
4127             print $post;
4128         }
4129     }
4130 }
4131
4132 # Print any perl warnings that have occured
4133 if (@perl_warnings) {
4134     foreach (@perl_warnings) {
4135         chop @$_;
4136         print "${linebreak}INTERNAL ERROR: @$_";
4137     }
4138     $exit_code = $E_UNKNOWN;
4139 }
4140
4141 # Reset the WARN signal
4142 $SIG{__WARN__} = $original_sigwarn;
4143
4144 # Print performance data
4145 if (defined $opt{perfdata} && !$opt{debug} && %perfdata) {
4146     my $lb = $opt{perfdata} eq 'multiline' ? "\n" : q{ };  # line break for perfdata
4147     print q{|};
4148
4149     sub perfdata {
4150         my %order
4151           = (
4152              fan       => 0,
4153              pwr       => 1,
4154              temp      => 2,
4155              enclosure => 3,
4156             );
4157         return ($order{(split /_/, $a, 2)[0]} cmp $order{(split /_/, $b, 2)[0]}) || $a cmp $b;
4158     }
4159
4160     print join $lb, map { "'$_'=$perfdata{$_}" } sort perfdata keys %perfdata;
4161 }
4162
4163 # Print a linebreak at the end
4164 print "\n" if !$opt{debug};
4165
4166 # Exit with proper exit code
4167 exit $exit_code;