ISAJET/isasusy/sstest.F

   1 #include "isajet/pilot.h"
   2       SUBROUTINE SSTEST(IALLOW)
   3 C
   4 C          Test MSSM parameters against existing bounds on SUSY from
   5 C          LEP and SLC:
   6 C          IALLOW = 1    Z1 is not LSP
   7 C          IALLOW = 2    Gamma(Z -> Z1SS Z1SS) < GAMINV
   8 C          IALLOW = 4    Z -> charginos allowed
   9 C          IALLOW = 8    BF(Z -> Z1SS Z2SS)>10^5
  10 C          IALLOW = 16   Z -> squarks, sleptons
  11 C          IALLOW = 32   BR(Z -> Z* HL0) < B(Z -> Z* H(M=MHSM))
  12 C          IALLOW = 64   BR(Z -> HL0 HA0) > 0
  13 C          IALLOW = 128  M(H+) > M(Z)/2
  14 C          where GAMINV is the present bound on the invisible width,
  15 C          and MHSM is the lower bound on the standard Higgs mass.
  16 C
  17 C          Bounds on the other modes are only approximate, but the
  18 C          error in the allowed region of masses must be tiny.
  19 C          Updated by H. Baer on 5/25/95
  20 C
  21 #if defined(CERNLIB_IMPNONE)
  22       IMPLICIT NONE
  23 #endif
  24 #include "isajet/sslun.inc"
  25 #include "isajet/ssmode.inc"
  26 #include "isajet/sssm.inc"
  27 #include "isajet/sspar.inc"
  28 #include "isajet/sstmp.inc"
  29 #include "isajet/sstype.inc"
  30 #include "isajet/sugmg.inc"
  31 #include "isajet/xmssm.inc"
  32 C
  33       INTEGER IALLOW
  34       EXTERNAL SSZHX
  35       REAL MHSM,GAMINV,PI,SR2,G,GP,MZ,MZ1,MZ2,MZ3,MZ4,MW1,MW2,
  36      $TANB,BETA,COS2B,SIN2B,VS,V,VP,FT,MHL,ALPHA,SUSYCC,
  37      $GAMSS,W11,GZ1Z1,GAMSM,SSXINT,SSXLAM,COS2W,
  38      $W12,GZ1Z2,DGAMZ,BFZ,BFZ1Z2
  39 C
  40 C          Current bounds
  41       DATA MHSM/64./,GAMINV/.0043/,DGAMZ/.0115/,BFZ/1.E-5/
  42 C
  43 C          Initialize
  44 C
  45       IALLOW=0
  46       PI=4.*ATAN(1.)
  47       SR2=SQRT(2.)
  48       G=SQRT(4*PI*ALFAEM/SN2THW)
  49       GP=G*SQRT(SN2THW/(1.-SN2THW))
  50       COS2W=SQRT(1.-SN2THW)
  51       MZ=AMZ
  52       MZ1=ABS(AMZ1SS)
  53       MZ2=ABS(AMZ2SS)
  54       MZ3=ABS(AMZ3SS)
  55       MZ4=ABS(AMZ4SS)
  56       MW1=ABS(AMW1SS)
  57       MW2=ABS(AMW2SS)
  58 C
  59 C          Check that Z1SS is LSP
  60 C
  61       IF(MZ1.GT.MW1.OR.MZ1.GT.AMGLSS.OR.MZ1.GT.AMULSS
  62      $.OR.MZ1.GT.AMERSS.OR.MZ1.GT.AMELSS.OR.MZ1.GT.AMN1SS
  63      $.OR.MZ1.GT.AMB1SS.OR.MZ1.GT.AMT1SS.OR.MZ1.GT.AML1SS) THEN
  64         IALLOW=IALLOW+1
  65       ENDIF
  66 C
  67 C          Z -> Z1SS + Z1SS
  68 C
  69       IF (AMZ.GT.2*MZ1) THEN
  70         W11=SQRT(G*G+GP*GP)
  71      $  *(ZMIXSS(1,1)*ZMIXSS(1,1)-ZMIXSS(2,1)*ZMIXSS(2,1))/4.
  72         GZ1Z1=SQRT(SSXLAM(MZ**2,MZ1**2,MZ1**2))/12./PI/MZ**3*W11**2
  73      $  *(2*MZ**2-MZ1**2-MZ1**2-(MZ1**2-MZ1**2)**2/MZ**2
  74      $  -6*MZ1*MZ1*SIGN(1.,AMZ1SS*AMZ1SS))
  75         IF(GZ1Z1.GT.GAMINV) THEN
  76           IALLOW=IALLOW+2
  77         ENDIF
  78       ENDIF
  79 C
  80 C          Check for other allowed visible modes modes
  81 C
  82       IF(AMZ.GT.2*MW1) THEN
  83         IALLOW=IALLOW+4
  84       ENDIF
  85 C
  86 C          Check funny Z branching fractions
  87 C
  88       BFZ1Z2=0.
  89       IF (AMZ.GT.MZ1+MZ2) THEN
  90         W12=SQRT(G*G+GP*GP)
  91      $  *(ZMIXSS(1,1)*ZMIXSS(1,2)-ZMIXSS(2,1)*ZMIXSS(2,2))/4.
  92         GZ1Z2=SQRT(SSXLAM(MZ**2,MZ1**2,MZ2**2))/6./PI/MZ**3*W12**2
  93      $  *(2*MZ**2-MZ1**2-MZ2**2-(MZ1**2-MZ2**2)**2/MZ**2
  94      $  -6*MZ1*MZ2*SIGN(1.,AMZ1SS*AMZ2SS))
  95         BFZ1Z2=GZ1Z2/GAMZ
  96       END IF
  97       IF(BFZ1Z2.GT.BFZ) THEN
  98         IALLOW=IALLOW+8
  99       ENDIF
 100 C
 101       IF(AMZ.GT.2*AMULSS.OR.AMZ.GT.2*AMELSS.OR.AMZ.GT.2*AMERSS
 102      $.OR.AMZ.GT.2*AMN1SS.OR.AMZ.GT.2*AMB1SS.OR.AMZ.GT.2*AMT1SS)THEN
 103         IALLOW=IALLOW+16
 104       ENDIF
 105 C
 106 C          Z -> Higgs modes
 107 C
 108       TMP(1)=MHSM
 109       GAMSM=SSXINT(2*MHSM/MZ,SSZHX,(1.+MHSM**2/MZ**2))
 110 C          Z -> hl0 x
 111       IF(AMZ.GT.AMHL) THEN
 112         TANB=1./RV2V1
 113         BETA=ATAN(TANB)
 114         COS2B=COS(2*BETA)
 115         SIN2B=SIN(2*BETA)
 116         VS=2*AMW**2/G**2/(1.+RV2V1**2)
 117         V=SQRT(VS)
 118         VP=RV2V1*V
 119         FT=G*AMTP/SR2/AMW/V*SQRT(V**2+VP**2)
 120         MHL=AMHL
 121         ALPHA=ALFAH
 122         SUSYCC=SIN(ALPHA+BETA)
 123         TMP(1)=MHL
 124         GAMSS=SSXINT(2*MHL/AMZ,SSZHX,(1.+MHL**2/AMZ**2))*SUSYCC**2
 125         IF(GAMSS.GE.GAMSM) IALLOW=IALLOW+32
 126       ENDIF
 127 C          Z -> hl0 ha0
 128       IF (AMZ.GT.(AMHL+AMHA)) THEN
 129         IALLOW=IALLOW+64
 130       ENDIF
 131 C          Z -> H+ H-
 132       IF(AMZ.GT.2*AMHC) THEN
 133         IALLOW=IALLOW+128
 134       ENDIF
 135 C
 136       RETURN
 137       END