ISAJET/isasusy/sshgl.F

   1 #include "isajet/pilot.h"
   2       SUBROUTINE SSHGL
   3 C-----------------------------------------------------------------------
   4 C
   5 C     Calculate H -> gl gl decays including both SM particles and
   6 C     SUSY particles in loop.
   7 C
   8 C     This subroutine uses the tau variable of the Higgs Hunters'
   9 C     Guide.  Many other authors, including the paper cited in
  10 C     Higgs Hunters' Guide (PR. D. 38(11): 3481) and Collider Physics
  11 C     by Barger and Phillips use the variable lambda
  12 C          LAMBDA = ( MASS OF PARTICLE IN LOOP / MASS OF HIGGS )**2
  13 C          TAU = 4.0 * LAMBDA
  14 C
  15 C     Bisset's HGLGL
  16 C-----------------------------------------------------------------------
  17 #if defined(CERNLIB_IMPNONE)
  18       IMPLICIT NONE
  19 #endif
  20 #include "isajet/sssm.inc"
  21 #include "isajet/sspar.inc"
  22 #include "isajet/sstype.inc"
  23 C
  24       DOUBLE PRECISION ETAH,IITOT,RITOT,TAU,IFFF,RFFF
  25      $,IFHALF,RFHALF,IF1,RF1,IF0,RF0,TW2,RHF,RHSF,RHSFL,RHSFR
  26      $,IIHF,RIHF,IIHSFL,RIHSFL,IIHSFR,RIHSFR,AS,SUMISQ,DW
  27      $,RHSF1,RHSF2,IIHSF1,IIHSF2,RIHSF1,RIHSF2
  28       DOUBLE PRECISION PI,SR2,XM,THETX,YM,THETY,SGL,CGL,SGR,CGR
  29      $,MW1,MW2,THETM,THETP,G2,BETA,ALPHA,SW2,CW2,MH,AMSQ
  30       DOUBLE PRECISION MFL(3),MFD(3),MFU(3)
  31       DOUBLE PRECISION SSALFS
  32       REAL WID
  33       REAL ASMB,MBMB,MBQ,ASMT,MTMT,MTQ,SUALFS
  34       DOUBLE PRECISION SSMQCD
  35       INTEGER IJ,II,NUMOUT,NUMH,IDHHA
  36 C
  37 C          Mass matrix parameters
  38 C
  39       PI=4.*ATAN(1.D0)
  40       SR2=SQRT(2.D0)
  41       XM=1./TAN(GAMMAL)
  42       THETX=SIGN(1.D0,XM)
  43       YM=1./TAN(GAMMAR)
  44       THETY=SIGN(1.D0,YM)
  45       SGL=1/(DSQRT(1+XM**2))
  46       CGL=SGL*XM
  47       SGR=1/(DSQRT(1+YM**2))
  48       CGR=SGR*YM
  49       MW1=DBLE(ABS(AMW1SS))
  50       MW2=DBLE(ABS(AMW2SS))
  51       THETM=SIGN(1.,AMW1SS)
  52       THETP=SIGN(1.,AMW2SS)
  53       G2=4.0*PI*ALFAEM/SN2THW
  54       BETA=ATAN(1.0/RV2V1)
  55       ALPHA=ALFAH
  56       SW2=SN2THW
  57       CW2=1.-SN2THW
  58 C
  59 C          Loop over neutral Higgs bosons
  60 C
  61       DO 100 NUMH=1,3
  62         IF(NUMH.EQ.1) THEN
  63           MH=AMHL
  64           IDHHA=ISHL
  65         ELSEIF(NUMH.EQ.2) THEN
  66           MH=AMHH
  67           IDHHA=ISHH
  68         ELSE
  69           MH=AMHA
  70           IDHHA=ISHA
  71         ENDIF
  72         ETAH=1.0
  73         IITOT=0.0
  74         RITOT=0.0
  75 C
  76       ASMB=SUALFS(AMBT**2,.36,AMTP,3)
  77       MBMB=AMBT*(1.-4*ASMB/3./PI)
  78       MBQ=SSMQCD(DBLE(MBMB),DBLE(MH))
  79       ASMT=SUALFS(AMTP**2,.36,AMTP,3)
  80       MTMT=AMTP/(1.+4*ASMT/3./PI+(16.11-1.04*(5.-6.63/AMTP))*
  81      $(ASMT/PI)**2)
  82       MTQ=SSMQCD(DBLE(MTMT),DBLE(MH))
  83
  84 C
  85       MFL(1)=DBLE(AME)
  86       MFL(2)=DBLE(AMMU)
  87       MFL(3)=DBLE(AMTAU)
  88       MFD(1)=DBLE(AMDN)
  89       MFD(2)=DBLE(AMST)
  90       MFD(3)=DBLE(MBQ)
  91       MFU(1)=DBLE(AMUP)
  92       MFU(2)=DBLE(AMCH)
  93       MFU(3)=DBLE(MTQ)
  94 C
  95 C
  96 C          Down-type quark loops
  97 C
  98         DO 20 II=1,3
  99           TAU=4.0*MFD(II)**2/MH**2
 100           CALL SSHGM1(TAU,IFFF,RFFF)
 101           IFHALF=0.5*TAU*(1.0-TAU*ETAH)*IFFF
 102           RFHALF=0.5*TAU*(ETAH+(1.0-TAU*ETAH)*RFFF)
 103           IF(NUMH.EQ.1) THEN
 104             RHF=SIN(ALPHA)/COS(BETA)
 105           ELSEIF(NUMH.EQ.2) THEN
 106             RHF=COS(ALPHA)/COS(BETA)
 107           ELSE
 108             RHF=TAN(BETA)
 109           ENDIF
 110           IIHF=RHF*IFHALF
 111           RIHF=RHF*RFHALF
 112           IITOT=IITOT+IIHF
 113           RITOT=RITOT+RIHF
 114 20      CONTINUE
 115 C
 116 C          Up-type quark loops
 117 C
 118         DO 30 II=1,2
 119           TAU=4.0*MFU(II)**2/MH**2
 120           CALL SSHGM1(TAU,IFFF,RFFF)
 121           IFHALF=0.5*TAU*(1.0-TAU*ETAH)*IFFF
 122           RFHALF=0.5*TAU*(ETAH+(1.0-TAU*ETAH)*RFFF)
 123           IF(NUMH.EQ.1) THEN
 124             RHF=COS(ALPHA)/SIN(BETA)
 125           ELSEIF(NUMH.EQ.2) THEN
 126             RHF=-SIN(ALPHA)/SIN(BETA)
 127           ELSE
 128             RHF=TAN(BETA)
 129           ENDIF
 130           IIHF=RHF*IFHALF
 131           RIHF=RHF*RFHALF
 132           IITOT=IITOT+IIHF
 133           RITOT=RITOT+RIHF
 134 30      CONTINUE
 135 C
 136         TAU=4.0*MTQ**2/MH**2
 137         CALL SSHGM1(TAU,IFFF,RFFF)
 138         IFHALF=0.5*TAU*(1.0-TAU*ETAH)*IFFF
 139         RFHALF=0.5*TAU*(ETAH+(1.0-TAU*ETAH)*RFFF)
 140         IF(NUMH.EQ.1) THEN
 141           RHF=COS(ALPHA)/SIN(BETA)
 142         ELSEIF(NUMH.EQ.2) THEN
 143           RHF=-SIN(ALPHA)/SIN(BETA)
 144         ELSE
 145           RHF=1.0/TAN(BETA)
 146         ENDIF
 147         IIHF=RHF*IFHALF
 148         RIHF=RHF*RFHALF
 149         IITOT=IITOT+IIHF
 150         RITOT=RITOT+RIHF
 151 C
 152 C          Down-type squark loops
 153 C          Mixing between the sbottom squarks is included, so
 154 C          masses used here are the mixed masses (AMB1SS & AMB2SS)
 155 C          First do d_L and s_L squarks
 156         TW2=SW2/CW2
 157         DO 50 II=1,2
 158           IF(NUMH.EQ.1) THEN
 159             RHSF=2.0*(MFD(II)/AMW)**2*SIN(ALPHA)/COS(BETA)
 160             RHSFL=(-1.0-TW2/3.0)*SIN(BETA-ALPHA)-RHSF
 161           ELSEIF(NUMH.EQ.2) THEN
 162             RHSF=2.0*(MFD(II)/AMW)**2*COS(ALPHA)/COS(BETA)
 163             RHSFL=(-1.0-TW2/3.0)*(-1.0)*COS(BETA-ALPHA)-RHSF
 164           ELSE
 165             RHSF=0
 166             RHSFL=0
 167           ENDIF
 168           IF (II.EQ.1) AMSQ=AMDLSS
 169           IF (II.EQ.2) AMSQ=AMSLSS
 170           TAU=4.0*AMSQ**2/MH**2
 171           CALL SSHGM1(TAU,IFFF,RFFF)
 172           IF0=-TAU*TAU*IFFF
 173           RF0=TAU*(1.0-TAU*RFFF)
 174           IIHSFL=RHSFL*IF0*(AMW/AMSQ)**2/8.0
 175           RIHSFL=RHSFL*RF0*(AMW/AMSQ)**2/8.0
 176           IITOT=IITOT+IIHSFL
 177           RITOT=RITOT+RIHSFL
 178 50      CONTINUE
 179 c       Next, do R squarks
 180         DO 51 II=1,2
 181           IF(NUMH.EQ.1) THEN
 182             RHSF=2.0*(MFD(II)/AMW)**2*SIN(ALPHA)/COS(BETA)
 183             RHSFR=(-2.0*TW2/3.0)*SIN(BETA-ALPHA)-RHSF
 184           ELSEIF(NUMH.EQ.2) THEN
 185             RHSF=2.0*(MFD(II)/AMW)**2*COS(ALPHA)/COS(BETA)
 186             RHSFR=(-2.0*TW2/3.0)*(-1.0)*COS(BETA-ALPHA)-RHSF
 187           ELSE
 188             RHSF=0
 189             RHSFR=0
 190           ENDIF
 191           IF (II.EQ.1) AMSQ=AMDRSS
 192           IF (II.EQ.2) AMSQ=AMSRSS
 193           TAU=4.0*AMSQ**2/MH**2
 194           CALL SSHGM1(TAU,IFFF,RFFF)
 195           IF0=-TAU*TAU*IFFF
 196           RF0=TAU*(1.0-TAU*RFFF)
 197           IIHSFR=RHSFR*IF0*(AMW/AMSQ)**2/8.0
 198           RIHSFR=RHSFR*RF0*(AMW/AMSQ)**2/8.0
 199           IITOT=IITOT+IIHSFR
 200           RITOT=RITOT+RIHSFR
 201 51      CONTINUE
 202         IF(NUMH.EQ.1) THEN
 203           RHSF=2.0*(MBQ/AMW)**2*SIN(ALPHA)/COS(BETA)
 204           RHSFL=(-1.0-TW2/3.0)*SIN(BETA-ALPHA)-RHSF
 205           RHSFR=(-2.0*TW2/3.0)*SIN(BETA-ALPHA)-RHSF
 206         ELSEIF(NUMH.EQ.2) THEN
 207           RHSF=2.0*(MBQ/AMW)**2*COS(ALPHA)/COS(BETA)
 208           RHSFL=(-1.0-TW2/3.0)*(-1.0)*COS(BETA-ALPHA)-RHSF
 209           RHSFR=(-2.0*TW2/3.0)*(-1.0)*COS(BETA-ALPHA)-RHSF
 210         ELSE
 211           RHSF=0
 212           RHSFL=0
 213           RHSFR=0
 214         ENDIF
 215         RHSF1=RHSFL*COS(THETAB)-RHSFR*SIN(THETAB)
 216         RHSF2=RHSFL*SIN(THETAB)+RHSFR*COS(THETAB)
 217         TAU=4.0*AMB1SS**2/MH**2
 218         CALL SSHGM1(TAU,IFFF,RFFF)
 219         IF0=-TAU*TAU*IFFF
 220         RF0=TAU*(1.0-TAU*RFFF)
 221         IIHSF1=RHSF1*IF0*(AMW/AMB1SS)**2/8.0
 222         RIHSF1=RHSF1*RF0*(AMW/AMB1SS)**2/8.0
 223         IITOT=IITOT+IIHSF1
 224         RITOT=RITOT+RIHSF1
 225         TAU=4.0*AMB2SS**2/MH**2
 226         CALL SSHGM1(TAU,IFFF,RFFF)
 227         IF0=-TAU*TAU*IFFF
 228         RF0=TAU*(1.0-TAU*RFFF)
 229         IIHSF2=RHSF2*IF0*(AMW/AMB2SS)**2/8.0
 230         RIHSF2=RHSF2*RF0*(AMW/AMB2SS)**2/8.0
 231         IITOT=IITOT+IIHSF2
 232         RITOT=RITOT+RIHSF2
 233 C
 234 C          Up-type squark loops
 235 C          Mixing between the stop squarks is included, so
 236 C          masses used here are the mixed masses (AMT1SS & AMT2SS)
 237 C          First do u_L and c_L
 238         DO 60 II=1,2
 239           IF(NUMH.EQ.1) THEN
 240             RHSF=2.0*(MFU(II)/AMW)**2*COS(ALPHA)/SIN(BETA)
 241             RHSFL=(1.0-TW2/3.0)*SIN(BETA-ALPHA)-RHSF
 242           ELSEIF(NUMH.EQ.2) THEN
 243             RHSF=2.0*(MFU(II)/AMW)**2
 244             RHSF=RHSF*(-1.0)*SIN(ALPHA)/SIN(BETA)
 245             RHSFL=(1.0-TW2/3.0)*(-1.0)*COS(BETA-ALPHA)-RHSF
 246           ELSE
 247             RHSF=0
 248             RHSFL=0
 249           ENDIF
 250           IF (II.EQ.1) AMSQ=AMULSS
 251           IF (II.EQ.2) AMSQ=AMCLSS
 252           TAU=4.0*(AMSQ)**2/MH**2
 253           CALL SSHGM1(TAU,IFFF,RFFF)
 254           IF0=-TAU*TAU*IFFF
 255           RF0=TAU*(1.0-TAU*RFFF)
 256           IIHSFL=RHSFL*IF0*(AMW/AMSQ)**2/8.0
 257           RIHSFL=RHSFL*RF0*(AMW/AMSQ)**2/8.0
 258           IITOT=IITOT+IIHSFL
 259           RITOT=RITOT+RIHSFL
 260 60      CONTINUE
 261 C          Next, do u_R and c_R
 262         DO 61 II=1,2
 263           IF(NUMH.EQ.1) THEN
 264             RHSF=2.0*(MFU(II)/AMW)**2*COS(ALPHA)/SIN(BETA)
 265             RHSFR=(4.0*TW2/3.0)*SIN(BETA-ALPHA)-RHSF
 266           ELSEIF(NUMH.EQ.2) THEN
 267             RHSF=2.0*(MFU(II)/AMW)**2
 268             RHSF=RHSF*(-1.0)*SIN(ALPHA)/SIN(BETA)
 269             RHSFR=(4.0*TW2/3.0)*(-1.0)*COS(BETA-ALPHA)-RHSF
 270           ELSE
 271             RHSF=0
 272             RHSFR=0
 273           ENDIF
 274           IF (II.EQ.1) AMSQ=AMURSS
 275           IF (II.EQ.2) AMSQ=AMCRSS
 276           TAU=4.0*(AMSQ)**2/MH**2
 277           CALL SSHGM1(TAU,IFFF,RFFF)
 278           IF0=-TAU*TAU*IFFF
 279           RF0=TAU*(1.0-TAU*RFFF)
 280           IIHSFR=RHSFR*IF0*(AMW/AMSQ)**2/8.0
 281           RIHSFR=RHSFR*RF0*(AMW/AMSQ)**2/8.0
 282           IITOT=IITOT+IIHSFR
 283           RITOT=RITOT+RIHSFR
 284 61      CONTINUE
 285 C
 286         IF(NUMH.EQ.1) THEN
 287           RHSF=2.0*(MTQ/AMW)**2*COS(ALPHA)/SIN(BETA)
 288           RHSFL=(1.0-TW2/3.0)*SIN(BETA-ALPHA)-RHSF
 289           RHSFR=(4.0*TW2/3.0)*SIN(BETA-ALPHA)-RHSF
 290         ELSEIF(NUMH.EQ.2) THEN
 291           RHSF=2.0*(MTQ/AMW)**2
 292           RHSF=RHSF*(-1.0)*SIN(ALPHA)/SIN(BETA)
 293           RHSFL=(1.0-TW2/3.0)*(-1.0)*COS(BETA-ALPHA)-RHSF
 294           RHSFR=(4.0*TW2/3.0)*(-1.0)*COS(BETA-ALPHA)-RHSF
 295         ELSE
 296           RHSF=0
 297           RHSFL=0
 298           RHSFR=0
 299         ENDIF
 300         RHSF1=RHSFL*COS(THETAT)-RHSFR*SIN(THETAT)
 301         RHSF2=RHSFL*SIN(THETAT)+RHSFR*COS(THETAT)
 302         TAU=4.0*AMT1SS**2/MH**2
 303         CALL SSHGM1(TAU,IFFF,RFFF)
 304         IF0=-TAU*TAU*IFFF
 305         RF0=TAU*(1.0-TAU*RFFF)
 306         IIHSF1=RHSF1*IF0*(AMW/AMT1SS)**2/8.0
 307         RIHSF1=RHSF1*RF0*(AMW/AMT1SS)**2/8.0
 308         IITOT=IITOT+IIHSF1
 309         RITOT=RITOT+RIHSF1
 310         TAU=4.0*AMT2SS**2/MH**2
 311         CALL SSHGM1(TAU,IFFF,RFFF)
 312         IF0=-TAU*TAU*IFFF
 313         RF0=TAU*(1.0-TAU*RFFF)
 314         IIHSF2=RHSF2*IF0*(AMW/AMT2SS)**2/8.0
 315         RIHSF2=RHSF2*RF0*(AMW/AMT2SS)**2/8.0
 316         IITOT=IITOT+IIHSF2
 317         RITOT=RITOT+RIHSF2
 318 C
 319 C           IITOT and RITOT now contain the total imaginary and
 320 C           real parts of the I function
 321 C
 322         SUMISQ=IITOT**2+RITOT**2
 323         AS=SSALFS(MH**2)
 324         DW=AS**2*G2*MH**3/(32.0*(PI**3)*AMW**2)
 325         WID=DW*SUMISQ
 326         CALL SSSAVE(IDHHA,WID,IDGL,IDGL,0,0,0)
 327 100   CONTINUE
 328 C
 329        RETURN
 330        END