cmake/FindFASTJET.cmake

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # AliRoot Build System Module to find and configure FASTJET
  17 # Author: Marco van Leeuwen
  18 # FastJet installation is pointed during cmake configuration -DFASTJET
  19 # Variables set during Find:
  20 # - FASTJET_CONFIG - fastjet-config location
  21 # - FASTJET_VERSION
  22 # - FASTJET_VERSION_MAJOR
  23 # - FASTJET_VERSION_MINOR
  24 # - FASTJET_VERSION_PATCH
  25 # - FASTJET_INCLUDE_DIR - fastjet headers location
  26 # - FASTJET_LIBS_DIR - fastjet libraries location
  27 # - FASTJET_DEFINITIONS - fastjet definition flags
  28 # - FASTJET_CXXFLAGS - fastjet compilation flags
  29 # - FASTJET_LIBS - fastjet libraries - array
  30
  31 set(FASTJET_FOUND FALSE)
  32
  33 if(FASTJET)
  34     # Check for fastjet-config script
  35     find_program(FASTJET_CONFIG NAMES fastjet-config PATHS ${FASTJET}/bin NO_DEFAULT_PATH)
  36     if(NOT FASTJET_CONFIG)
  37         message(FATAL_ERROR "Could not find fastjet-config executable")
  38     endif(NOT FASTJET_CONFIG)
  39
  40     # Check for header installation
  41     find_path(FASTJETHH include/fastjet/PseudoJet.hh PATHS ${FASTJET})
  42
  43     if (FASTJETHH-NOTFOUND)
  44         message(FATAL_ERROR "Header file fastjet/PseudoJet.hh not found in ${FASTJET}/include. Please check your FASTJET installation")
  45     endif(FASTJETHH-NOTFOUND)
  46
  47     # FastJet version
  48     execute_process(COMMAND ${FASTJET_CONFIG} --version OUTPUT_VARIABLE FASTJET_VERSION ERROR_VARIABLE error OUTPUT_STRIP_TRAILING_WHITESPACE )
  49     if(error)
  50         message(FATAL_ERROR "Error retrieving FastJet version : ${error}")
  51     endif(error)
  52
  53     # Extract major, minor, and patch versions from
  54     string(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+.*" "\\1" FASTJET_VERSION_MAJOR "${FASTJET_VERSION}")
  55     string(REGEX REPLACE "^[0-9]+\\.([0-9])+\\.[0-9]+.*" "\\1" FASTJET_VERSION_MINOR "${FASTJET_VERSION}")
  56     string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1" FASTJET_VERSION_PATCH "${FASTJET_VERSION}")
  57
  58     # Extracting compilation flags
  59     execute_process(COMMAND ${FASTJET_CONFIG} --cxxflags OUTPUT_VARIABLE FASTJET_CXXFLAGS ERROR_VARIABLE error OUTPUT_STRIP_TRAILING_WHITESPACE )
  60     if(error)
  61         message(FATAL_ERROR "Error retrieving FastJet compilation flags : ${error}")
  62     endif(error)
  63
  64     # Extracting the include path from the CXX flags
  65     set(FASTJET_INCLUDE_DIR)
  66     if(FASTJET_CXXFLAGS)
  67         string(STRIP ${FASTJET_CXXFLAGS} FASTJET_CXXFLAGS)
  68         string(REGEX MATCHALL  "[-][I]([^ ])+" incfolders ${FASTJET_CXXFLAGS})
  69
  70         foreach(incfolder ${incfolders})
  71             string(REPLACE "-I" "" incfolder ${incfolder})
  72             set(FASTJET_INCLUDE_DIR ${incfolder} ${FASTJET_INCLUDE_DIR})
  73         endforeach()
  74     endif(FASTJET_CXXFLAGS)
  75
  76     # Extracting libraries and linking options
  77     execute_process(COMMAND ${FASTJET_CONFIG} --libs OUTPUT_VARIABLE FASTJET_CONFIGLIBS ERROR_VARIABLE error OUTPUT_STRIP_TRAILING_WHITESPACE )
  78     if(error)
  79         message(FATAL_ERROR "Error retrieving FastJet libs : ${error}")
  80     endif(error)
  81
  82     # Extracting the list of needed libraries during linking and the linking folders
  83     set(FASTJET_LIBS)
  84     set(FASTJET_LIBS_DIR)
  85     if(FASTJET_CONFIGLIBS)
  86         string(STRIP ${FASTJET_CONFIGLIBS} FASTJET_CONFIGLIBS)
  87
  88         # Extracting the list of libraries needed during linking
  89         # -l strings
  90         string(REGEX MATCHALL "[-][l]([^ ])+" fjlibs "${FASTJET_CONFIGLIBS}")
  91
  92         foreach(flib ${fjlibs})
  93             string(REPLACE "-l" "" flib "${flib}")
  94             set(FASTJET_LIBS ${FASTJET_LIBS} ${flib})
  95         endforeach()
  96
  97         # Extracting the list of libraries folders
  98         # -L strings
  99         string(REGEX MATCHALL "[-][L]([^ ])+" fjlibdirs "${FASTJET_CONFIGLIBS}")
 100
 101         foreach(fjlibdir ${fjlibdirs})
 102             string(REPLACE "-L" "" fjlibdir ${fjlibdir})
 103             set(FASTJET_LIBS_DIR ${fjlibdir} ${FASTJET_LIBS_DIR})
 104         endforeach()
 105     endif()
 106
 107     set(FASTJET_FOUND TRUE)
 108     set(FASTJET_DEFINITIONS "-DHAVE_FASTJET")
 109     message(STATUS "FastJet ${FASTJET_VERSION_MAJOR}.${FASTJET_VERSION_MINOR}.${FASTJET_VERSION_PATCH} installation found: ${FASTJET}")
 110 else()
 111     message(STATUS "FastJet not found: disabling dependencies")
 112 endif(FASTJET)