FMD/FMDbase/CMakeLists.txt

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # Module
  17 set(MODULE FMDbase)
  18
  19 # Module include folder
  20 include_directories(${AliRoot_SOURCE_DIR}/FMD/${MODULE})
  21
  22 # Additional include folders in alphabetical order except ROOT
  23 include_directories(${ROOT_INCLUDE_DIRS}
  24                     ${AliRoot_SOURCE_DIR}/FMD/FMDrec
  25                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
  26                     ${AliRoot_SOURCE_DIR}/STEER/CDB
  27                     ${AliRoot_SOURCE_DIR}/STEER/ESD
  28                     ${AliRoot_SOURCE_DIR}/STEER/STEER
  29                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
  30                    )
  31
  32 # Sources in alphabetical order
  33 set(SRCS
  34     AliFMD1.cxx
  35     AliFMD2.cxx
  36     AliFMD3.cxx
  37     AliFMDAltroMapping.cxx
  38     AliFMDBaseDigit.cxx
  39     AliFMDBoolMap.cxx
  40     AliFMDCalibGain.cxx
  41     AliFMDCalibPedestal.cxx
  42     AliFMDCalibSampleRate.cxx
  43     AliFMDCalibStripRange.cxx
  44     AliFMDDetector.cxx
  45     AliFMDDigit.cxx
  46     AliFMDGeometryBuilder.cxx
  47     AliFMDGeometry.cxx
  48     AliFMDIndex.cxx
  49     AliFMDParameters.cxx
  50     AliFMDPreprocessor.cxx
  51     AliFMDQAChecker.cxx
  52     AliFMDRing.cxx
  53     AliFMDSDigit.cxx
  54     AliFMDSurveyToAlignObjs.cxx
  55     AliFMDUShortMap.cxx
  56    )
  57
  58 # Headers from sources
  59 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
  60 set(HDRS ${HDRS} AliFMDCalibFwd.h)
  61
  62 # Generate the dictionary
  63 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
  64 get_directory_property(incdirs INCLUDE_DIRECTORIES)
  65 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
  66
  67 # Dependencies
  68 set(ROOT_DEPENDENCIES)
  69 set(ALIROOT_DEPENDENCIES STEERBase STEER ESD CDB RAWDatabase FMDrec)
  70
  71 # Generate the ROOT map
  72 # Dependecies
  73 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  74 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
  75
  76 # Create an object to be reused in case of static libraries
  77 # Otherwise the sources will be compiled twice
  78 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
  79 # Follow headers dependencies
  80 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
  81 # Add a library to the project using the object
  82 add_library(${MODULE} SHARED $<TARGET_OBJECTS:${MODULE}-object>)
  83
  84 # linking
  85 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  86
  87 # Setting the correct headers for the object as gathered from the dependencies
  88 target_include_directories(${MODULE}-object PUBLIC $<TARGET_PROPERTY:${MODULE},INCLUDE_DIRECTORIES>)
  89 set_target_properties(${MODULE}-object PROPERTIES COMPILE_DEFINITIONS $<TARGET_PROPERTY:${MODULE},COMPILE_DEFINITIONS>)
  90
  91 # Additional compilation flags
  92 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS " ")
  93
  94 # System dependent: Modify the way the library is build
  95 if(${CMAKE_SYSTEM} MATCHES Darwin)
  96     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
  97 endif(${CMAKE_SYSTEM} MATCHES Darwin)
  98
  99 # Installation
 100 install(TARGETS ${MODULE}
 101         ARCHIVE DESTINATION lib
 102         LIBRARY DESTINATION lib)
 103
 104 install(FILES ${HDRS} DESTINATION include)
 105
 106 # Static version if DA enabled
 107 if(ALIROOT_STATIC)
 108     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:${MODULE}-object>)
 109     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
 110
 111     # list of shared dependencies / the name of the variable containing the list of static ones
 112     generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")
 113     target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root)
 114
 115     # Public include folders that will be propagated to the dependecies
 116     target_include_directories(${MODULE}-static PUBLIC ${incdirs})
 117
 118     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
 119
 120     # Installation
 121     install(TARGETS ${MODULE}-static
 122             ARCHIVE DESTINATION lib
 123             LIBRARY DESTINATION lib)
 124 endif(ALIROOT_STATIC)