EMCAL/EMCALUtils/CMakeLists.txt

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # Module
  17 set(MODULE EMCALUtils)
  18
  19 # Module include folder
  20 include_directories(${AliRoot_SOURCE_DIR}/EMCAL/${MODULE})
  21
  22 # Additional include folders in alphabetical order except ROOT
  23 include_directories(${ROOT_INCLUDE_DIRS}
  24                     ${AliRoot_SOURCE_DIR}/STEER/AOD
  25                     ${AliRoot_SOURCE_DIR}/STEER/ESD
  26                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
  27                    )
  28
  29 # Sources in alphabetical order
  30 set(SRCS
  31     AliEMCALCalibTimeDepCorrection.cxx
  32     AliEMCALEMCGeometry.cxx
  33     AliEMCALTriggerMapping.cxx
  34     AliEMCALTriggerMappingV1.cxx
  35     AliEMCALTriggerMappingV2.cxx
  36     AliEMCALGeometry.cxx
  37     AliEMCALGeoParams.cxx
  38     AliEMCALHistoUtilities.cxx
  39     AliEMCALPIDUtils.cxx
  40     AliEMCALRecoUtils.cxx
  41     AliEMCALShishKebabTrd1Module.cxx
  42     AliEMCALTrack.cxx
  43    )
  44
  45 # Headers from sources
  46 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
  47 set(HDRS ${HDRS} AliCaloConstants.h)
  48
  49 # Generate the dictionary
  50 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
  51 get_directory_property(incdirs INCLUDE_DIRECTORIES)
  52 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
  53
  54 set(ROOT_DEPENDENCIES)
  55 set(ALIROOT_DEPENDENCIES STEERBase ESD AOD)
  56
  57 # Generate the ROOT map
  58 # Dependecies
  59 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  60 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
  61
  62 # Create an object to be reused in case of static libraries
  63 # Otherwise the sources will be compiled twice
  64 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
  65 # Follow headers dependencies
  66 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
  67 # Add a library to the project using the object
  68 add_library(${MODULE} SHARED $<TARGET_OBJECTS:${MODULE}-object>)
  69 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  70
  71 # Setting the correct headers for the object as gathered from the dependencies
  72 target_include_directories(${MODULE}-object PUBLIC $<TARGET_PROPERTY:${MODULE},INCLUDE_DIRECTORIES>)
  73 set_target_properties(${MODULE}-object PROPERTIES COMPILE_DEFINITIONS $<TARGET_PROPERTY:${MODULE},COMPILE_DEFINITIONS>)
  74
  75 # Additional compilation flags
  76 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS " ")
  77 add_definitions(-D__EMCALUTIL__)
  78
  79 # System dependent: Modify the way the library is build
  80 if(${CMAKE_SYSTEM} MATCHES Darwin)
  81     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
  82 endif(${CMAKE_SYSTEM} MATCHES Darwin)
  83
  84 # Installation
  85 install(TARGETS ${MODULE}
  86         ARCHIVE DESTINATION lib
  87         LIBRARY DESTINATION lib)
  88
  89 install(FILES ${HDRS} DESTINATION include)
  90
  91 # Static version if DA enabled
  92 if(ALIROOT_STATIC)
  93     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:${MODULE}-object>)
  94     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
  95
  96     # list of shared dependencies / the name of the variable containing the list of static ones
  97     generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")
  98     target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root RootExtra)
  99
 100     # Public include folders that will be propagated to the dependecies
 101     target_include_directories(${MODULE}-static PUBLIC ${incdirs})
 102
 103     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
 104
 105     # Installation
 106     install(TARGETS ${MODULE}-static
 107             ARCHIVE DESTINATION lib
 108             LIBRARY DESTINATION lib)
 109 endif(ALIROOT_STATIC)