-if test ! "x$have_aliroot" = "xno" ; then
- ALIROOT_CPPFLAGS="-I${ALIROOTINCDIR} -I${ALICE_ROOT}/RAW"
- ALIROOT_LDFLAGS="-L${ALIROOTLIBDIR}"
- ALIROOT_LIBS="$ADD_ROOTLIBS"
- save_CPPFLAGS=$CPPFLAGS
- save_LDFLAGS=$LDFLAGS
- save_LIBS=$LIBS
- CPPFLAGS="$save_CPPFLAGS $ALIROOT_CPPFLAGS"
- LDFLAGS="$save_LDFLAGS -L${ROOTLIBDIR} $ALIROOT_LDFLAGS"
-
- # check for certain AliRoot libraries/files/features
- # libSTEERBase present since Aug 7 2007
- # ###########################################
- # temporary workaround for circular dependency libSTEERbase libSTEER
- # https://savannah.cern.ch/bugs/index.php?49914
- # disable the sequence of checks and load libraries in parallel
- ALIROOT_LIBS="$ALIROOT_LIBS -lAOD -lCDB -lRAWDatabase -lRAWDatarec -lESD -lSTEER"
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS"
- CHECKLIB=STEERBase
- AC_CHECK_LIB([$CHECKLIB],[_init],[ALIROOT_LIBS="$ALIROOT_LIBS -l$CHECKLIB"])
-
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS"
- CHECKLIB=AOD
- AC_CHECK_LIB([$CHECKLIB],[_init],[ALIROOT_LIBS="$ALIROOT_LIBS -l$CHECKLIB"])
-
- # CBD library is present since AliRoot version v4-05-00 (02.06.2006)
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS"
- CHECKLIB=CDB
- AC_CHECK_LIB([$CHECKLIB],[_init],[ALIROOT_LIBS="$ALIROOT_LIBS -l$CHECKLIB"])
-
- # splitted RAW libraries since AliRoot version v4-04-Rev-07 (09.08.2006)
- have_alirawdata=no
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS"
- CHECKLIB=RAWDatabase
- AC_CHECK_LIB([$CHECKLIB],[_init],
- [ALIROOT_LIBS="$ALIROOT_LIBS -l$CHECKLIB"
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS -lESD -lSTEER"
- CHECKLIB=RAWDatarec
- AC_CHECK_LIB([$CHECKLIB],[_init],
- [ALIROOT_LIBS="$ALIROOT_LIBS -l$CHECKLIB"
- have_alirawdata=$CHECKLIB])],
- [# second pass with -RAWData
- CHECKLIB="-lRAWData"
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS $CHECKLIB -lSTEER"
- AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <AliRawReaderMemory.h>
- #include <AliRawReaderFile.h>
- #include <AliRawReaderDate.h>
- #include <AliRawReaderRoot.h>],
- [AliRawReaderMemory mreader;
- AliRawReaderFile freader;
- AliRawReaderDate dreader(NULL,0);
- AliRawReaderRoot rreader(NULL,0);])],
- [ALIROOT_LIBS="$ALIROOT_LIBS $CHECKLIB"
- have_alirawdata=$CHECKLIB],
- [have_alirawdata=no])
- ]) dnl AC_CHECK_LIB RAWDatabase
- AC_MSG_CHECKING([for AliRawReader classes in RAWData libraries])
- AC_MSG_RESULT([$have_alirawdata])
-
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS -lSTEER"
- CHECKLIB=ESD
- AC_CHECK_LIB([$CHECKLIB],[_init],[ALIROOT_LIBS="$ALIROOT_LIBS -l$CHECKLIB"])
-
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS"
- CHECKLIB=STEER
- AC_CHECK_LIB([$CHECKLIB],[_init],[ALIROOT_LIBS="$ALIROOT_LIBS -l$CHECKLIB"],[have_aliroot=no])
-
- dnl
- dnl check whether AliLog supports notification callback
- dnl
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS"
- have_alilog_notification=no
- if test ! "x$have_aliroot" = "xno" ; then
- AC_MSG_CHECKING([whether AliLog supports notification callback])
- AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <AliLog.h>],
- [AliLog::AliLogNotification fct])],
- [have_alilog_notification=yes],
- [AC_DEFINE(NO_ALILOG_NOTIFICATION)])
- AC_MSG_RESULT([$have_alilog_notification])
- fi
-
- if test "x$have_aliroot" = "xno" ; then
- # 2007-08-18 dont reset ALIROOT_CPPFLAGS in order to allow compilation
- # but library dependencies might not be resolved completely
- #ALIROOT_CPPFLAGS=
- AC_MSG_WARN([some of the AliRoot library dependencies are not resolved.
- This can happen from time to time due to development in AliRoot. You can
- force compilation of detector libs by --enable-<detector>, but be aware
- of unresolved references at runtime.])
- AC_MSG_WARN([ ------------------------------------------ ])
- AC_MSG_WARN([ Report this to $PACKAGE_BUGREPORT ])
- AC_MSG_WARN([ please include config.log ])
- AC_MSG_WARN([ ------------------------------------------ ])
- ALIROOT_LDFLAGS=
- ALIROOT_LIBS=
- fi
-
- dnl
- dnl ESD supports non-std content
- dnl
- have_esd_nonstd=no
- AC_RUN_IFELSE([AC_LANG_PROGRAM([#include <AliESDEvent.h>
- #include <AliExternalTrackParam.h>
- #include <TTree.h>
- #include <TClonesArray.h>],
- [AliESDEvent esd;
- esd.CreateStdContent();
- TTree* tree=new TTree("esdTree", "Tree with HLT ESD objects");
- TClonesArray* a=new TClonesArray("AliExternalTrackParam");
- a->SetName("SomeObject");
- esd.AddObject(a);
- esd.WriteToTree(tree);
- if (!tree->FindBranch("SomeObject")) return 1;
- return 0;])],
- [have_esd_nonstd=yes],
- [AC_DEFINE(HAVE_NOT_ESD_NONSTD)])
- AC_MSG_CHECKING(whether ESD supports non standard content)
- AC_MSG_RESULT([$have_esd_nonstd])
-
- dnl
- dnl ESD copy function added May 9 2008 rev 25667
- dnl
- if test "x$have_esd_nonstd" != "xyes"; then
- have_esd_copy=no
- AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <AliESDEvent.h>],
- [AliESDEvent esd1;
- AliESDEvent esd2;
- esd2=esd1;])],
- [have_esd_copy=yes],
- [AC_DEFINE(HAVE_NOT_ESD_COPY)])
- AC_MSG_CHECKING(for ESD assignment operator)
- AC_MSG_RESULT([$have_esd_copy])
- fi
-
- dnl
- dnl AliRawReaderMemory support for multiple buffers added
- dnl revision 26829 Jun 2008
- dnl
- CPPFLAGS="$save_CPPFLAGS $ALIROOT_CPPFLAGS -I${ALICE_ROOT}/RAW"
- have_rawreadermemory_multbuffers=no
- AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <AliRawReaderMemory.h>],
- [AliRawReaderMemory rr;
- rr.AddBuffer(NULL, 0, 0);])],
- [have_rawreadermemory_multbuffers=yes],
- [AC_DEFINE(HAVE_NOT_ALIRAWREADERMEMORY_ADDBUFFER)])
- AC_MSG_CHECKING(AliRawReaderMemory support for multiple buffers)
- AC_MSG_RESULT([$have_rawreadermemory_multbuffers])
-
- dnl
- dnl Changes in the magnetic field implementation
- dnl revision 30848 Feb 1 2009
- dnl
- CPPFLAGS="$save_CPPFLAGS $ALIROOT_CPPFLAGS -I${ALICE_ROOT}/STEER"
- have_alimagf30848=no
- AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <AliMagF.h>],
- [int test=AliMagF::k5kG;])],
- [have_alimagf30848=yes],
- [AC_DEFINE(HAVE_NOT_ALIMAGF30848)])
- AC_MSG_CHECKING(AliMagF contains field definitions)
- AC_MSG_RESULT([$have_alimagf30848])
-
- dnl
- dnl Cleanup of the RunLoader implementation
- dnl revision 30859 Feb 2 2009
- dnl
- CPPFLAGS="$save_CPPFLAGS $ALIROOT_CPPFLAGS -I${ALICE_ROOT}/STEER"
- have_alirunloader30859=no
- AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <AliRunLoader.h>],
- [AliRunLoader* rl=AliRunLoader::Instance();])],
- [have_alirunloader30859=yes],
- [AC_DEFINE(HAVE_NOT_ALIRUNLOADER30859)])
- AC_MSG_CHECKING(AliRunLoader::Instance)
- AC_MSG_RESULT([$have_alirunloader30859])
-
- have_aliqav1=no
- AC_CHECK_HEADER([AliQAv1.h], [have_aliqav1=yes], [])
- AM_CONDITIONAL(EN_HLT_QA, test x$have_aliqav1 = xyes)
-
- dnl
- dnl required header files and libraries for modules
- dnl
-
- dnl
- dnl Check for the interface of AliExternalTrackParam which has been changed
- dnl in revision 1.17 of AliExternalTrackParam.h (AliRoot version v4-05-04
- dnl or higher)
- externaltrackparam_version=1
- AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <AliExternalTrackParam.h>],
- [AliExternalTrackParam trackparam;
- Double_t param[[5]]; Double_t covar[[15]];
- trackparam.Set(0., 0., param, covar);])],
- [externaltrackparam_version=2],
- [AC_DEFINE(EXTERNALTRACKPARAM_V1)])
- AC_MSG_CHECKING(for version of AliExternalTrackParam)
- AC_MSG_RESULT($externaltrackparam_version)
-
- dnl The AliShuttleInterface was changed in rev 29388. Some return types
- dnl had been const, now changed according to gcc 4.3 warnings
- AC_MSG_CHECKING(for version of AliShuttleInterface.h)
- CPPFLAGS="$save_CPPFLAGS $ALIROOT_CPPFLAGS -I${ALICE_ROOT}/"
- LDFLAGS="$save_LDFLAGS -L${ROOTLIBDIR} $ALIROOT_LDFLAGS"
- LIBS="$save_LIBS $ROOTLIBS $ALIROOT_LIBS $ALITPC_LIBS"
- AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <AliShuttleInterface.h>],
- [class dummy : public AliShuttleInterface {
- public:
- const UInt_t GetStartTimeDCSQuery() {;}
- };])],
- [AC_DEFINE(SHUTTLE_PRE_REV29388_INTERFACE)
- alishuttleinterface_version=pre.rev.29388],
- [alishuttleinterface_version=up.to.date])
- AC_MSG_RESULT([$alishuttleinterface_version])
-
- CPPFLAGS=$save_CPPFLAGS
- LDFLAGS=$save_LDFLAGS
- LIBS=$save_LIBS
-fi # if test ! "x$have_aliroot" = "xno"
-