RAW/RAWDatarec/CMakeLists.txt

   1 # **************************************************************************
   2 # * Copyright(c) 1998-2014, ALICE Experiment at CERN, All rights reserved. *
   3 # *                                                                        *
   4 # * Author: The ALICE Off-line Project.                                    *
   5 # * Contributors are mentioned in the code where appropriate.              *
   6 # *                                                                        *
   7 # * Permission to use, copy, modify and distribute this software and its   *
   8 # * documentation strictly for non-commercial purposes is hereby granted   *
   9 # * without fee, provided that the above copyright notice appears in all   *
  10 # * copies and that both the copyright notice and this permission notice   *
  11 # * appear in the supporting documentation. The authors make no claims     *
  12 # * about the suitability of this software for any purpose. It is          *
  13 # * provided "as is" without express or implied warranty.                  *
  14 # **************************************************************************
  15
  16 # Module
  17 set(MODULE RAWDatarec)
  18
  19 # Module include folder
  20 include_directories(${AliRoot_SOURCE_DIR}/RAW/${MODULE})
  21
  22 # Additional include folders in alphabetical order except ROOT
  23 include_directories(${ROOT_INCLUDE_DIR}
  24                     ${AliRoot_SOURCE_DIR}/RAW/dateStream
  25                     ${AliRoot_SOURCE_DIR}/RAW/RAWDatabase
  26                     ${AliRoot_SOURCE_DIR}/STEER/ESD
  27                     ${AliRoot_SOURCE_DIR}/STEER/STEERBase
  28                    )
  29 # Sources in alphabetical order
  30 set(SRCS
  31     AliAltroRawStream.cxx
  32     AliAltroRawStreamV3.cxx
  33     AliCaloRawStream.cxx
  34     AliCaloRawStreamV3.cxx
  35     AliFilter.cxx
  36     AliRawHLTManager.cxx
  37     AliRawReaderChain.cxx
  38     AliRawReader.cxx
  39     AliRawReaderDate.cxx
  40     AliRawReaderFile.cxx
  41     AliRawReaderMemory.cxx
  42     AliRawReaderRoot.cxx
  43     AliVMERawStream.cxx
  44    )
  45
  46 # Headers from sources
  47 string(REPLACE ".cxx" ".h" HDRS "${SRCS}")
  48
  49 # Generate the dictionary
  50 # It will create G_ARG1.cxx and G_ARG1.h / ARG1 = function first argument
  51 get_directory_property(incdirs INCLUDE_DIRECTORIES)
  52 generate_dictionary("${MODULE}" "${MODULE}LinkDef.h" "${HDRS}" "${incdirs}")
  53
  54 set(ROOT_DEPENDENCIES Core Net RIO TreePlayer Tree)
  55 set(ALIROOT_DEPENDENCIES ESD RAWDatabase STEERBase)
  56
  57 # Generate the ROOT map
  58 # Dependecies
  59 set(LIBDEPS ${ROOT_DEPENDENCIES} ${ALIROOT_DEPENDENCIES})
  60 generate_rootmap("${MODULE}" "${LIBDEPS}" "${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}LinkDef.h")
  61
  62 # Create an object to be reused in case of static libraries
  63 # Otherwise the sources will be compiled twice
  64 add_library(${MODULE}-object OBJECT ${SRCS} G__${MODULE}.cxx)
  65 # Follow headers dependencies
  66 add_dependencies(${MODULE}-object ${ALIROOT_DEPENDENCIES})
  67 # Add a library to the project using the object
  68 add_library(${MODULE} SHARED $<TARGET_OBJECTS:RAWDatarec-object>)
  69
  70 target_link_libraries(${MODULE} LINK_PUBLIC ${ROOT_DEPENDENCIES} ${ALIROOT_DEPENDENCIES})
  71
  72 # Setting the correct headers for the object as gathered from the dependencies
  73 target_include_directories(${MODULE}-object PUBLIC $<TARGET_PROPERTY:${MODULE},INCLUDE_DIRECTORIES>)
  74 set_target_properties(${MODULE}-object PROPERTIES COMPILE_DEFINITIONS $<TARGET_PROPERTY:${MODULE},COMPILE_DEFINITIONS>)
  75
  76 # Public include folders that will be propagated to the dependecies
  77 target_include_directories(${MODULE} PUBLIC ${incdirs})
  78
  79 # Compile and link flags
  80 set(MODULE_COMPILE_FLAGS)
  81 set(MODULE_LINK_FLAGS)
  82
  83 if(DATE_FOUND)
  84     set(MODULE_COMPILE_FLAGS "${DATE_CFLAGS}")
  85     set(MODULE_LINK_FLAGS "${DATE_LDFLAGS} ${DATE_LIBS}")
  86 endif(DATE_FOUND)
  87
  88 # Additional compilation and linking flags
  89 set(MODULE_COMPILE_FLAGS " ${MODULE_COMPILE_FLAGS}")
  90
  91 # System dependent: Modify the way the library is build
  92 if(${CMAKE_SYSTEM} MATCHES Darwin)
  93     set(MODULE_LINK_FLAGS "-undefined dynamic_lookup ${MODULE_LINK_FLAGS}")
  94 endif(${CMAKE_SYSTEM} MATCHES Darwin)
  95
  96 # Setting compile flags for the object
  97 set_target_properties(${MODULE}-object PROPERTIES COMPILE_FLAGS "${MODULE_COMPILE_FLAGS}")
  98
  99 # Setting linking flags for the library
 100 set_target_properties(${MODULE} PROPERTIES LINK_FLAGS "${MODULE_LINK_FLAGS}")
 101
 102 # Installation
 103 install(TARGETS ${MODULE}
 104         ARCHIVE DESTINATION lib
 105         LIBRARY DESTINATION lib)
 106
 107 install(FILES ${HDRS} DESTINATION include)
 108
 109 # Static version if DA enabled
 110 if(ALIROOT_STATIC)
 111     add_library(${MODULE}-static STATIC $<TARGET_OBJECTS:RAWDatarec-object>)
 112
 113     # list of shared dependencies / the name of the variable containing the list of static ones
 114     generate_static_dependencies("${ALIROOT_DEPENDENCIES}" "STATIC_ALIROOT_DEPENDENCIES")
 115     target_link_libraries(${MODULE}-static ${STATIC_ALIROOT_DEPENDENCIES} Root RootExtra)
 116
 117     # Public include folders that will be propagated to the dependecies
 118     target_include_directories(${MODULE}-static PUBLIC ${incdirs})
 119
 120     set_target_properties(${MODULE}-static PROPERTIES OUTPUT_NAME ${MODULE})
 121     set_target_properties(${MODULE}-static PROPERTIES LINK_FLAGS "-Wl,--whole-archive")
 122
 123     # Installation
 124     install(TARGETS ${MODULE}-static
 125             ARCHIVE DESTINATION lib
 126             LIBRARY DESTINATION lib)
 127 endif(ALIROOT_STATIC)