ACORDE/ACORDEbase/CMakeLists.txt

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # Module
  17 set(MODULE ACORDEbase)
  18
  19 # Module include folder
  20 include_directories(${AliRoot_SOURCE_DIR}/ACORDE/${MODULE})
  21
  22 # Additional include folders in alphabetical order except ROOT
  23 include_directories(${ROOT_INCLUDE_DIRS}
  24                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
  25                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatarec
  26                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatasim
  27                     ${AliRoot_SOURCE_DIR}/STEER/CDB
  28                     ${AliRoot_SOURCE_DIR}/STEER/ESD
  29                     ${AliRoot_SOURCE_DIR}/STEER/STEER
  30                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
  31                    )
  32
  33 # Sources in alphabetical order
  34 set(SRCS
  35     AliACORDEAlign.cxx
  36     AliACORDECalibData.cxx
  37     AliACORDEConstants.cxx
  38     AliACORDEDataDCS.cxx
  39     AliACORDEdigit.cxx
  40     AliACORDELoader.cxx
  41     AliACORDEPreprocessor.cxx
  42     AliACORDEQAChecker.cxx
  43     AliACORDERawReader.cxx
  44     AliACORDERawStream.cxx
  45     AliGenACORDE.cxx
  46    )
  47
  48 # Headers from sources
  49 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
  50
  51 # Generate the dictionary
  52 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
  53 get_directory_property(incdirs INCLUDE_DIRECTORIES)
  54 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
  55
  56 # Generate the ROOT map
  57 # Dependecies
  58 set(LIBDEPS STEERBase STEER CDB ESD RAWDatabase RAWDatarec RAWDatasim)
  59 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
  60
  61 # Create an object to be reused in case of static libraries
  62 # Otherwise the sources will be compiled twice
  63 add_library(ACORDEbase-object OBJECT ${SRCS} G__${MODULE}.cxx)
  64 # Add a library to the project using the object
  65 add_library(ACORDEbase SHARED $<TARGET_OBJECTS:ACORDEbase-object>)
  66 target_link_libraries(ACORDEbase STEERBase STEER CDB ESD RAWDatabase RAWDatarec RAWDatasim)
  67
  68 # Additional compilation flags for the object
  69 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS "-fPIC -O -g")
  70
  71 # System dependent: Modify the way the library is build
  72 if(${CMAKE_SYSTEM} MATCHES Darwin)
  73     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
  74 endif(${CMAKE_SYSTEM} MATCHES Darwin)
  75
  76 # Installation
  77 install(TARGETS ${MODULE}
  78         ARCHIVE DESTINATION lib
  79         LIBRARY DESTINATION lib)
  80
  81 install(FILES ${HDRS} DESTINATION include)
  82
  83 # Static version if DA enabled
  84 if(ALIROOT_STATIC)
  85     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:ACORDEbase-object>)
  86     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
  87     target_link_libraries(${MODULE}-static STEERBase-static STEER-static ESD-static CDB-static RAWDatabase-static RAWDatarec-static RAWDatasim-static Root)
  88     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
  89
  90     # Installation
  91     install(TARGETS ${MODULE}-static
  92             ARCHIVE DESTINATION lib
  93             LIBRARY DESTINATION lib)
  94 endif(ALIROOT_STATIC)