PDF/spdf/sasvm1.F

   1 #include "pdf/pilot.h"
   2        SUBROUTINE SASVM1(ISET,KF,X,Q2,P2,ALAM,XPGA)
   3 C...Purpose: to evaluate the VMD parton distributions of a photon,
   4 C...evolved homogeneously from an initial scale P2 to Q2.
   5 C...Does not include dipole suppression factor.
   6 C...ISET is parton distribution set, see above;
   7 C...additionally ISET=0 is used for the evolution of an anomalous photon
   8 C...which branched at a scale P2 and then evolved homogeneously to Q2.
   9 C...ALAM is the 4-flavour Lambda, which is automatically converted
  10 C...to 3- and 5-flavour equivalents as needed.
  11       DIMENSION XPGA(-6:6)
  12       DATA PMC/1.3/, PMB/4.6/, AEM/0.007297/, AEM2PI/0.0011614/
  13
  14 C...Reset output.
  15       DO 100 KFL=-6,6
  16       XPGA(KFL)=0.
  17   100 CONTINUE
  18       KFA=IABS(KF)
  19
  20 C...Calculate Lambda; protect against unphysical Q2 and P2 input.
  21       ALAM3=ALAM*(PMC/ALAM)**(2./27.)
  22       ALAM5=ALAM*(ALAM/PMB)**(2./23.)
  23       P2EFF=MAX(P2,1.2*ALAM3**2)
  24       IF(KFA.EQ.4) P2EFF=MAX(P2EFF,PMC**2)
  25       IF(KFA.EQ.5) P2EFF=MAX(P2EFF,PMB**2)
  26       Q2EFF=MAX(Q2,P2EFF)
  27
  28 C...Find number of flavours at lower and upper scale.
  29       NFP=4
  30       IF(P2EFF.LT.PMC**2) NFP=3
  31       IF(P2EFF.GT.PMB**2) NFP=5
  32       NFQ=4
  33       IF(Q2EFF.LT.PMC**2) NFQ=3
  34       IF(Q2EFF.GT.PMB**2) NFQ=5
  35
  36 C...Find s as sum of 3-, 4- and 5-flavour parts.
  37       S=0.
  38       IF(NFP.EQ.3) THEN
  39         Q2DIV=PMC**2
  40         IF(NFQ.EQ.3) Q2DIV=Q2EFF
  41         S=S+(6./27.)*LOG(LOG(Q2DIV/ALAM3**2)/LOG(P2EFF/ALAM3**2))
  42       ENDIF
  43       IF(NFP.LE.4.AND.NFQ.GE.4) THEN
  44         P2DIV=P2EFF
  45         IF(NFP.EQ.3) P2DIV=PMC**2
  46         Q2DIV=Q2EFF
  47         IF(NFQ.EQ.5) Q2DIV=PMB**2
  48         S=S+(6./25.)*LOG(LOG(Q2DIV/ALAM**2)/LOG(P2DIV/ALAM**2))
  49       ENDIF
  50       IF(NFQ.EQ.5) THEN
  51         P2DIV=PMB**2
  52         IF(NFP.EQ.5) P2DIV=P2EFF
  53         S=S+(6./23.)*LOG(LOG(Q2EFF/ALAM5**2)/LOG(P2DIV/ALAM5**2))
  54       ENDIF
  55
  56 C...Calculate frequent combinations of x and s.
  57       X1=1.-X
  58       XL=-LOG(X)
  59       S2=S**2
  60       S3=S**3
  61       S4=S**4
  62
  63 C...Evaluate homogeneous anomalous parton distributions below or
  64 C...above threshold.
  65       IF(ISET.EQ.0) THEN
  66       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
  67      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
  68         XVAL = X * 1.5 * (X**2+X1**2)
  69         XGLU = 0.
  70         XSEA = 0.
  71       ELSE
  72         XVAL = (1.5/(1.-0.197*S+4.33*S2)*X**2 + (1.5+2.10*S)/
  73      &  (1.+3.29*S)*X1**2 + 5.23*S/(1.+1.17*S+19.9*S3)*X*X1) *
  74      &  X**(1./(1.+1.5*S)) * (1.-X**2)**(2.667*S)
  75         XGLU = 4.*S/(1.+4.76*S+15.2*S2+29.3*S4) *
  76      &  X**(-2.03*S/(1.+2.44*S)) * (X1*XL)**(1.333*S) *
  77      &  ((4.*X**2+7.*X+4.)*X1/3. - 2.*X*(1.+X)*XL)
  78         XSEA = S2/(1.+4.54*S+8.19*S2+8.05*S3) *
  79      &  X**(-1.54*S/(1.+1.29*S)) * X1**(2.667*S) *
  80      &  ((8.-73.*X+62.*X**2)*X1/9. + (3.-8.*X**2/3.)*X*XL +
  81      &  (2.*X-1.)*X*XL**2)
  82       ENDIF
  83
  84 C...Evaluate set 1D parton distributions below or above threshold.
  85       ELSEIF(ISET.EQ.1) THEN
  86       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
  87      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
  88         XVAL = 1.294 * X**0.80 * X1**0.76
  89         XGLU = 1.273 * X**0.40 * X1**1.76
  90         XSEA = 0.100 * X1**3.76
  91       ELSE
  92         XVAL = 1.294/(1.+0.252*S+3.079*S2) * X**(0.80-0.13*S) *
  93      &  X1**(0.76+0.667*S) * XL**(2.*S)
  94         XGLU = 7.90*S/(1.+5.50*S) * EXP(-5.16*S) *
  95      &  X**(-1.90*S/(1.+3.60*S)) * X1**1.30 * XL**(0.50+3.*S) +
  96      &  1.273 * EXP(-10.*S) * X**0.40 * X1**(1.76+3.*S)
  97         XSEA = (0.1-0.397*S2+1.121*S3)/(1.+5.61*S2+5.26*S3) *
  98      &  X**(-7.32*S2/(1.+10.3*S2)) *
  99      &  X1**((3.76+15.*S+12.*S2)/(1.+4.*S))
 100         XSEA0 = 0.100 * X1**3.76
 101       ENDIF
 102
 103 C...Evaluate set 1M parton distributions below or above threshold.
 104       ELSEIF(ISET.EQ.2) THEN
 105       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
 106      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
 107         XVAL = 0.8477 * X**0.51 * X1**1.37
 108         XGLU = 3.42 * X**0.255 * X1**2.37
 109         XSEA = 0.
 110       ELSE
 111         XVAL = 0.8477/(1.+1.37*S+2.18*S2+3.73*S3) * X**(0.51+0.21*S)
 112      &  * X1**1.37 * XL**(2.667*S)
 113         XGLU = 24.*S/(1.+9.6*S+0.92*S2+14.34*S3) * EXP(-5.94*S) *
 114      &  X**((-0.013-1.80*S)/(1.+3.14*S)) * X1**(2.37+0.4*S) *
 115      &  XL**(0.32+3.6*S) + 3.42 * EXP(-12.*S) * X**0.255 *
 116      &  X1**(2.37+3.*S)
 117         XSEA = 0.842*S/(1.+21.3*S-33.2*S2+229.*S3) *
 118      &  X**((0.13-2.90*S)/(1.+5.44*S)) * X1**(3.45+0.5*S) *
 119      &  XL**(2.8*S)
 120         XSEA0 = 0.
 121       ENDIF
 122
 123 C...Evaluate set 2D parton distributions below or above threshold.
 124       ELSEIF(ISET.EQ.3) THEN
 125       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
 126      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
 127         XVAL = X**0.46 * X1**0.64 + 0.76 * X
 128         XGLU = 1.925 * X1**2
 129         XSEA = 0.242 * X1**4
 130       ELSE
 131         XVAL = (1.+0.186*S)/(1.-0.209*S+1.495*S2) * X**(0.46+0.25*S)
 132      &  * X1**((0.64+0.14*S+5.*S2)/(1.+S)) * XL**(1.9*S) +
 133      &  (0.76+0.4*S) * X * X1**(2.667*S)
 134         XGLU = (1.925+5.55*S+147.*S2)/(1.-3.59*S+3.32*S2) *
 135      &  EXP(-18.67*S) * X**((-5.81*S-5.34*S2)/(1.+29.*S-4.26*S2))
 136      &  * X1**((2.-5.9*S)/(1.+1.7*S)) * XL**(9.3*S/(1.+1.7*S))
 137         XSEA = (0.242-0.252*S+1.19*S2)/(1.-0.607*S+21.95*S2) *
 138      &  X**(-12.1*S2/(1.+2.62*S+16.7*S2)) * X1**4 * XL**S
 139         XSEA0 = 0.242 * X1**4
 140       ENDIF
 141
 142 C...Evaluate set 2M parton distributions below or above threshold.
 143       ELSEIF(ISET.EQ.4) THEN
 144       IF(Q2.LE.P2.OR.(KFA.EQ.4.AND.Q2.LT.PMC**2).OR.
 145      &(KFA.EQ.5.AND.Q2.LT.PMB**2)) THEN
 146         XVAL = 1.168 * X**0.50 * X1**2.60 + 0.965 * X
 147         XGLU = 1.808 * X1**2
 148         XSEA = 0.209 * X1**4
 149       ELSE
 150         XVAL = (1.168+1.771*S+29.35*S2) * EXP(-5.776*S) *
 151      &  X**((0.5+0.208*S)/(1.-0.794*S+1.516*S2)) *
 152      &  X1**((2.6+7.6*S)/(1.+5.*S)) * XL**(5.15*S/(1.+2.*S)) +
 153      &  (0.965+22.35*S)/(1.+18.4*S) * X * X1**(2.667*S)
 154         XGLU = (1.808+29.9*S)/(1.+26.4*S) * EXP(-5.28*S) *
 155      &  X**((-5.35*S-10.11*S2)/(1.+31.71*S)) *
 156      &  X1**((2.-7.3*S+4.*S2)/(1.+2.5*S)) *
 157      &  XL**(10.9*S/(1.+2.5*S))
 158         XSEA = (0.209+0.644*S2)/(1.+0.319*S+17.6*S2) *
 159      &  X**((-0.373*S-7.71*S2)/(1.+0.815*S+11.0*S2)) *
 160      &  X1**(4.+S) * XL**(0.45*S)
 161         XSEA0 = 0.209 * X1**4
 162       ENDIF
 163       ENDIF
 164
 165 C...Threshold factors for c and b sea.
 166       SLL=LOG(LOG(Q2EFF/ALAM**2)/LOG(P2EFF/ALAM**2))
 167       XCHM=0.
 168       IF(Q2.GT.PMC**2.AND.Q2.GT.1.001*P2EFF) THEN
 169         SCH=MAX(0.,LOG(LOG(PMC**2/ALAM**2)/LOG(P2EFF/ALAM**2)))
 170         IF(ISET.EQ.0) THEN
 171           XCHM=XSEA*(1.-(SCH/SLL)**2)
 172         ELSE
 173           XCHM=MAX(0.,XSEA-XSEA0*X1**(2.667*S))*(1.-SCH/SLL)
 174         ENDIF
 175       ENDIF
 176       XBOT=0.
 177       IF(Q2.GT.PMB**2.AND.Q2.GT.1.001*P2EFF) THEN
 178         SBT=MAX(0.,LOG(LOG(PMB**2/ALAM**2)/LOG(P2EFF/ALAM**2)))
 179         IF(ISET.EQ.0) THEN
 180           XBOT=XSEA*(1.-(SBT/SLL)**2)
 181         ELSE
 182           XBOT=MAX(0.,XSEA-XSEA0*X1**(2.667*S))*(1.-SBT/SLL)
 183         ENDIF
 184       ENDIF
 185
 186 C...Fill parton distributions.
 187       XPGA(0)=XGLU
 188       XPGA(1)=XSEA
 189       XPGA(2)=XSEA
 190       XPGA(3)=XSEA
 191       XPGA(4)=XCHM
 192       XPGA(5)=XBOT
 193       XPGA(KFA)=XPGA(KFA)+XVAL
 194       DO 110 KFL=1,5
 195       XPGA(-KFL)=XPGA(KFL)
 196   110 CONTINUE
 197
 198       RETURN
 199       END