TPC/TPCsim/CMakeLists.txt

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # Module
  17 set(MODULE TPCsim)
  18
  19 # Module include folder
  20 include_directories(${AliRoot_SOURCE_DIR}/TPC/${MODULE})
  21
  22 # Additional include folders in alphabetical order except ROOT
  23 include_directories(${ROOT_INCLUDE_DIR}
  24                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
  25                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatarec
  26                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatasim
  27                     ${AliRoot_SOURCE_DIR}/STEER/CDB
  28                     ${AliRoot_SOURCE_DIR}/STEER/ESD
  29                     ${AliRoot_SOURCE_DIR}/STEER/STEER
  30                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
  31                     ${AliRoot_SOURCE_DIR}/TPC/TPCbase
  32                     ${AliRoot_SOURCE_DIR}/TPC/TPCrec
  33                    )
  34
  35 # Sources in alphabetical order
  36 set(SRCS
  37     AliTPCBuffer.cxx
  38     AliTPC.cxx
  39     AliTPCDDLRawData.cxx
  40     AliTPCDigitizer.cxx
  41     AliTPCLaser.cxx
  42     AliTPCQADataMakerSim.cxx
  43     AliTPCTrackHitsV2.cxx
  44     AliTPCv0.cxx
  45     AliTPCv2.cxx
  46     AliTPCv4.cxx
  47    )
  48
  49 # Headers from sources
  50 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
  51
  52 # Generate the dictionary
  53 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
  54 get_directory_property(incdirs INCLUDE_DIRECTORIES)
  55 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
  56
  57 set(ROOT_DEPENDENCIES Core EG GenVector Geom Hist MathCore Matrix Physics RIO Tree VMC)
  58 set(ALIROOT_DEPENDENCIES  STEERBase STEER CDB ESD RAWDatabase RAWDatarec RAWDatasim TPCbase TPCrec)
  59
  60 # Generate the ROOT map
  61 # Dependecies
  62 set(LIBDEPS ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  63 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
  64
  65 # Create an object to be reused in case of static libraries
  66 # Otherwise the sources will be compiled twice
  67 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
  68 # Follow headers dependencies
  69 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
  70 # Add a library to the project using the object
  71 add_library(${MODULE} SHARED $<TARGET_OBJECTS:TPCsim-object>)
  72
  73 # Linking
  74 target_link_libraries(${MODULE} ${ALIROOT_DEPENDENCIES} ${ROOT_DEPENDENCIES})
  75
  76 # Setting the correct headers for the object as gathered from the dependencies
  77 target_include_directories(${MODULE}-object PUBLIC $<TARGET_PROPERTY:${MODULE},INCLUDE_DIRECTORIES>)
  78 set_target_properties(${MODULE}-object PROPERTIES COMPILE_DEFINITIONS $<TARGET_PROPERTY:${MODULE},COMPILE_DEFINITIONS>)
  79
  80 # Public include folders that will be propagated to the dependecies
  81 target_include_directories(${MODULE} PUBLIC ${incdirs})
  82
  83 # Additional compilation flags
  84 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS "")
  85
  86 # System dependent: Modify the way the library is build
  87 if(${CMAKE_SYSTEM} MATCHES Darwin)
  88     set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
  89 endif(${CMAKE_SYSTEM} MATCHES Darwin)
  90
  91 # Installation
  92 install(TARGETS ${MODULE}
  93         ARCHIVE DESTINATION lib
  94         LIBRARY DESTINATION lib)
  95 install(FILES ${HDRS} DESTINATION include)