ISAJET/code/sigdy2.F

   1 #include "isajet/pilot.h"
   2       SUBROUTINE SIGDY2
   3 C
   4 C          Compute the lepton-lepton-jet cross or quark-antiquark-jet
   5 C          cross section
   6 C          d(sigma)/d(qmw**2)d(qtw**2)d(yw)d(yj)d(omega*)
   7 C          for the specified W and jet types
   8 C
   9 C          Also fix the incoming partons to be the selected types.
  10 C
  11 C          QT cutoff from Parisi and Petronzio, Nucl Phys B154, 427
  12 C          qk+gl-->qk+w suppressed at low QTW
  13 C
  14 C          Ver 6.40: Fix underflow in standard Drell-Yan
  15 C
  16 C          Ver 7.17: include top mass for gb --> Wt and gt --> Zt
  17 C          with no extra qt suppression factor. Note we do NOT include
  18 C          gt --> Wb; while this process makes sense for qt >> m_t,
  19 C          it has a pole in the physical region at low qt from the
  20 C          on-shell decay t --> Wb. We let Q**2 --> Q**2 + m_t**2
  21 C          in the scale for the parton distributions.
  22 C
  23 C          Ver 7.32: Rewrite AJLWT for gb --> Wt, etc., in terms of
  24 C          scaled variables, and restore SWT**5 later to avoid
  25 C          floating errors on VMS.
  26 C
  27 C
  28 #if defined(CERNLIB_IMPNONE)
  29       IMPLICIT NONE
  30 #endif
  31 #include "isajet/itapes.inc"
  32 #include "isajet/jetpar.inc"
  33 #include "isajet/primar.inc"
  34 #include "isajet/q1q2.inc"
  35 #include "isajet/jetsig.inc"
  36 #include "isajet/wsig.inc"
  37 #include "isajet/qsave.inc"
  38 #include "isajet/wcon.inc"
  39 #include "isajet/const.inc"
  40 C
  41       REAL PROP,AJLWT,FCDIR,FCINT,QT2CUT,QFCN,AMASS,STRUC
  42       REAL AJLZT1,AJLZT2,AJLZT3,AJLZT4
  43       REAL X1WT,X2WT,P1WT,P2WT,SWT,TWT,UWT,QZW,P3Z,
  44      $S,T,U,S1,T1,U1,TDIR,UDIR,TINT,UINT,COUPL,DENOM,
  45      $AMT,AMT2,TERM1,TERM2,SIG0,QMW2,Q2,XX,S1WT,T1WT,U1WT,P1M,P2M,
  46      $AMI2,AMF2,EFWT,A2,A2B2,AB,AL2BL2,ALBL,QQ,TM2
  47       REAL AMFAC(13)
  48       INTEGER I,JF,IFLQ,JQK,IQ1,IQ2,IFL1,IQ,IFLL,IH,IQ3
  49       INTEGER NZERO(4)
  50       EQUIVALENCE (S,SHAT),(T,THAT),(U,UHAT)
  51       EQUIVALENCE (S1,SHAT1),(T1,THAT1),(U1,UHAT1)
  52 C
  53       DATA NZERO/13,9,9,11/
  54       DATA AMFAC/11*0.,2*1./
  55
  56 C          Functions.  FCDIR and FCINT are direct and interference
  57 C          terms for virtual Compton cross section.
  58 C
  59       PROP(I)=1./((QMW2-WMASS(I)**2)**2+(WMASS(I)*WGAM(I))**2)
  60       FCDIR(S,T,U,S1,T1,U1)=COUPL*(S*(2.*S1**2-2.*S1*U1-2.*T1*U1)
  61      1+T*(-2.*S1*T1-4.*S1*U1-2.*T1*U1)+U*(2.*U1**2-2.*S1*T1-2.*S1*U1)
  62      2+QMW2*(S**2+U**2+2.*T*QMW2))*(-T)/DENOM
  63       FCINT(S,T,U,S1,T1,U1)=-COUPL*(S1*(S*T-T*U+T*QMW2+QMW2**2)
  64      1+T1*(-S**2+U**2+2.*S*QMW2-2.*U*QMW2)+U1*(S*T-T*U-T*QMW2-QMW2**2))
  65      2*(-T)/DENOM
  66 C          QT cutoff function
  67       QT2CUT(QMW)=CUTOFF*QMW**CUTPOW
  68 C          Parton distributions for top processes
  69       QFCN(XX,IQ,IH)=STRUC(XX,QSQ+AMT2,IQ,IDIN(IH))/XX
  70 C          Matrix elements JL/128 from FORM
  71       AJLWT(S,T,T1,U1,QQ,TM2)=
  72      $ + 2*QQ**3*S*T - 2*QQ**3*S*TM2 - 2*QQ**2*S**2*TM2
  73      $ - 2*QQ**2*S*T**2 + 4*QQ**2*S*T*T1 + 2*QQ**2*S*T*U1
  74      $ - 4*QQ**2*S*T1*TM2 - 2*QQ**2*S*U1*TM2 + 2*QQ**2*S*TM2**2
  75      $ + QQ*S**2*T*TM2 - 4*QQ*S**2*T1*TM2 + QQ*S**2*TM2**2
  76      $ + QQ*S*T**3 - 2*QQ*S*T**2*T1 - QQ*S*T**2*TM2 + 2*QQ*S*T*T1**2
  77      $ + 2*QQ*S*T*T1*U1 - 2*QQ*S*T*T1*TM2 + QQ*S*T*U1**2
  78      $ - 3*QQ*S*T*U1*TM2 + QQ*S*T*TM2**2 - 2*QQ*S*T1**2*TM2
  79      $ - 2*QQ*S*T1*U1*TM2 + 4*QQ*S*T1*TM2**2 - QQ*S*U1**2*TM2
  80      $ + 3*QQ*S*U1*TM2**2 - QQ*S*TM2**3 + S**2*T*T1*TM2
  81      $ - S**2*T*U1*TM2 - 2*S**2*T1**2*TM2 + S**2*T1*TM2**2
  82      $ + S**2*U1*TM2**2 + S*T**2*T1*TM2 - 2*S*T*T1**2*TM2
  83      $ - 2*S*T*T1*U1*TM2 - S*T*U1**2*TM2 + S*T*U1*TM2**2
  84      $ + 2*S*T1**2*TM2**2 + 2*S*T1*U1*TM2**2 - S*T1*TM2**3
  85      $ + S*U1**2*TM2**2 - S*U1*TM2**3
  86 C
  87       AJLZT1(S,T,T1,U1,QQ,TM2)=
  88      $ + A2*AL2BL2 * ( 8*QQ**2*S*T*TM2 - 8*QQ**2*S*TM2**2
  89      $ - 8*QQ**2*T*TM2**2 + 8*QQ**2*TM2**3 - 8*QQ*S**2*T*TM2
  90      $ - 8*QQ*S*T**2*TM2 + 16*QQ*S*T*TM2**2 + 8*QQ*S*TM2**3
  91      $ + 8*QQ*T*TM2**3 - 16*QQ*TM2**4 + 8*S**2*T*U1*TM2
  92      $ - 8*S**2*U1*TM2**2 + 8*S*T**2*U1*TM2 + 8*S*T*U1**2*TM2
  93      $ - 32*S*T*U1*TM2**2 - 8*S*U1**2*TM2**2 + 24*S*U1*TM2**3
  94      $ - 8*T**2*U1*TM2**2 - 8*T*U1**2*TM2**2 + 24*T*U1*TM2**3
  95      $ + 8*U1**2*TM2**3 - 16*U1*TM2**4 )/8.
  96       AJLZT2(S,T,T1,U1,QQ,TM2)=
  97      $ + A2B2*AL2BL2 * ( 2*QQ**3*S*T - 2*QQ**3*S*TM2
  98      $ - 2*QQ**3*T*TM2 + 2*QQ**3*TM2**2 - 2*QQ**2*S**2*TM2
  99      $ - 2*QQ**2*S*T**2 + 4*QQ**2*S*T*T1 + 2*QQ**2*S*T*U1
 100      $ - 8*QQ**2*S*T*TM2 - 4*QQ**2*S*T1*TM2 - 2*QQ**2*S*U1*TM2
 101      $ + 14*QQ**2*S*TM2**2 - 4*QQ**2*T*T1*TM2 - 2*QQ**2*T*U1*TM2
 102      $ + 12*QQ**2*T*TM2**2 + 4*QQ**2*T1*TM2**2 + 2*QQ**2*U1*TM2**2
 103      $ - 14*QQ**2*TM2**3 + QQ*S**3*T - QQ*S**3*TM2 + 2*QQ*S**2*T*T1
 104      $ + 2*QQ*S**2*T*U1 - QQ*S**2*T*TM2 - 6*QQ*S**2*T1*TM2
 105      $ - 2*QQ*S**2*U1*TM2 + 9*QQ*S**2*TM2**2 + QQ*S*T**3
 106      $ - 2*QQ*S*T**2*T1 + 3*QQ*S*T**2*TM2 + 4*QQ*S*T*T1**2
 107      $ + 4*QQ*S*T*T1*U1 - 16*QQ*S*T*T1*TM2 + 2*QQ*S*T*U1**2
 108      $ - 12*QQ*S*T*U1*TM2 + 10*QQ*S*T*TM2**2 - 4*QQ*S*T1**2*TM2
 109      $ - 4*QQ*S*T1*U1*TM2 + 26*QQ*S*T1*TM2**2 - 2*QQ*S*U1**2*TM2
 110      $ + 12*QQ*S*U1*TM2**2 - 30*QQ*S*TM2**3 - QQ*T**3*TM2
 111      $ - 2*QQ*T**2*T1*TM2 - 4*QQ*T**2*U1*TM2 + 5*QQ*T**2*TM2**2
 112      $ - 4*QQ*T*T1**2*TM2 - 4*QQ*T*T1*U1*TM2 + 22*QQ*T*T1*TM2**2
 113      $ - 2*QQ*T*U1**2*TM2 + 18*QQ*T*U1*TM2**2 )/8.
 114       AJLZT3(S,T,T1,U1,QQ,TM2)=
 115      $ + A2B2*AL2BL2 * ( - 26*QQ*T*TM2**3 + 4*QQ*T1**2*TM2**2
 116      $ + 4*QQ*T1*U1*TM2**2 - 24*QQ*T1*TM2**3 + 2*QQ*U1**2*TM2**2
 117      $ - 14*QQ*U1*TM2**3 + 30*QQ*TM2**4 - 8*S**2*T*U1*TM2
 118      $ - 4*S**2*T1**2*TM2 + 8*S**2*T1*TM2**2 + 8*S**2*U1*TM2**2
 119      $ - 4*S**2*TM2**3 - 8*S*T**2*U1*TM2 - 8*S*T*T1**2*TM2
 120      $ - 8*S*T*T1*U1*TM2 + 16*S*T*T1*TM2**2 - 8*S*T*U1**2*TM2
 121      $ + 40*S*T*U1*TM2**2 - 8*S*T*TM2**3 + 16*S*T1**2*TM2**2
 122      $ + 8*S*T1*U1*TM2**2 - 32*S*T1*TM2**3 + 8*S*U1**2*TM2**2
 123      $ - 32*S*U1*TM2**3 + 16*S*TM2**4 - 4*T**2*T1**2*TM2
 124      $ - 8*T**2*T1*U1*TM2 + 8*T**2*T1*TM2**2 - 4*T**2*U1**2*TM2
 125      $ + 16*T**2*U1*TM2**2 - 4*T**2*TM2**3 + 16*T*T1**2*TM2**2
 126      $ + 24*T*T1*U1*TM2**2 - 32*T*T1*TM2**3 + 16*T*U1**2*TM2**2
 127      $ - 48*T*U1*TM2**3 + 16*T*TM2**4 - 16*T1**2*TM2**3
 128      $ - 16*T1*U1*TM2**3 + 32*T1*TM2**4 - 12*U1**2*TM2**3
 129      $ + 32*U1*TM2**4 - 16*TM2**5 )/8.
 130       AJLZT4(S,T,T1,U1,QQ,TM2)=
 131      $ + AB*ALBL * ( 8*QQ**3*S*T - 8*QQ**3*S*TM2 - 8*QQ**3*T*TM2
 132      $ + 8*QQ**3*TM2**2 - 8*QQ**2*S**2*TM2 - 8*QQ**2*S*T**2
 133      $ + 16*QQ**2*S*T*T1 + 8*QQ**2*S*T*U1 - 16*QQ**2*S*T*TM2
 134      $ - 16*QQ**2*S*T1*TM2 - 8*QQ**2*S*U1*TM2 + 40*QQ**2*S*TM2**2
 135      $ - 16*QQ**2*T*T1*TM2 - 8*QQ**2*T*U1*TM2 + 32*QQ**2*T*TM2**2
 136      $ + 16*QQ**2*T1*TM2**2 + 8*QQ**2*U1*TM2**2 - 40*QQ**2*TM2**3
 137      $ - 4*QQ*S**3*T + 4*QQ*S**3*TM2 - 8*QQ*S**2*T*T1
 138      $ - 8*QQ*S**2*T*U1 + 20*QQ*S**2*T*TM2 - 8*QQ*S**2*T1*TM2
 139      $ + 8*QQ*S**2*U1*TM2 - 4*QQ*S**2*TM2**2 + 4*QQ*S*T**3
 140      $ - 8*QQ*S*T**2*T1 - 4*QQ*S*T**2*TM2 + 40*QQ*S*T1*TM2**2
 141      $ - 32*QQ*S*TM2**3 - 4*QQ*T**3*TM2 - 8*QQ*T**2*T1*TM2
 142      $ - 16*QQ*T**2*U1*TM2 + 20*QQ*T**2*TM2**2 + 40*QQ*T*T1*TM2**2
 143      $ + 40*QQ*T*U1*TM2**2 - 48*QQ*T*TM2**3 - 48*QQ*T1*TM2**3
 144      $ - 24*QQ*U1*TM2**3 + 48*QQ*TM2**4 )/8.
 145 C
 146 C          Find whether JETTYP(1) or JETTYP(2) is particle
 147 C
 148       JF=1
 149       IF(2*(JETTYP(1)/2).NE.JETTYP(1)) JF=2
 150 C
 151 C          Kinematics
 152 C
 153       QMW2=QMW**2
 154       QZW=QTMW*SINH(YW)
 155       Q0W=QTMW*COSH(YW)
 156       QW=SQRT(QZW**2+QTW**2)
 157
 158       T1=-X2*ECM*PT(JF)*EXP(YJ(JF))
 159       U1=-X1*ECM*PT(JF)*EXP(-YJ(JF))
 160       S1=-T1-U1-QMW2
 161       SIGLLQ=0.
 162       IF(STDDY) GO TO 400
 163 C
 164 C          qk + qb --> gl + w
 165 C
 166       IF(JETTYP(3).EQ.1) THEN
 167         IFLL=JETTYP(1)/2
 168         COUPL=-ALFA**2*ALFQSQ*PROP(JWTYP)/(9.*PI*SCM*S)
 169         DENOM=S**2*EXP(.5*ALOG(QTW**4+QT2CUT(QMW)**2))
 170         TDIR=FCDIR(T,S,U,T1,S1,U1)*(AQ(IFLL,JWTYP)**2+BQ(IFLL,JWTYP)**2)
 171         UDIR=FCDIR(U,S,T,U1,S1,T1)*(AQ(IFLL,JWTYP)**2+BQ(IFLL,JWTYP)**2)
 172         TINT=FCINT(T,S,U,T1,S1,U1)*2.*AQ(IFLL,JWTYP)*BQ(IFLL,JWTYP)
 173         UINT=FCINT(U,S,T,U1,S1,T1)*2.*AQ(IFLL,JWTYP)*BQ(IFLL,JWTYP)
 174         IQ1=INITYP(1)
 175         IQ2=INITYP(2)
 176         IFL1=IQ1/2
 177         IF(2*IFL1.EQ.IQ1) THEN
 178           TERM1=TDIR*(AQ(IFL1,JWTYP)**2+BQ(IFL1,JWTYP)**2)
 179      $    *QSAVE(IQ1,1)*QSAVE(IQ2,2)
 180           TERM2=TINT*2.*AQ(IFL1,JWTYP)*BQ(IFL1,JWTYP)
 181      $    *QSAVE(IQ1,1)*QSAVE(IQ2,2)
 182           SIGLLQ=SIGLLQ+TERM1+TERM2
 183         ELSE
 184           TERM1=UDIR*(AQ(IFL1,JWTYP)**2+BQ(IFL1,JWTYP)**2)
 185      $    *QSAVE(IQ1,1)*QSAVE(IQ2,2)
 186           TERM2=UINT*2.*AQ(IFL1,JWTYP)*BQ(IFL1,JWTYP)
 187      $    *QSAVE(IQ1,1)*QSAVE(IQ2,2)
 188           SIGLLQ=SIGLLQ+TERM1+TERM2
 189         ENDIF
 190         SIGLLQ=SIGLLQ*UNITS
 191         IF(JETTYP(1).LE.13) SIGLLQ=3.*SIGLLQ
 192         RETURN
 193 C
 194 C          qk + gl --> qk + w
 195 C
 196       ELSEIF(JETTYP(3).LE.NZERO(JWTYP)) THEN
 197         JQK=MATCH(JETTYP(3),4)
 198         JQK=MATCH(JQK,JWTYP)
 199         IF(JQK.EQ.0) RETURN
 200         COUPL=ALFA**2*ALFQSQ*PROP(JWTYP)/(24.*PI*SCM*S)
 201         DENOM=S**2*EXP(.5*ALOG(QTW**4+QT2CUT(QMW)**2))
 202         IFLQ=JQK/2
 203         IFLL=JETTYP(1)/2
 204         IF(INITYP(2).EQ.1) THEN
 205           TDIR=FCDIR(S,T,U,S1,T1,U1)*QSAVE(JQK,1)*QSAVE(1,2)
 206         ELSE
 207           TDIR=FCDIR(S,U,T,S1,U1,T1)*QSAVE(JQK,2)*QSAVE(1,1)
 208         ENDIF
 209         TDIR=TDIR*(AQ(IFLQ,JWTYP)**2+BQ(IFLQ,JWTYP)**2)
 210      $  *(AQ(IFLL,JWTYP)**2+BQ(IFLL,JWTYP)**2)
 211         IF(INITYP(2).EQ.1) THEN
 212           TINT=FCINT(S,T,U,S1,T1,U1)*QSAVE(JQK,1)*QSAVE(1,2)
 213         ELSE
 214           TINT=FCINT(S,U,T,S1,U1,T1)*QSAVE(JQK,2)*QSAVE(1,1)
 215         ENDIF
 216         TINT=TINT*4.*AQ(IFLQ,JWTYP)*BQ(IFLQ,JWTYP)*AQ(IFLL,JWTYP)
 217      $  *BQ(IFLL,JWTYP)
 218         SIGLLQ=TDIR+TINT
 219         SIGLLQ=SIGLLQ*UNITS
 220         IF(JETTYP(1).LE.13) SIGLLQ=3.*SIGLLQ
 221         SIGLLQ=SIGLLQ*QTW**2/(QTW**2+QT2CUT(QMW))
 222         RETURN
 223 C
 224 C          bt,tp + gl --> bt,tp + W,Z
 225 C
 226       ELSEIF(JETTYP(3).GE.NZERO(JWTYP)+1) THEN
 227         IQ3=JETTYP(3)
 228         JQK=MATCH(IQ3,4)
 229         JQK=MATCH(JQK,JWTYP)
 230         IF(JQK.EQ.0) RETURN
 231         AMT=AMASS(6)
 232         AMT2=AMT**2
 233         Q2=QMW2
 234         AMF2=AMFAC(IQ3)*AMT2
 235         AMI2=AMFAC(JQK)*AMT2
 236         EFWT=SQRT(P(3)**2+AMF2)
 237         P3Z=P(3)*CTH(3)
 238         SWT=QMW2+AMF2+2.*Q0W*EFWT-2.*QZW*P3Z+2.*PT(3)**2
 239 C          Kinematics
 240         IF(INITYP(2).EQ.1) THEN
 241           P1WT=EFWT+P3Z+Q0W+QZW
 242           P1M=AMI2/P1WT
 243           P2WT=EFWT-P3Z+Q0W-QZW-P1M
 244           X1WT=.5*P1WT/HALFE
 245           X2WT=.5*P2WT/HALFE
 246           TWT=-P1WT*(EFWT-P3Z)-P1M*(P(3)+P3Z)+AMI2+AMF2
 247           UWT=-P2WT*(EFWT+P3Z)+AMF2
 248           T1WT=-X2WT*ECM*PT(JF)*EXP(YJ(JF))
 249           U1WT=-X1WT*ECM*PT(JF)*EXP(-YJ(JF))-P1M*PT(JF)*EXP(YJ(JF))
 250           S1WT=-T1WT-U1WT-QMW2+AMI2+AMF2
 251         ELSE
 252           P2WT=EFWT-P3Z+Q0W-QZW
 253           P2M=AMI2/P2WT
 254           P1WT=EFWT+P3Z+Q0W+QZW-P2M
 255           X1WT=.5*P1WT/HALFE
 256           X2WT=.5*P2WT/HALFE
 257           TWT=-P1WT*(EFWT-P3Z)+AMF2
 258           UWT=-P2WT*(EFWT+P3Z)-P2M*(EFWT-P3Z)+AMI2+AMF2
 259           T1WT=-X2WT*ECM*PT(JF)*EXP(YJ(JF))-P2M*PT(JF)*EXP(-YJ(JF))
 260           U1WT=-X1WT*ECM*PT(JF)*EXP(-YJ(JF))
 261           S1WT=-T1WT-U1WT-QMW2+AMI2+AMF2
 262         ENDIF
 263 C          Cross section
 264         SIG0=-ALFA**2*ALFQSQ/(12*PI*SCM*SWT)*PROP(JWTYP)*UNITS
 265         IF(JETTYP(1).LE.13) SIG0=3*SIG0
 266         IF(JWTYP.EQ.2.OR.JWTYP.EQ.3) THEN
 267           SIG0=SIG0*(AQ(6,JWTYP)**2+BQ(6,JWTYP)**2)**2
 268           IF(INITYP(2).EQ.1.AND.(IQ3.EQ.12.OR.IQ3.EQ.13)) THEN
 269             SIGLLQ=AJLWT(SWT/SWT,TWT/SWT,T1WT/SWT,U1WT/SWT,Q2/SWT,
 270      $      AMT2/SWT)
 271             SIGLLQ=SIGLLQ*SWT*(SWT/(SWT-AMI2))**2*(SWT/(TWT-AMF2))**2
 272             SIGLLQ=SIGLLQ*SIG0*QFCN(X1WT,JQK,1)*QFCN(X2WT,1,2)
 273           ELSEIF(INITYP(1).EQ.1.AND.(IQ3.EQ.12.OR.IQ3.EQ.13)) THEN
 274             SIGLLQ=AJLWT(SWT/SWT,UWT/SWT,U1WT/SWT,T1WT/SWT,Q2/SWT,
 275      $      AMT2/SWT)
 276             SIGLLQ=SIGLLQ*SWT*(SWT/(SWT-AMI2))**2*(SWT/(TWT-AMF2))**2
 277             SIGLLQ=SIGLLQ*SIG0*QFCN(X1WT,JQK,2)*QFCN(X2WT,1,1)
 278           ENDIF
 279         ELSEIF(JWTYP.EQ.4) THEN
 280           A2=AQ(6,JWTYP)**2
 281           A2B2=AQ(6,JWTYP)**2+BQ(6,JWTYP)**2
 282           AB=AQ(6,JWTYP)*BQ(6,JWTYP)
 283           AL2BL2=AQ(JETTYP(1)/2,JWTYP)**2+BQ(JETTYP(1)/2,JWTYP)**2
 284           ALBL=AQ(JETTYP(1)/2,JWTYP)*BQ(JETTYP(1)/2,JWTYP)
 285           IF(INITYP(2).EQ.1) THEN
 286             SIGLLQ=AJLZT1(SWT/SWT,TWT/SWT,T1WT/SWT,U1WT/SWT,
 287      $      Q2/SWT,AMT2/SWT)
 288             SIGLLQ=SIGLLQ+AJLZT2(SWT/SWT,TWT/SWT,T1WT/SWT,U1WT/SWT,
 289      $      Q2/SWT,AMT2/SWT)
 290             SIGLLQ=SIGLLQ+AJLZT3(SWT/SWT,TWT/SWT,T1WT/SWT,U1WT/SWT,
 291      $      Q2/SWT,AMT2/SWT)
 292             SIGLLQ=SIGLLQ+AJLZT4(SWT/SWT,TWT/SWT,T1WT/SWT,U1WT/SWT,
 293      $      Q2/SWT,AMT2/SWT)
 294             SIGLLQ=SIGLLQ*SWT*(SWT/(SWT-AMI2))**2*(SWT/(TWT-AMF2))**2
 295             SIGLLQ=SIGLLQ*SIG0*QFCN(X1WT,JQK,1)*QFCN(X2WT,1,2)
 296           ELSEIF(INITYP(1).EQ.1) THEN
 297             SIGLLQ=AJLZT1(SWT/SWT,UWT/SWT,U1WT/SWT,T1WT/SWT,
 298      $      Q2/SWT,AMT2/SWT)
 299             SIGLLQ=SIGLLQ+AJLZT2(SWT/SWT,UWT/SWT,U1WT/SWT,T1WT/SWT,
 300      $      Q2/SWT,AMT2/SWT)
 301             SIGLLQ=SIGLLQ+AJLZT3(SWT/SWT,UWT/SWT,U1WT/SWT,T1WT/SWT,
 302      $      Q2/SWT,AMT2/SWT)
 303             SIGLLQ=SIGLLQ+AJLZT4(SWT/SWT,UWT/SWT,U1WT/SWT,T1WT/SWT,
 304      $      Q2/SWT,AMT2/SWT)
 305             SIGLLQ=SIGLLQ*SWT*(SWT/(SWT-AMI2))**2*(SWT/(UWT-AMF2))**2
 306             SIGLLQ=SIGLLQ*SIG0*QFCN(X1WT,JQK,2)*QFCN(X2WT,1,1)
 307           ENDIF
 308         ENDIF
 309       ENDIF
 310       RETURN
 311 C
 312 C          Standard Drell-Yan with QT=0.
 313 C
 314 400   CONTINUE
 315       IFLL=JETTYP(1)/2
 316       COUPL=ALFA**2*PROP(JWTYP)*UNITS
 317       TDIR=COUPL*(AQ(IFLL,JWTYP)**2+BQ(IFLL,JWTYP)**2)
 318      $*((U1**2+T1**2)/(6.*SCM*QMW2))
 319       TINT=COUPL*2.*AQ(IFLL,JWTYP)*BQ(IFLL,JWTYP)
 320      $*((U1**2-T1**2)/(6.*SCM*QMW2))
 321       IQ1=INITYP(1)
 322       IQ2=INITYP(2)
 323       IFL1=IQ1/2
 324       TERM1=TDIR*(AQ(IFL1,JWTYP)**2+BQ(IFL1,JWTYP)**2)
 325      $*QSAVE(IQ1,1)*QSAVE(IQ2,2)
 326       TERM2=-TINT*2.*AQ(IFL1,JWTYP)*BQ(IFL1,JWTYP)
 327      $*QSAVE(IQ1,1)*QSAVE(IQ2,2)
 328       IF(2*IFL1.EQ.IQ1) SIGLLQ=SIGLLQ+TERM1+TERM2
 329       IF(2*IFL1.NE.IQ1) SIGLLQ=SIGLLQ+TERM1-TERM2
 330       IF(JETTYP(1).LE.13) SIGLLQ=3.*SIGLLQ
 331       RETURN
 332       END