Generated static dependecies

[u/mrichter/AliRoot.git] / STEER / AOD / CMakeLists.txt

# **************************************************************************
# * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
# *                                                                        *
# * Author: The ALICE Off-line Project.                                    *
# * Contributors are mentioned in the code where appropriate.              *
# *                                                                        *
# * Permission to use, copy, modify and distribute this software and its   *
# * documentation strictly for non-commercial purposes is hereby granted   *
# * without fee, provided that the above copyright notice appears in all   *
# * copies and that both the copyright notice and this permission notice   *
# * appear in the supporting documentation. The authors make no claims     *
# * about the suitability of this software for any purpose. It is          *
# * provided "as is" without express or implied warranty.                  *
# **************************************************************************

# Module
set (MODULE AOD)

# Module include folders
include_directories(${AliRoot_SOURCE_DIR}/STEER/${MODULE})

# Additional include directories - alphabetical order except ROOT
include_directories(${ROOT_INCLUDE_DIRS}
                    ${AliRoot_SOURCE_DIR}/STEER/ESD
                    ${AliRoot_SOURCE_DIR}/STEER/STEERBase
                   )

# Sources - alphabetical order
set(SRCS
    AliAODBranchReplicator.cxx
    AliAODCaloCells.cxx
    AliAODCaloCluster.cxx
    AliAODCaloTrigger.cxx
    AliAODcascade.cxx
    AliAODCluster.cxx
    AliAODDiJet.cxx
    AliAODDimuon.cxx
    AliAODEvent.cxx
    AliAODExtension.cxx
    AliAODFmdCluster.cxx
    AliAODHandler.cxx
    AliAODHeader.cxx
    AliAODHMPIDrings.cxx
    AliAODInputHandler.cxx
    AliAODJet.cxx
    AliAODJetEventBackground.cxx
    AliAODMCHeader.cxx
    AliAODMCParticle.cxx
    AliAODPhoton.cxx
    AliAODPid.cxx
    AliAODpidUtil.cxx
    AliAODPmdCluster.cxx
    AliAODPWG4ParticleCorrelation.cxx
    AliAODPWG4Particle.cxx
    AliAODRecoDecay.cxx
    AliAODRedCov.cxx
    AliAODTagCreator.cxx
    AliAODTrack.cxx
    AliAODTracklets.cxx
    AliAODTrdTrack.cxx
    AliAODTrdTracklet.cxx
    AliAODTZERO.cxx
    AliAODv0.cxx
    AliAODVertex.cxx
    AliAODVZERO.cxx
    AliAODZDC.cxx
    AliNanoAODHeader.cxx
    AliNanoAODStorage.cxx
    AliNanoAODTrackMapping.cxx
   )

# Sources from headers
string(REPLACE ".cxx" ".h" HDRS "${SRCS}")

# Generate the dictionary
# It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
get_directory_property(incdirs INCLUDE_DIRECTORIES)
generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")

# ROOT and other AliRoot depencies
# Used to create the root maps and for the actual linking
set(ROOT_DEPENDENCIES Core EG Geom Hist MathCore Matrix Net Physics RIO Tree)
set(ALIROOT_DEPENDENCIES ESD STEERBase)

# Generate the ROOT map
# Dependecies
set(LIBDEPS ${ROOT_DEPENDENCIES} ${ALIROOT_DEPENDENCIES})
generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")

# Create an object to be reused in case of static libraries 
# Otherwise the sources will be compiled twice
add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
# Add a library to the project using the object
add_library(${MODULE} SHARED $<TARGET_OBJECTS:AOD-object>)

# library dependecies
target_link_libraries(${MODULE} ${ROOT_DEPENDENCIES} ${ALIROOT_DEPENDENCIES})

# Additional compilation flags
set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS "-O -g -fPIC")

# System dependent: Modify the way the library is build
if(${CMAKE_SYSTEM} MATCHES Darwin)
    set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
endif(${CMAKE_SYSTEM} MATCHES Darwin)

# Installation
install(TARGETS ${MODULE} 
  ARCHIVE DESTINATION lib
  LIBRARY DESTINATION lib)
install(FILES ${HDRS} DESTINATION include)

# Static version if DA enabled
if(ALIROOT_STATIC)
    add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:AOD-object>)
    set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
    
    # list of shared dependencies / the name of the variable containing the list of static ones
    generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")

    target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root RootExtra)
    set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")

    # Installation
    install(TARGETS ${MODULE}-static
            ARCHIVE DESTINATION lib
            LIBRARY DESTINATION lib)
endif(ALIROOT_STATIC)