PYTHIA/pythia/pyggam.F

   1
   2 C*********************************************************************
   3
   4 C...The following routines are adapted from
   5 C...SaSgam - parton distributions of the photon
   6 C...by Gerhard A. Schuler and Torbjorn Sjostrand
   7 C...For further information see CERN-TH/95-62.
   8 C...The version found here is NOT suitable for standalone usage.
   9
  10       SUBROUTINE PYGGAM(ISET,X,Q2,P2,F2GM,XPDFGM)
  11 C...Purpose: to construct the F2 and parton distributions of the photon
  12 C...by summing homogeneous (VMD) and inhomogeneous (anomalous) terms.
  13 C...For F2, c and b are included by the Bethe-Heitler formula;
  14 C...in the 'MSbar' scheme additionally a Cgamma term is added.
  15       DIMENSION XPDFGM(-6:6)
  16       COMMON/PYINT8/XPVMD(-6:6),XPANL(-6:6),XPANH(-6:6),XPBEH(-6:6),
  17      &XPDIR(-6:6)
  18       SAVE /PYINT8/
  19
  20 C...Temporary array.
  21       DIMENSION XPGA(-6:6)
  22 C...Charm and bottom masses (low to compensate for J/psi etc.).
  23       DATA PMC/1.3/, PMB/4.6/
  24 C...alpha_em and alpha_em/(2*pi).
  25       DATA AEM/0.007297/, AEM2PI/0.0011614/
  26 C...Lambda value for 4 flavours.
  27       DATA ALAM/0.20/
  28 C...Mixture u/(u+d), = 0.5 for incoherent and = 0.8 for coherent sum.
  29       DATA FRACU/0.8/
  30 C...VMD couplings f_V**2/(4*pi).
  31       DATA FRHO/2.20/, FOMEGA/23.6/, FPHI/18.4/
  32 C...Masses for rho (=omega) and phi.
  33       DATA PMRHO/0.770/, PMPHI/1.020/
  34
  35 C...Reset output.
  36       F2GM=0.
  37       DO 100 KFL=-6,6
  38       XPDFGM(KFL)=0.
  39       XPVMD(KFL)=0.
  40       XPANL(KFL)=0.
  41       XPANH(KFL)=0.
  42       XPBEH(KFL)=0.
  43       XPDIR(KFL)=0.
  44   100 CONTINUE
  45
  46 C...Set k0 cut-off parameter as function of set used.
  47       IF(ISET.LE.2) THEN
  48         AK0=0.6
  49       ELSE
  50         AK0=2.
  51       ENDIF
  52
  53 C...Call VMD parametrization for d quark and use to give rho+omega+ phi.
  54 C...Note scale choice and dipole dampening for off-shell photon.
  55       P2MX=MAX(P2,AK0**2)
  56       CALL PYGVMD(ISET,1,X,Q2,P2MX,ALAM,XPGA)
  57       XFVAL=XPGA(1)-XPGA(2)
  58       XPGA(1)=XPGA(2)
  59       XPGA(-1)=XPGA(-2)
  60       FACUD=AEM*(1./FRHO+1./FOMEGA)*(PMRHO**2/(PMRHO**2+P2))**2
  61       FACS=AEM*(1./FPHI)*(PMPHI**2/(PMPHI**2+P2))**2
  62       DO 110 KFL=-5,5
  63       XPVMD(KFL)=(FACUD+FACS)*XPGA(KFL)
  64   110 CONTINUE
  65       XPVMD(1)=XPVMD(1)+(1.-FRACU)*FACUD*XFVAL
  66       XPVMD(2)=XPVMD(2)+FRACU*FACUD*XFVAL
  67       XPVMD(3)=XPVMD(3)+FACS*XFVAL
  68       XPVMD(-1)=XPVMD(-1)+(1.-FRACU)*FACUD*XFVAL
  69       XPVMD(-2)=XPVMD(-2)+FRACU*FACUD*XFVAL
  70       XPVMD(-3)=XPVMD(-3)+FACS*XFVAL
  71
  72 C...Call anomalous parametrization for d + u + s.
  73       CALL PYGANO(-3,X,Q2,P2MX,ALAM,XPGA)
  74       DO 120 KFL=-5,5
  75       XPANL(KFL)=XPGA(KFL)
  76   120 CONTINUE
  77
  78 C...Call anomalous parametrization for c and b.
  79       CALL PYGANO(4,X,Q2,P2MX,ALAM,XPGA)
  80       DO 130 KFL=-5,5
  81       XPANH(KFL)=XPGA(KFL)
  82   130 CONTINUE
  83       CALL PYGANO(5,X,Q2,P2MX,ALAM,XPGA)
  84       DO 140 KFL=-5,5
  85       XPANH(KFL)=XPANH(KFL)+XPGA(KFL)
  86   140 CONTINUE
  87
  88 C...Call Bethe-Heitler term expression for charm and bottom.
  89       CALL PYGBEH(4,X,Q2,P2,PMC**2,XPBH)
  90       XPBEH(4)=XPBH
  91       XPBEH(-4)=XPBH
  92       CALL PYGBEH(5,X,Q2,P2,PMB**2,XPBH)
  93       XPBEH(5)=XPBH
  94       XPBEH(-5)=XPBH
  95
  96 C...For MSbar subtraction call C^gamma term expression for d, u, s.
  97       IF(ISET.EQ.2.OR.ISET.EQ.4) THEN
  98         CALL PYGDIR(X,Q2,P2,AK0,XPGA)
  99         DO 150 KFL=-5,5
 100         XPDIR(KFL)=XPGA(KFL)
 101   150   CONTINUE
 102       ENDIF
 103
 104 C...Store result in output array.
 105       DO 160 KFL=-5,5
 106       CHSQ=1./9.
 107       IF(IABS(KFL).EQ.2.OR.IABS(KFL).EQ.4) CHSQ=4./9.
 108       XPF2=XPVMD(KFL)+XPANL(KFL)+XPBEH(KFL)+XPDIR(KFL)
 109       IF(KFL.NE.0) F2GM=F2GM+CHSQ*XPF2
 110       XPDFGM(KFL)=XPVMD(KFL)+XPANL(KFL)+XPANH(KFL)
 111   160 CONTINUE
 112
 113       RETURN
 114       END